使用SQL函数[Split]分割字符串，并放入内存表中

最新推荐文章于 2022-02-22 14:13:14 发布

原创最新推荐文章于 2022-02-22 14:13:14 发布 · 650 阅读

0 ·

CC 4.0 BY-SA版权

文章标签：

#sql #input #function #insert #table #fun

SQL Server 专栏收录该内容

43 篇文章

订阅专栏

本文详细介绍了如何通过创建表值函数来解决SQL查询中ID为INT类型但参数@uid为字符串的问题。具体展示了使用表值函数Split将字符串拆分为多个值，并通过实例演示了如何将这些值应用于查询中，最终实现根据ID集合获取对应的数据。同时，文章提供了一种简化版的Split函数实现方式，进一步优化了代码效率。

今天遇到一个SQL方法的编写，需要使用到 SELECT * FROM USER WHERE ID IN(@uid)
@uid为字符串，但是ID是INT类型，无法编译运行，需要使用下面的函数

 表值函数 所以需要像访问表那样访问

CREATE FUNCTION [dbo].[Split]
(
    @Input varchar(4000), -- 输入字符串
    @Separator varchar(4000) = '.' -- 分隔符
)
RETURNS 
@Result TABLE 
(
    Value varchar(4000)
)
AS
BEGIN

DECLARE @InputLength int;
SET @InputLength = LEN(@Input);
DECLARE @SeparatorLength int;
SET @SeparatorLength = LEN(@Separator);
DECLARE @LastIndex int;
SET @LastIndex = 0;
DECLARE @CurrentIndex int;
SET @CurrentIndex = -1;

WHILE @CurrentIndex != 0
BEGIN
    SET @CurrentIndex = CHARINDEX(@Separator, @Input, @LastIndex );

    IF @CurrentIndex != 0
        INSERT @Result
        (
            Value
        )
        VALUES
        (
            SUBSTRING(@Input, @LastIndex, @CurrentIndex - @LastIndex)
        )
    ELSE
        INSERT @Result
        (
            Value
        )
        VALUES
        (
            SUBSTRING(@Input, @LastIndex, @InputLength + 1 - @LastIndex)
        )

    SET @LastIndex = @CurrentIndex + @SeparatorLength;
END

RETURN 

END

GO

select * from  [dbo].[Split]('12,2,3,4,5,6,7',',')

Value                                                                                                                                                                                                                                                            
-------------------------------------------------------------------------------------
12
2
3
4
5
6
7

（所影响的行数为 7 行）

 drop FUNCTION [dbo].[Split]

--经网友修改后方法(精简版)

ALTER FUNCTION [dbo].[Split]
(
    @Input varchar(4000), -- 输入字符串
    @Separator varchar(4000) = '.' -- 分隔符
)
RETURNS @Result TABLE 
(
    [Value] varchar(4000)
)
AS
BEGIN
DECLARE @i INT
SELECT @i=CHARINDEX(@Separator,@Input)
WHILE  @i>0
    BEGIN
        INSERT @Result VALUES(LEFT(@Input,@i-LEN(@Separator)))
        SELECT @Input=STUFF(@Input,1,@i,''),@i=CHARINDEX(@Separator,@Input)
    END
INSERT @Result VALUES(@Input)
RETURN 
END

拼接SQL字符串字段根据用户的ID,[1|2|3|4|] 返回名字的集合['张三|李四|王武|王麻子|']

CREATE FUNCTION FUN_GetNamesByIds
(
@Ids NVARCHAR(50)
)
RETURNS NVARCHAR(100)
AS
BEGIN
DECLARE @Names NVARCHAR(100) SET @Names=''
SELECT @Names=@Names+RealName+'|' FROM Employee WHERE PKID IN
 (SELECT * FROM Split(@Ids,'|'))
return @Names
END