批处理怎样判断一个txt文件是否为空？

[已解决]批处理怎样判断一个txt文件是否为空？

我有个系统，会生成一个文件“D：\aa.txt”
这个文件会被经常改写，有时为空（即：0字节），有时有内容（即：大于0字节）

我想用批处理来判断：若该文件为空，则执行"A.exe";
                              若该文件不为空，则执行"B.exe”

谢谢！

batman 发表于 2011-3-25 11:05

[code]
@echo off
set "paths=d:\a.txt"
for %%a in ("%paths%") do (
     if "%%~za" equ "0" (
        start "" "完整路径(a.exe)"
        ) else (
        start "" "完整路径(b.exe)"
     )
)
[/code]

zidian5 发表于 2011-3-25 11:26

[b] [url=http://www.bathome.net/redirect.php?goto=findpost&pid=73699&ptid=11601]2#[/url] [i]batman[/i] [/b]


非常感谢，已经解决了！

dashige 发表于 2011-3-25 11:35

equ "0"
哈哈。。。。

wc726842270 发表于 2011-3-25 12:32

无聊用WMIC写一个，当然不如用2L的方法好。
PS：空格真是上火，找了N久才发现[code]
@echo off
set /p #a=请指定文件:
for %%i in (%#a%) do set #d=%%~di&set #p=%%~pi &set #n=%%~ni& set #e=%%~xi
set b=%#p:\=\\%
set c=%b:~0,-1%
set x=%#e:~1,-1%
wmic datafile where "drive='%#d%' and path='%c%' and filename='%#n%' and extension='%x%'" get filesize
pause
[/code]

hbwazxf 发表于 2011-3-25 13:01

新人学习。感谢2楼的方法

CrLf 发表于 2011-3-25 13:08

方法很多，
方法一：
findstr .* a.txt&&a.exe||b.exe
方法二：
for %%a in (a.txt) do if %%~za==0 (a.exe) else b.exe
方法三：
cd.>tmp
fc tmp a.txt&&a.exe||b.exe
方法四：
wmic...
::详见5楼
方法五：
vbs...
::但是我只知道有，不清楚怎么写
方法六：
for /f "eol=" %%a in (a.txt) do set tmp=1
if defined tmp (a.exe) else b.exe
::忽略空行

当然还可以写出很多引申的办法，就不一一列举了

dahual 发表于 2011-3-25 13:31

以前不知道此用法，这下好了。:lol学习帖。[code]
另外，FOR 变量参照的替换已被增强。您现在可以使用下列
选项语法:

     %~I          - 删除任何引号(")，扩展 %I
     %~fI        - 将 %I 扩展到一个完全合格的路径名
     %~dI        - 仅将 %I 扩展到一个驱动器号
     %~pI        - 仅将 %I 扩展到一个路径
     %~nI        - 仅将 %I 扩展到一个文件名
     %~xI        - 仅将 %I 扩展到一个文件扩展名
     %~sI        - 扩展的路径只含有短名
     %~aI        - 将 %I 扩展到文件的文件属性
     %~tI        - 将 %I 扩展到文件的日期/时间
     %~zI        - 将 %I 扩展到文件的大小
     %~$PATH:I   - 查找列在路径环境变量的目录，并将 %I 扩展
                   到找到的第一个完全合格的名称。如果环境变量名
                   未被定义，或者没有找到文件，此组合键会扩展到
                   空字符串

可以组合修饰符来得到多重结果:

     %~dpI       - 仅将 %I 扩展到一个驱动器号和路径
     %~nxI       - 仅将 %I 扩展到一个文件名和扩展名
     %~fsI       - 仅将 %I 扩展到一个带有短名的完整路径名
     %~dp$PATH:I - 搜索列在路径环境变量的目录，并将 %I 扩展
                   到找到的第一个驱动器号和路径。
     %~ftzaI     - 将 %I 扩展到类似输出线路的 DIR
[/code]

tmplinshi 发表于 2011-3-25 16:47

[quote]方法六：
for /f "eol=" %%a in (a.txt) do set tmp=1
if defined tmp (a.exe) else b.exe
::忽略空行
[size=2][color=#999999]zm900612 发表于 2011-3-25 13:08[/color] [url=http://bathome.net/redirect.php?goto=findpost&pid=73717&ptid=11601][img]http://bathome.net/images/common/back.gif[/img][/url][/size][/quote]
"eol=" 会忽略以双引号开头的行。

页: [1]