计算机word中的宏,Word用宏来更改文档样式-word技巧-电脑技巧收藏家

启动 Microsoft Word 2003 并打开一篇要更改其中样式的文档。

启动 Microsoft Excel 2003 并新建一个 Excel 工作簿。

在单元格 A1 中，键入要在打开的 Word 文档中更改的样式的名称。然后在单元格 B1 中，键入您想更改为的新样式的名称。对您想更改的每个样式重复执行下面的过程：在 A 列中键入现有样式的名称，在 B 列中键入新样式的名称。下面是一个例子：

输入完成后，保存并关闭 Excel 工作簿。

回到 Word。在“工具”菜单上，指向“宏”，然后单击“宏”。

在“宏的位置”列表中，单击“Normal.dot(共用模板)”。

在“宏名”列表中，键入“ChangeDocumentStyles”，然后单击“创建”。屏幕上将出现“Visual Basic 编辑器”。

找到下面的代码：

Sub ChangeDocumentStyles()

'

' ChangeDocumentStyles Macro

' 宏在 {日期} 由 {人名} 创建

'

End Sub

将此代码编辑成下面这样：

Sub ChangeDocumentStyles()

'

' ChangeDocumentStyles Macro

' 宏在 {日期} 由 {人名} 创建

'

' 目的：基于 Microsoft Excel 样式更改文件提供的资料

' 更改所有文档样式。

Dim objFileDlg As Office.FileDialog

Dim xlApp As Excel.Application

Dim objWB As Excel.Workbook

Dim objWS As Excel.Worksheet

Dim objRngOld As Excel.Range

Dim objRngNew As Excel.Range

On Error GoTo ChangeDocumentStyles_Err

' 用户告知宏 Excel 样式更改文件的位置。

Set objFileDlg = Application.FileDialog(FileDialogType:=msoFileDialogOpen)

With objFileDlg

.AllowMultiSelect = False

.Title = "Select Style Change File"

.Filters.Clear

.Filters.Add _

Description:="Style Change Files (*.xls)", Extensions:="*.xls"

' “-1” 说明用户在“文件对话框”中单击了“打开”按钮。

If .Show = -1 Then

' 在 Excel 工作簿中打开第一个工作表并从单元格 A1 开始。

Set xlApp = New Excel.Application

Set objWB = xlApp.Workbooks.Open(FileName:=objFileDlg.SelectedItems(1))

Set objWS = objWB.Worksheets.Item(1)

Set objRngOld = objWS.Range(Cell1:="A1")

' 如果单元格为空，则任务完成。

Do While Not objRngOld.Value = ""

' 使用活动 Word 文档。

With ActiveDocument.Content.Find

'在 A 列中找到样式。

.Style = ActiveDocument.Styles(objRngOld.Value)

' 替换为 B 列。

Set objRngNew = objRngOld.Offset(ColumnOffset:=1)

.Replacement.Style = ActiveDocument.Styles(objRngNew.Value)

.Execute Replace:=wdReplaceAll

' 在下一行指向 A 列

Set objRngOld = objRngNew.Offset(RowOffset:=1, ColumnOffset:=-1)

End With

Loop

End If

End With

ChangeDocumentStyles_Exit:

' 任务已完成。

MsgBox Prompt:="Done!"

Exit Sub

' 如果出现错误，便转到这里。

ChangeDocumentStyles_Err:

Select Case Err.Number

Case 5941 ' Unknown style.

MsgBox Prompt:="Can't find one or more styles to replace." & _

"Check the styles in column B of your style change sheet." & _

"Program execution stopped."

Case 62

Resume Next

Case Else ' Unknown error.

MsgBox Prompt:="Error " & Err.Number & _

" in ChangeDocumentStyles macro:" & Err.Description

End Select

GoTo ChangeDocumentStyles_Exit

End Sub

在“工具”菜单上，单击“引用”。屏幕上将出现“引用 - Normal”对话框。

在“可用的引用”列表中，选中“Microsoft Excel 10.0 对象库”复选框，然后单击“确定”。

在“文件”菜单上，单击“保存 Normal”。

在“文件”菜单上，单击“关闭并返回 Microsoft Word”。

确保您的 Word 文档仍在打开状态。如已关闭，请将其重新打开。

在 Word 中的“工具”菜单上，指向“宏”，然后单击“宏”。您会看到“宏”对话框。

在宏列表中，单击“ChangeDocumentStyles”，然后单击“运行”。您会看到“Select Style Change File”(选择样式更改文件)对话框。

单击您在上面的第 2 步中创建的文件，然后单击“打开”。