动态表，动态构造。。。系统自带

最新推荐文章于 2024-08-18 19:31:32 发布

原创最新推荐文章于 2024-08-18 19:31:32 发布 · 413 阅读

0 ·

CC 4.0 BY-SA版权

文章标签：

#table #parameters #database #c

本文介绍了一种通过ABAP编程实现从数据库动态导入表格到内部表格的方法，并支持用户自定义排序的功能。用户可以在选择屏幕上输入数据库表格名称及排序依据的列名。程序首先创建动态类型的标准表格，然后从中读取数据并进行自定义排序。

データベーステーブルを動的な内部テーブルに動的にインポートし、その内容を動的にソートします。データベーステーブル名、およびテーブルをソートするための列名は、選択画面で入力することができます。

PARAMETERS dbtab TYPE c LENGTH 30.

SELECT-OPTIONS columns FOR dbtab NO INTERVALS.

DATA: otab  TYPE abap_sortorder_tab,
      oline TYPE abap_sortorder,
      dref  TYPE REF TO data.

FIELD-SYMBOLS: <column> LIKE LINE OF columns,
               <itab> TYPE STANDARD TABLE.

TRY.
    CREATE DATA dref TYPE STANDARD TABLE OF (dbtab).
    ASSIGN dref->* TO <itab>.
  CATCH cx_sy_create_data_error.
    MESSAGE 'Wrong data type!' TYPE 'I' DISPLAY LIKE 'E'.
    LEAVE PROGRAM.
ENDTRY.

TRY.
    SELECT *
           FROM (dbtab)
           INTO TABLE <itab>.
  CATCH cx_sy_dynamic_osql_semantics.
    MESSAGE 'Wrong database table!' TYPE 'I' DISPLAY LIKE 'E'.
    LEAVE PROGRAM.
ENDTRY.

LOOP AT columns ASSIGNING <column>.
  oline-name = <column>-low.
  APPEND oline TO otab.
ENDLOOP.

TRY.
    SORT <itab> BY (otab).
  CATCH cx_sy_dyn_table_ill_comp_val.
    MESSAGE 'Wrong column name!' TYPE 'I' DISPLAY LIKE 'E'.
    LEAVE PROGRAM.
ENDTRY.