用erlang实现观察者模式

观察者模式，有时也被称为发布/订阅模式。在面向对象中的解析为：一个目标对象管理所有相依于它的观察者对象，并且在它本身的状态改变时主动发出通知。这通常透过呼叫各观察者所提供的方法来实现。由于erlang是没有对象这个概念的，所以把定义里面的“对象”替换成“进程”即可。

此种模式通常被用来实作事件处理系统。对应的，在erlang中的error_handler就是个不错的观察者模式实例。

或许，进程组pg和pg2模块也算是个观察者模式实现吧。加入进程组对应订阅，离开进程组对应撤销观察，send消息对于发布。

其实，在erlang中实现观察者模式并不困难，只要考虑好一些细节即可。

比如bigwig项目使用的观察者模式就是个不错的例子，代码如下:

-module(bigwig_pubsubhub).

-behaviour(gen_server).

-define(SERVER, ?MODULE).

 

%% ------------------------------------------------------------------

%% API Function Exports

%% ------------------------------------------------------------------

 

-export([start_link/0, notify/1, register_client/1]).

 

%% ------------------------------------------------------------------

%% gen_server Function Exports

%% ------------------------------------------------------------------

 

-export([init/1, handle_call/3, handle_cast/2, handle_info/2, terminate/2, code_change/3]).

 

-record(state, {listeners=[]}).

 

%% ------------------------------------------------------------------

%% API Function Definitions

%% ------------------------------------------------------------------

 

start_link() ->

  gen_server:start_link({local, ?SERVER}, ?MODULE, [], []).

 

notify(Msg) ->

    gen_server:cast(?SERVER, {notify, Msg}).

 

register_client(Pid) ->

    gen_server:call(?SERVER, {register_client, Pid}).

 

%% ------------------------------------------------------------------

%% gen_server Function Definitions

%% ------------------------------------------------------------------

 

init([]) ->

    {ok, #state{}}.

 

handle_call({register_client, Pid}, _From, State) ->

    NewListeners = [ Pid | State#state.listeners ],

    erlang:monitor(process, Pid),

    {reply, ok, State#state{ listeners=NewListeners }}.

 

handle_cast({notify, Msg}, State) ->

    %%io:format("BROADCASTING: ~p\n", [Msg]),

    lists:foreach(fun(P) -> P ! {bigwig, Msg} end, State#state.listeners),

    {noreply, State}.

 

handle_info({'DOWN', _MonitorRef, process, Pid, _Reason}, State) ->

    NewListeners = lists:delete(Pid, State#state.listeners),

    {noreply, State#state{ listeners=NewListeners }};

 

handle_info(_Info, State) ->

  {noreply, State}.

 

terminate(_Reason, _State) ->

  ok.

 

code_change(_OldVsn, State, _Extra) ->

  {ok, State}.

通过register_client方法来订阅，通过notify方法来发布，而bigwig_pubsubhub模块本身负责监听订阅的进程的状态，如果该进程退出了，则自动取消订阅。当然，也可以提供一个unregister_client方法来手动取消订阅，如果需要的话。

大道至简，just keep it simple stupy.

转载于:https://www.cnblogs.com/hx-cavalier/p/4365080.html