官方的正则表达式组件 RegularExpressions (2) : 子表达式-优快云博客

本文介绍了一个使用正则表达式进行字符串匹配与替换的例子。通过定义特定的模式，可以提取并替换文本中符合该模式的部分。示例中演示了如何从一组字符串中提取字母与数字组合，并对其进行替换。

uses RegularExpressions;

const
  pattern = '([A-Z]+)(\d+)'; //其三个子表达式分别是：[A-Z]+\d+  [A-Z]+  \d+
  txt = 'AAA1 BBB2 AA11 BB22 A111 B222 AAAA'; //测试用的目标文本

procedure TForm1.Button1Click(Sender: TObject);
var
  match: TMatch;
  group: TGroup;
  groups: TGroupCollection;
begin
  match := TRegEx.Match(txt, pattern);
  groups := match.Groups;

  Memo1.Clear;
  for group in groups do
  begin
    Memo1.Lines.Add(group.Value); //AAA1/AAA/1
  end;
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  match: TMatch;
  group: TGroup;
begin
  Memo1.Clear;
  for match in TRegEx.Matches(txt, pattern) do
  begin
    for group in match.Groups do
    begin
      Memo1.Lines.Add(group.Value);
    end;
    Memo1.Lines.Add('');
  end;
end;
{**************
AA11
AA
11

BB22
BB
22

A111
A
111

B222
B
222
**************}

procedure TForm1.Button3Click(Sender: TObject);
var
  rStr: string;
begin
  Memo1.Clear;
  rStr := TRegEx.Replace(txt, pattern, '$1');   //AAA BBB AA BB A B AAAA
  Memo1.Lines.Add(rStr);

  rStr := TRegEx.Replace(txt, pattern, '$2');   //1 2 11 22 111 222 AAAA
  Memo1.Lines.Add(rStr);

  rStr := TRegEx.Replace(txt, pattern, '$2$1'); //1AAA 2BBB 11AA 22BB 111A 222B AAAA
  Memo1.Lines.Add(rStr);
end;
{**********************************
AAA BBB AA BB A B AAAA
1 2 11 22 111 222 AAAA
1AAA 2BBB 11AA 22BB 111A 222B AAAA
***********************************}

转载于:https://www.cnblogs.com/del/archive/2011/03/28/1998139.html