Excel-将表格数据按某一列的值拆分成若干个文件

在处理表格数量时，有时候会遇到这样的需求，需要将一张表格，按照其中一列的值，分类拆分成若干个表格。
如下图，将按不同的部门，将这个表拆分成一个部门一个excel文件。

分类筛选，复制粘贴，纯手工打造，完全可以实现。但是如果就一点数据，还可以，如果数量量大呢？操作到让你怀疑人生。
用python可以实现吗？当然可以，但是不是每个人都会python，不是每个电脑都有python运行环境。
那就用VB实现吧，建一个宏，运行一下，就搞定了。
以上面截图为例：
1、把要处理的表格按部门排序。
2、按 Alt+F11，打开VB工作界面，依次点击【插入】-【模块】
3、把下面的代码复制，粘贴到新建的模块中，保存，然后关闭VB。

Sub 带表头拆分数据为若干新文件()
    Dim arr, d As Object, k, t, i&, lc%, rng As Range, c%
    c = Application.InputBox("请输入拆分列号", , 4, , , , , 1)
    If c = 0 Then Exit Sub
    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
    arr = [a1].CurrentRegion
    lc = UBound(arr, 2)
    Set rng = [a1].Resize(, lc)
    Set d = CreateObject("scripting.dictionary")
    For i = 2 To UBound(arr)
        If Not d.Exists(arr(i, c)) Then
            Set d(arr(i, c)) = Cells(i, 1).Resize(1, lc)
        Else
            Set d(arr(i, c)) = Union(d(arr(i, c)), Cells(i, 1).Resize(1, lc))
        End If
    Next
    k = d.Keys
    t = d.Items
    For i = 0 To d.Count - 1
        With Workbooks.Add(xlWBATWorksheet)
            rng.Copy .Sheets(1).[a1]
            t(i).Copy .Sheets(1).[a2]
            .SaveAs Filename:=ThisWorkbook.Path & "\" & k(i) & ".xls"
            .Close
        End With
    Next
    Application.DisplayAlerts = True
    Application.ScreenUpdating = True
    MsgBox "拆分完毕，请在当前文件目录下查看！"
End Sub

4、在需要处理的表格中，依次点击【开发工具】-【插入】，选择第一个表单控件【按钮（窗体控件）】，然后在表格中画一个按钮控件，在弹出的指定宏中，选择刚建的宏，确定。如下图：

然后点击按钮，输入指定值所在列，示例中是部门一列，所以输入 4 确定。等待完成的提示即可。