在setclasspath.bat文件中设置tomcat环境变量

以前一直都 是在IDE中启动tomcat，今天为了方便就直接在运行startup.bat启动，突然就一闪而过了，我还以为启动完成了，在地址栏输入http://localhost:8080还是找不到页面，再去启动了几次还是一样，然后在cmd找到tomcat目录启启动，错误出来了：Neither the JAVA_HOME nor the JRE_HOME environment variable is defined At least one of these environment variable is needed to run this program;提示找不到java_home各jre_home路径，看了一下startup.bat的代码发现调用了catalina.bat,而catalina.bat调用setclasspath.bat，在头部定义了JAVA_HOME和JRE_HOME的值就可以不用在系统那里设置变量了：

rem ---------------------------------------------------------------------------
rem Set CLASSPATH and Java options
rem
rem $Id: setclasspath.bat 505241 2007-02-09 10:22:58Z jfclere $
rem ---------------------------------------------------------------------------

 

set JAVA_HOME=C:/Program Files/Java/jdk1.5.0_05
set JRE_HOME=C:/Program Files/Java/jre1.5.0_05

 

rem Make sure prerequisite environment variables are set
if not "%JAVA_HOME%" == "" goto gotJdkHome
if not "%JRE_HOME%" == "" goto gotJreHome
echo Neither the JAVA_HOME nor the JRE_HOME environment variable is defined
echo At least one of these environment variable is needed to run this program
goto exit

:gotJreHome
if not exist "%JRE_HOME%/bin/java.exe" goto noJavaHome
if not exist "%JRE_HOME%/bin/javaw.exe" goto noJavaHome
if not ""%1"" == ""debug"" goto okJavaHome
echo JAVA_HOME should point to a JDK in order to run in debug mode.
goto exit

:gotJdkHome
if not exist "%JAVA_HOME%/bin/java.exe" goto noJavaHome
if not exist "%JAVA_HOME%/bin/javaw.exe" goto noJavaHome
if not exist "%JAVA_HOME%/bin/jdb.exe" goto noJavaHome
if not exist "%JAVA_HOME%/bin/javac.exe" goto noJavaHome
if not "%JRE_HOME%" == "" goto okJavaHome
set JRE_HOME=%JAVA_HOME%
goto okJavaHome

:noJavaHome
echo The JAVA_HOME environment variable is not defined correctly
echo This environment variable is needed to run this program
echo NB: JAVA_HOME should point to a JDK not a JRE
goto exit
:okJavaHome

if not "%BASEDIR%" == "" goto gotBasedir
echo The BASEDIR environment variable is not defined
echo This environment variable is needed to run this program
goto exit
:gotBasedir
if exist "%BASEDIR%/bin/setclasspath.bat" goto okBasedir
echo The BASEDIR environment variable is not defined correctly
echo This environment variable is needed to run this program
goto exit
:okBasedir

rem Set the default -Djava.endorsed.dirs argument
set JAVA_ENDORSED_DIRS=%BASEDIR%/endorsed

rem Set standard CLASSPATH
rem Note that there are no quotes as we do not want to introduce random
rem quotes into the CLASSPATH
if not exist "%JAVA_HOME%/bin/tools.jar" goto noJavac
set CLASSPATH=%JAVA_HOME%/lib/tools.jar
:noJavac

rem Set standard command for invoking Java.
rem Note that NT requires a window name argument when using start.
rem Also note the quoting as JAVA_HOME may contain spaces.
set _RUNJAVA="%JRE_HOME%/bin/java"
set _RUNJAVAW="%JRE_HOME%/bin/javaw"
set _RUNJDB="%JAVA_HOME%/bin/jdb"
set _RUNJAVAC="%JAVA_HOME%/bin/javac"

goto end

:exit
exit /b 1

:end