【vbs脚本】02.高级

例子01、使用默认浏览器打开百度。

Dim objShell
Set objShell = CreateObject("Wscript.Shell")
objShell.Run("http://www.baidu.com/")

例子02、结束进程

Dim strComputer, objWMIService, colProcessList, objProcess
strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colProcessList = objWMIService.ExecQuery("Select * from Win32_Process Where Name = 'notepad.exe'")
For Each objProcess in colProcessList
	objProcess.Terminate()
Next

例子03、获取网卡MAC地址

Dim objMc, objMo

Set objMc = GetObject("Winmgmts:").InstancesOf("Win32_NetworkAdapterConfiguration")
For Each objMo In objMc
    If ObjMo.IpEnabled = True Then
    	MsgBox "本机网卡MAC地址是:" & objMo.MacAddress
    	Exit For
    End If
Next

例子04、列出系统所用进程

Dim objWMIService, objProc, objProcs, stEnum
Set objWMIService = GetObject("WinMgmts:")
Set objProcs = objWMIService.InstancesOf("Win32_Process")

For Each objProc In objProcs
	strEnum = strEnum + objProc.Description + chr(13) + chr(10)
Next

msgbox strEnum

例子05、获取计算机信息

On Error Resume Next
strComputer = "."
strInfo = ""

Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")

Set colItems = objWMIService.ExecQuery("select * from Win32_BIOS", , 48)

For Each objItem in colItems
    strInfo = strInfo & "SerialNumber: " & objItem.SerialNumber & vbCrLf
Next

Set colItems = objWMIService.ExecQuery("select * from Win32_ComputerSystem", , 48)
For Each objItem in colItems
    strInfo = strInfo & "UserName: " & objItem.UserName & vbCrLf
    strInfo = strInfo & "ComputerName: " & objItem.Name & vbCrLf
    strInfo = strInfo & "Domain: " & objItem.Domain &vbCrLf
    strInfo = strInfo & "Manufacturer: " & objItem.Manufacturer & vbCrLf
    strInfo = strInfo & "Model: " & objItem.Model & vbCrLf
    strInfo = strInfo & "TotalPhysicalMemory: " & Round(objItem.TotalPhysicalMemory/(1024^2), 0) & " M" & vbCrLf
Next

Set colItems = objWMIService.ExecQuery("select * from Win32_Processor", , 48)
For Each objItem in colItems
    If ProcessorNumber = 0 Then
        strInfo = strInfo & "ProcessorMaxClockSpeed: " & Round(objItem.MaxClockSpeed/1024, 1) & " G" & vbCrLf
        strInfo = strInfo & "ProcessorName: " & objItem.Name & vbCrLf
    End If
    ProcessorNumber = ProcessorNumber + 1
Next

strInfo = strInfo & "ProcessorNumber: " & ProcessorNumber & vbCrLf

WScript.Echo strInfo

例子06、取得系统所有服务及运行状态

strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer)
Set colServiceSet = objWMIService.InstancesOf("Win32_Service")
Dim objItem, strInfo
strInfo = ""
For Each objItem In colServiceSet
    strInfo = strInfo & objItem.Description + " ==>" + objItem.State + chr(13) + chr(10)
NEXT

msgbox strInfo

'消息对话框显示不全，因此保存为文本文件。
Dim objFso, filInfo
Set objFso = CreateObject("Scripting.FileSystemObject")
Set filInfo = objFso.OpenTextFile("d:\ServicesInfo.txt", 2, True)

filInfo.Write strInfo
filInfo.Close

 例子07、获取CPU序列号

Dim strCpuInfo
strCpuInfo = ""

Set colProcessorSet = GetObject("Winmgmts:").InstancesOf("Win32_Processor")
For Each objItem in colProcessorSet
    strCpuInfo = CStr(objItem.ProcessorId)
    msgbox "CPU SerialNumber is: " & strCpuInfo
Next

08、获取硬盘序列号

Dim strHDId, colDiskDriveSet

Set colDiskDriveSet = GetObject("Winmgmts:").InstancesOf("Win32_DiskDrive")
'多块硬盘会弹出多个消息对话框
For Each objItem In colDiskDriveSet
    strHDId = objItem.Model
    msgbox "硬盘序列号为：" & strHDId
Next

09、获取显卡信息

On Error Resume Next
Dim colVideoControllerSet, objItem

Set colVideoControllerSet = GetObject("winmgmts:{impersonationLevel=impersonate}").InstancesOf("Win32_VideoController")
For Each objItem In colVideoControllerSet
    msgbox "型号：" & objItem.VideoProcessor & vbCrLf _
    & "厂商：" & objItem.AdapterCompatibility & vbCrLf _
    & "名称：" & objItem.Name & vbCrLf _
    & "状态：" & objItem.Status & vbCrLf _
    & "显存：" & (objItem.AdapterRAM \ 1024000) & "MB" & vbCrLf _
    & "驱动（dll）：" & objItem.InstalledDisplayDrivers & vbCrLf _
    & "驱动（inf）：" & objItem.infFilename & vbCrLf _
    & objItem.DriverVersion
Next