UnityShader初级篇——实现逐像素高光反射光照模型

最新推荐文章于 2025-07-12 13:19:20 发布

啦啦啦小聪聪

最新推荐文章于 2025-07-12 13:19:20 发布

阅读量1k

点赞数

分类专栏： UnityShader初级篇文章标签： shader unity

UnityShader初级篇专栏收录该内容

37 篇文章

订阅专栏

本文介绍了一种在Unity中实现逐像素高光反射的方法，通过详细的Shader代码展示了如何计算光照模型，包括环境光、漫反射和高光反射等部分。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

1.实现逐像素高光反射光照模型

高光反射部分的计算是非线性的，顶点着色器中计算光照再进行插值的过程是线性的，破坏了原计算的非线性关系，会出现较大的视觉问题，于是需使用逐像素方法。

Shader "Unity Shaders Book/Chapter 6/Specular Pixel-Level"
{
	Properties
	{
		_Diffuse ("Diffuse", Color) = (1,1,1,1)
		//控制高光反射的颜色
		_Specular("Specular", Color) = (1,1,1,1)
		//控制高光区域的大小
		_Gloss("Gloss", Range(8.0,256)) = 20
	}
	SubShader
	{
		Pass
		{
		      //指明光照模式
		       Tags {"LightMode"="ForwardBase"}
		       
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			//包含引用的内置文件
			#include "Lighting.cginc"

			//声明properties中定义的属性
			fixed4 _Diffuse;
			fixed4 _Specular;
			float _Gloss;

			//定义输入与输出的结构体
			struct a2v
			{
				float4 vertex : POSITION;
				float3 normal : NORMAL;
			};

			struct v2f
			{
				float4 pos : SV_POSITION;
				//存储世界坐标下的法线方向和顶点坐标
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
			};

			//在顶点着色器中，计算世界坐标下的法线方向和顶点坐标，并传递给片元着色器
			v2f vert (a2v v)
			{
				v2f o;
				//转换顶点坐标到裁剪空间
				o.pos = UnityObjectToClipPos(v.vertex);
				//转换法线坐标到世界空间，直接使用_Object2World转换法线，不能保证转换后法线依然与模型垂直
				o.worldNormal = mul(v.normal, (float3x3)_World2Object);
				//转换顶点坐标到世界空间
				o.worldPos = mul(_Object2World, v.vertex).xyz;	
				return o;
			}

			//在片元着色器中计算光照模型
			fixed4 frag (v2f i) : SV_Target
			{
				 //获取环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);

				//计算漫反射光照
				fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLightDir));

				//获取反射方向
				fixed3 reflectDir = normalize(reflect(-worldLightDir,worldNormal));
				//获取视角方向 = 摄像机的世界坐标 - 顶点的世界坐标
				fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
				//计算高光光照
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir,viewDir)),_Gloss);

				return fixed4(ambient + diffuse + specular,1.0);

			}
			ENDCG
		}
	}

	Fallback"Specular"
}