SQL Server分区动态生成脚本（三）（按年份划分）

SQL Server 分区策略实现

最新推荐文章于 2024-11-04 10:03:19 发布

weixin_33787529

最新推荐文章于 2024-11-04 10:03:19 发布

阅读量93

点赞数

CC 4.0 BY-SA版权

文章标签：数据库

原文链接：http://www.cnblogs.com/saratearing/p/6027437.html

本文详细介绍了一种针对 SQL Server 数据库中大型表的分区策略实现过程。通过使用 T-SQL 脚本，该策略能够按年份创建不同的文件组，并为每个文件组分配独立的文件。此外，还定义了分区函数和方案来确保数据被有效地分散到各个文件组中。

--生成分区脚本
DECLARE @DataBaseName NVARCHAR(50)--数据库名称
DECLARE @TableName NVARCHAR(50)--表名称
DECLARE @ColumnName NVARCHAR(50)--字段名称
DECLARE @Location NVARCHAR(50)--保存分区文件的路径
DECLARE @PStartDay DATE--分区开始时间点
DECLARE @PEndDay DATE --分区截止时间点
DECLARE @FGStr NVARCHAR(50) --文件组名
DECLARE @FStr NVARCHAR(50) --文件名
DECLARE @Size NVARCHAR(50)='10MB'--分区初始化大小,默认为10MB
DECLARE @FileGrowth NVARCHAR(50)='100MB'--分区文件增量，默认值为100MB

DECLARE @sql NVARCHAR(max)

--设置下面变量
SET @DataBaseName = 'BigDBTest'
SET @TableName = 'Dim_Date'
SET @ColumnName = 'DateKey'
SET @Location = 'H:\partion\'
SET @PStartDay='2015-01-01'
SET @PEndDay='2016-02-01'
SET @FGStr = ''
SET @FStr = ''

DECLARE @Y INT

--1.创建文件组

PRINT '--1.创建文件组'
SET @Y = YEAR(@PStartDay)
WHILE @Y <= YEAR(@PEndDay)
BEGIN
SET @FGStr = @Y
SET @sql = 'ALTER DATABASE ['+@DataBaseName +'] ADD FILEGROUP [FG_'+@FGStr+']'
PRINT @sql + CHAR(13)
SET @Y = @Y+1
END

--2.创建文件

PRINT CHAR(13)+'--2.创建文件'
SET @Y = YEAR(@PStartDay)
WHILE @Y <=YEAR(@PEndDay)
BEGIN
SET @FGStr=@Y
SET @FStr=@Y
SET @sql = 'ALTER DATABASE ['+@DataBaseName +']
ADD FILE
(NAME = N''FG_'+@FStr+'_data'',FILENAME = N'''+@Location+'FG_'+@FStr+'_data.ndf'',SIZE = '+@Size+', FILEGROWTH = '+@FileGrowth+' )
TO FILEGROUP [FG_'+@FGStr+'];'
PRINT @sql + CHAR(13)
SET @Y = @Y+1
END

--3.创建分区函数
PRINT CHAR(13)+'--3.创建分区函数'
DECLARE @FunValueStr NVARCHAR(MAX)=''

SET @Y = YEAR(@PStartDay)
WHILE @Y <YEAR(@PEndDay)
BEGIN
SET @FunValueStr = @FunValueStr +''''+CAST(@Y AS NVARCHAR(4))+'-01-01'''+','
SET @Y = @Y+1
END
SET @FunValueStr = SUBSTRING(@FunValueStr,1,len(@FunValueStr)-1)
SET @sql = 'CREATE PARTITION FUNCTION
Fun_'+@ColumnName+'(date) AS RANGE RIGHT FOR VALUES('+@FunValueStr+')'
PRINT @sql + CHAR(13)

--4.创建分区方案
PRINT CHAR(13)+'--4.创建分区方案'

SET @Y = YEAR(@PStartDay)
SET @FGStr = ''
WHILE @Y<=YEAR(@PEndDay)
BEGIN
SET @FGStr =@FGStr+'[FG_'+CAST(@Y AS nvarchar(4))+'],'
SET @Y=@Y+1
END
SET @FGStr=SUBSTRING(@FGStr,1,len(@FGStr)-1)
SET @sql = 'CREATE PARTITION SCHEME Sch_'+@ColumnName+' AS
PARTITION Fun_'+@ColumnName+'
TO('+@FGStr+')'
PRINT @sql + CHAR(13)

转载于:https://www.cnblogs.com/saratearing/p/6027437.html