Vim自定义函数之正则表达式匹配

初衷是实现一个Vim插件，能够帮助将C++中h头文件中声明的方法自动实现到cpp实现文件中（我所知道的c.vim实现得并不如我意思，eclipse中source菜单中实现得很好），其中用到需要解析当前光标所在行，如：

需要将

void sayHello(int msg,string buffer);

转化为

void Hello::sayHello(int msg,string msg2){

}

必须解析出其中的返回值 函数名称，参数等部分，采用vim内置函数可以解决，因为正则表达式和一般写法略有不同，已做备忘,比如其中

()需要添加天添加\       \(\)

[]不用

{}需要写成\{\}

?需要写成\?

matchlist('Hello World(int msg,string msg2)', '\(.*\)\s\+\(.*\)\s*(\(.*\));')

该函数返回一个列表

['Hello World(int msg,string msg2);', 'Hello', 'World', 'int msg,string msg2', '', '', '', '', '', '']

可以解析该返回列表继续。

完整插件如下（需要安装切换头文件和实现文件的插件a.vim）

if exists("loaded_generate_impl_corey")
        finish  
endif
let loaded_generate_impl_corey=1
 
function <SID>GetClassName(lineNum)
        let tmplinenum=a:lineNum
        while tmplinenum>0
                let tmplinenum-=1
                let tmpline=getline(tmplinenum)
                let clslist=matchlist(tmpline,'\s*class\s*\(\S*\)\s*.*')
                if stridx(tmpline,'class ')>=0
                        return get(clslist,1)
                endif   
        endwhile
        return ""
endfunction


function <SID>ToImpl()
        let s:curline=getline(line("."))
        let s:flist= matchlist(s:curline, '\s*\(.*\)\s\+\(.*\)\s*(\(.*\));')
        if strlen(get(s:flist,0))== 0 || strlen(get(s:flist,2))== 0
                echo "this is not a function"
                return  
        endif   
        let s:rtn=get(s:flist,1)
        if s:rtn=='virtual'
                let s:rtn=""
        endif   
        let s:method=get(s:flist,2)
        let s:args=get(s:flist,3)
        let s:classname=<SID>GetClassName(line("."))
        let s:implclause="\n\t".s:rtn . (strlen(s:rtn)==0?"":" ") .s:classname."::". s:method . "(". s:args . ")" . "{" . "\n" ."\n"."\t"."}"
        call setreg('',s:implclause)
        execute ":A" 
        execute "normal G"
        execute "normal p"
        call cursor(line(".")+2,0)
endfunction     

nnoremap zz :call <SID>ToImpl()<CR>