Flex3 Object to xml

最新推荐文章于 2019-07-17 05:31:44 发布

weixin_34210740

最新推荐文章于 2019-07-17 05:31:44 发布

阅读量77

点赞数

CC 4.0 BY-SA版权

原文链接：http://www.cnblogs.com/kaixuan/archive/2009/08/31/1557412.html

本文介绍三种将ActionScript对象转换为XML的方法：自定义遍历属性方式、自定义子节点方式及使用SimpleXMLEncoder组件。提供了详细的代码示例并展示了不同方法的输出效果。

Flex Code
//自己遍历Object转换（属性方示表现）
public function objectToXml1(obj:Object,name:String):XML{
    var result : XML;
    var info:Object = ObjectUtil.getClassInfo(obj);
    if(name==null)
        name = info.name;

    var line:String = "<" + name;
    for each (var qn : QName in info.properties){
        line += " ";
        line = line + qn.toString() + "=";
        line = line + "\"" + obj[qn.toString()] + "\"";
    }
    line += "/>"

    result = new XML(line);
    return result;
}

//自己遍历Object转换（子节点方示表现）
public function objectToXml2(obj:Object,name:String):XML{
    var result : XML;
    var info:Object = ObjectUtil.getClassInfo(obj);
    if(name==null)
        name = info.name;
    result = new XML("<" + name + "></"+ name + ">");
    for each (var qn : QName in info.properties){
        var val : Object = obj[qn.toString()];
        if(ObjectUtil.isSimple(val))
            result[qn.toString()] = val;
        else
            result.appendChild(objectToXml2(val,qn.toString()));
    }
    return result;
}

//通过SimpleXMLEncoder转换
private function objectToXml3(obj:Object,name:String):XML {
    var qName:QName = new QName(name);
    var xmlDocument:XMLDocument = new XMLDocument();
    var simpleXMLEncoder:SimpleXMLEncoder = new SimpleXMLEncoder(xmlDocument);
    var xmlNode:XMLNode = simpleXMLEncoder.encodeValue(obj, qName, xmlDocument);
    var xml:XML = new XML(xmlDocument.toString());
    // trace(xml.toXMLString());
    return xml;
}

调用方示
var testPerson:Object = {name:"xxx",role:"leader",phone:"123456",email:"mail@mail.com",image:"ttt.swf"};
var xml1:XML = objectToXml1(testPerson,"person");
var xml2:XML = objectToXml2(testPerson,"person");
var xml3:XML = objectToXml3(testPerson,"person");

返回结果