Soildity之示例合约分析（7）

之前有同事转行做区块链钱包方面的开发，在18年上半年币市大伙的时候，在以太坊主链上部署了一个智能合约发行代码，今天就通过 https://etherscan.io/ 网站通过智能约合地址来撸一下智能合约的代码，源码如下：

pragma solidity ^0.4.16;

//基类合约
contract Ownable {
    address public owner;

    function Ownable() public {
        owner = msg.sender;
        //构造函数，对owner进行赋值，部署合约的发起方
    }

    modifier onlyOwner()  {
        //函数修改器，调用_;函数体必须满足 msg.sender == owner 条件
        require(msg.sender == owner);
        _;
    }

    function transferOwnership(address newOwner) public onlyOwner {
        if (newOwner != address(0)) {
        	//修改合约的部署方账号地址
            owner = newOwner;
        }
    }

}

contract SafeMath {
    function safeSub(uint a, uint b) pure internal returns (uint) {
    	//针对减法做安全性判断，适用于转账，转账发起方账户余额大于转账金额
        sAssert(b <= a);
        return a - b;
    }

    function safeAdd(uint a, uint b) pure internal returns (uint) {
    	//针对加法做安全性判断，适用于转账，防止大额转账接收方数据溢出
        uint c = a + b;
        sAssert(c>=a && c>=b);
        return c;
    }

    function sAssert(bool assertion) internal pure {
        if (!assertion) {
            revert(); //发生错误，进行状态回滚
        }
    }
}

contract ERC20 {
 	//发现代币的总额
    uint public totalSupply;
    //查询账户代币的余额
    function balanceOf(address who) public constant returns (uint);
    //查询owner账户可对spender账户进行代币转账操作的余额
    function allowance(address owner, address spender) public constant returns (uint);
	
	//转账
    function transfer(address toAcct, uint value) public returns (bool ok);
    function transferFrom(address fromAcct, address toAcct, uint value) public returns (bool ok);
    
    //额度设置函数
    function approve(address spender, uint value) public returns (bool ok);
    
    //定义两个事件，用于通知客户端
    event Transfer(address indexed fromAcct, address indexed toAcct, uint value);
    event Approval(address indexed owner, address indexed spender, uint value);
}

contract StandardToken is ERC20, SafeMath {
	//记录所有账户余额的映射
    mapping(address => uint) balances;
    mapping (address => mapping (address => uint)) allowed;
	
	//转账实现
    function transfer(address _toAcct, uint _value) public returns (bool success) {
        balances[msg.sender] = safeSub(balances[msg.sender], _value);
        balances[_toAcct] = safeAdd(balances[_toAcct], _value);
        //触发事件
        Transfer(msg.sender, _toAcct, _value);
        return true;
    }
	
	//转账实现
    function transferFrom(address _fromAcct, address _toAcct, uint _value) public returns (bool success) {
    	//获取账户能够进行转账的额度
        var _allowance = allowed[_fromAcct][msg.sender];
        
        //进行转账相关账户余额的安全性验证
        balances[_toAcct] = safeAdd(balances[_toAcct], _value);
        balances[_fromAcct] = safeSub(balances[_fromAcct], _value);
        
        //对可进行转账的余额进行修改
        allowed[_fromAcct][msg.sender] = safeSub(_allowance, _value);
		
		//触发事件
        Transfer(_fromAcct, _toAcct, _value);
        return true;
    }
	
	//查询账户余额
    function balanceOf(address _owner) public constant returns (uint balance) {
        return balances[_owner];
    }

    function approve(address _spender, uint _value) public  returns (bool success) {
    	//设置msg.sender可以对_spender账户进行代币转账的总额度
        allowed[msg.sender][_spender] = _value;
        //触发事件
        Approval(msg.sender, _spender, _value);
        return true;
    }
	
	//查询可进行代币转账的余额
    function allowance(address _owner, address _spender) public constant returns (uint remaining) {
        return allowed[_owner][_spender];
    }

}

contract BcnCoin is Ownable, StandardToken {

    string public name;
    string public symbol;
    uint public decimals;                  
    uint public totalSupply;  
	
	//构造函数，对代币进行初始化配置
    function BcbCoin() public {
        totalSupply = 2000 * (10**6) * (10**18); 
        balances[msg.sender] = totalSupply;
        name = "BCN";
        symbol = "BCN";
        decimals = 18;  
    }
	
	//可接收以太币转账的fallback函数
    function () payable public{
    }

    //代币发行方进行账户变更
    function transferOwnership(address _newOwner) public onlyOwner {
        balances[_newOwner] = safeAdd(balances[owner], balances[_newOwner]);
        balances[owner] = 0;
        Ownable.transferOwnership(_newOwner);
    }

    // Owner can transfer out any ERC20 tokens sent in by mistake
    function transferAnyERC20Token(address tokenAddress, uint amount) public onlyOwner returns (bool success)
    {
        return ERC20(tokenAddress).transfer(owner, amount);
    }

}

以上是对源码的全部解释。看完也感觉合约也不是那样的神秘，其实也就是一段代码！
推荐一个比较全面的合约代码：https://www.jianshu.com/p/0d0dd2f09c99