关于“隔夜拆放利率”

最新推荐文章于 2025-08-16 17:02:07 发布

转载最新推荐文章于 2025-08-16 17:02:07 发布 · 223 阅读

0 ·

CC 4.0 BY-SA版权

原文链接：https://my.oschina.net/wonder365/blog/140588

文章标签：

#awk #python

2019独角兽企业重金招聘Python工程师标准>>>

五月底开始全国银行间同业拆放利率持续抖动攀升，看的人心惊胆战。
那什么是“同行拆借”呢，通俗地说就是：一家银行因现金不足，向另一家银行进行短期借贷。"同业拆借"有不同的时间周期，"隔夜拆借"是最短的。如果"隔夜拆借利率"持续猛增，通常说明银行普遍缺钱（钱荒），为了找同业借钱，不惜支付很高的拆借利息。
咱不是经济工作者，搞不懂那些背后的博弈。还是从技术上讲讲吧。

首先，需要获取拆借利率数据。可以采用如下脚本。

#下载上海银行间拆放利率
#下载地址
URL=http://www.shibor.org/shibor/shiborDefDown.do

for s in 2006 2007 2008 2009 2010 2012 2013
do
        #Shibor数据 报价数据 Shibor均值
        for st in Historical_Shibor_Data_ Historical_Quote_Data_ Historical_Shibor_Tendency_Data_
        do
                fname=$st$s.txt
                sdata="fileName=$fname&url=&shiborRadio=txt&quoteRadio=txt&shiborTendencyRadio=txt"
                echo $fname
                curl -d $sdata $URL -o $fname
        done
done

报价数据需要列转行处理才方便分析

piconv -f gbk Historical_Quote_Data_2013.txt | awk -f groupby.awk

BEGIN {
    # 为了使四大行在最前边，先初始化
    jg["中国银行"] = 0;
    jg["农业银行"] = length(jg);
    jg["工商银行"] = length(jg);
    jg["建设银行"] = length(jg);
}
/^20.*$/ {
    if (!($2 in jg)) {
        # 如果只想要四大行，注释掉下面这行
        jg[$2] = length(jg);
    }
    if (!($1 in rq)) {
        rq[$1] = length(rq);
    }
    datas[$1, $2] = $4;
}

END {
    # 将机构->顺序 转换为 顺序->机构
    for (s in jg) {
        jgs[jg[s]] = s;
    }
    # 打印表头（银行名称）
    printf("日期\t");
    for (j = 0; j < length(jgs); j++) {
        printf("%s\t", jgs[j]);
    }
    printf("\n");
    # 顺序化日期
    for (s in rq) {
        rqs[rq[s]] = s;
    }

    for (r = 0; r < length(rqs); r++) {
        printf("%s\t", rqs[r]);
        for (j = 0; j < length(jgs); j++) {
            printf("%s\t", datas[rqs[r], jgs[j]]);
        }
        printf("\n");
    }
}

拆借利率是由几大行报价，然后加权生成的。通过近半年的报价和最终利率可知,2013年5月份之后，隔夜拆借利率明细攀升了,见下图。