poj3020[无向图最小边匹配]

Antenna Placement

Time Limit: 1000MS		Memory Limit: 65536K
Total Submissions: 4461		Accepted: 2194

Description

The Global Aerial Research Centre has been allotted the task of building the fifth generation of mobile phone nets in Sweden. The most striking reason why they got the job, is their discovery of a new, highly noise resistant, antenna. It is called 4DAir, and comes in four types. Each type can only transmit and receive signals in a direction aligned with a (slightly skewed) latitudinal and longitudinal grid, because of the interacting electromagnetic field of the earth. The four types correspond to antennas operating in the directions north, west, south, and east, respectively. Below is an example picture of places of interest, depicted by twelve small rings, and nine 4DAir antennas depicted by ellipses covering them. 
 
Obviously, it is desirable to use as few antennas as possible, but still provide coverage for each place of interest. We model the problem as follows: Let A be a rectangular matrix describing the surface of Sweden, where an entry of A either is a point of interest, which must be covered by at least one antenna, or empty space. Antennas can only be positioned at an entry in A. When an antenna is placed at row r and column c, this entry is considered covered, but also one of the neighbouring entries (c+1,r),(c,r+1),(c-1,r), or (c,r-1), is covered depending on the type chosen for this particular antenna. What is the least number of antennas for which there exists a placement in A such that all points of interest are covered? 

Input

On the first row of input is a single positive integer n, specifying the number of scenarios that follow. Each scenario begins with a row containing two positive integers h and w, with 1 <= h <= 40 and 0 < w <= 10. Thereafter is a matrix presented, describing the points of interest in Sweden in the form of h lines, each containing w characters from the set ['*','o']. A '*'-character symbolises a point of interest, whereas a 'o'-character represents open space. 

Output

For each scenario, output the minimum number of antennas necessary to cover all '*'-entries in the scenario's matrix, on a row of its own.

Sample Input

2
7 9
ooo**oooo
**oo*ooo*
o*oo**o**
ooooooooo
*******oo
o*o*oo*oo
*******oo
10 1
*
*
*
o
*
*
*
*
*
*

Sample Output

17
5

Source

Svenskt Mästerskap i Programmering/Norgesmesterskapet 2001
======================================================================================================
构图，无向图最小边覆盖=|P|-二分图最大匹配/2;
Code:

program poj3020;

const
di:array[1..4] of longint=(1,0,0,-1);
dj:array[1..4] of longint=(0,1,-1,0);

var
g:array[1..400,1..400] of boolean;
from:array[1..400] of longint;
cover:array[1..400] of boolean;
map:array[1..40,1..10] of longint;
n:longint;

function Find(u:longint):boolean;
var i,q:longint;
begin
     for i:=1 to n do
     if (g[u,i])and(not cover[i]) then begin
        cover[i]:=true;
        q:=from[i]; from[i]:=u;
        if (q=0)or(Find(q))then exit(true);
        from[i]:=q;
     end;
     exit(false);
end;
function Ed:longint;
var i:longint;
begin
     fillchar(from,sizeof(from),0);
     Ed:=0;
     for i:=1 to n do begin
         fillchar(cover,sizeof(cover),false);
         if Find(i) then inc(Ed);
     end;
end;

procedure Scan;
var i,j,k,ii,jj,h,w:longint; ch:char;
begin
     n:=0;
     readln(h,w);
     for i:=1 to h do begin
         for j:=1 to w do begin
             read(ch);
             if ch='*' then begin
                inc(n); map[i,j]:=n;
             end else map[i,j]:=0;
         end;
         readln;
     end;

     fillchar(g,sizeof(g),false);

     for i:=1 to h do
     for j:=1 to w do
     if map[i,j]<>0 then
     for k:=1 to 4 do begin
         ii:=i+di[k];
         jj:=j+dj[k];
         if (ii>=1)and(ii<=h)and(jj>=1)and(jj<=w) then
            if map[ii,jj]<>0 then begin
               g[map[i,j],map[ii,jj]]:=true;
            end;
     end;
end;

procedure Main;
var caseno:longint;
begin
     readln(caseno);
     while caseno>0 do begin
           dec(caseno);
           Scan;
           writeln(n-(Ed shr 1));
     end;
end;

begin
     assign(input,'poj3020.in'); reset(input);
     assign(output,'poj3020.out'); rewrite(output);

     Main;

     close(input); close(output);
end.