Flex 3使用代码分离构建自定义组件

本文介绍如何在Flex开发中采用代码分离技术,通过结合MXML和ActionScript实现组件化开发。详细解析了从数据模型到视图展示的过程,包括事件处理和组件间的通信。

 

在创建组件时,MXMLActionScript语言有不同的优点和缺点。

·         当你创建一个创建一个符合组件,MXML使得它容易被创建和安置子组件。

·         当你修改组件的行为,也就是说,覆盖他的方法,那么应该使用ActionScript


大多数时间,当创建组件和应用时,同时使用MXMLActionScriptFlex提供几种同时使用MXMLActionScript的途径,包含如下:

·         MXML标记中放置ActionScript代码声明,这使用于内联事件处理

·         <mx:Script>标记中放置ActionScript代码。

·         使用<mx:Script>标记的source属性引入外部ActionScript文件。

·         使用MXML安置组件,把ActionScript代码放在一个类定义中。这种方式被叫做代码分离


要代码behind使用连接ActionScriptMXML,需要让ActionScript类作为MXML组件的更标记。也就是说,MXML组件扩展ActionScript类。

例如,要实现自定义AddressForm组件(显示符合地址登记表),你需要做如下事情:
1
创建一个叫做AddressFormClassActionScript类。你可以使这个类扩展基本的Flex类。既然这样,使用Form容器的布局能力并且使AddressFormClass扩展mx.contain.form 类。
2
创建一个命名为AddressFormMXML组件,并且事他的更标记是AddressFormClass
3
使用MXML布局AddressForm组件的内容
4
使用ActionScript来创建AddressForm组件的逻辑。


提示:你必须声明子组件为公共属性,在ActionScript类中


在下边的例子包含了自定义的AddressForm组件。主程序文件也利用了代码behind,并且这个例子也包含CountryComboxPaddedPanel组件,这些在其他指导中创建的组件。
连接:在构建Flex应用程序时,这被认为是最佳实践架构的引论。更多的信息,查看Arp framework——一个开源的模式基础框架,用来创建FlashFlex应用程序,他使用了代码分离。

数据模型

components/AddressVO.as


package components

{

    public class AddressVO

    {

        // We are using public properties for the

        // value object to keep this example short. In a


        // real-world application, make these properties

        // private and use implicit accessors to expose them

        // so you can do validation, etc. if necessary.

        public var name:String;

        public var street:String;

        public var city:String;

        public var state:String;

        public var country:String;

    }


}

事件模型,定义事件类型和事件对应的数据

components/AddressFormEvent.as

package components

{

    import flash.events.Event;

    import components.AddressVO;


    public class AddressFormEvent extends Event

    {


        public static const SUBMIT:String = "submit";


        private var _data:AddressVO;


        public function AddressFormEvent (eventName:String)


        {

            super (eventName);

        }

       

        public function set data (value:AddressVO):void


        {

            _data = value;

        }

       

        public function get data ():AddressVO

        {


            return _data;

        }

    }

}           

定义视图的模型,处理事件

components/AddressFormClass.as

package components
{
    import mx.events.FlexEvent;
    import mx.controls.Button;
    import mx.controls.TextInput;
    import flash.events.MouseEvent;
    import mx.containers.Form;
   
    public class AddressFormClass extends Form
    {

        // Components in the MXML must be
        // declared public. This is a limitation in
        // the current version of Flex and may change
        // in the future.
        public var submitButton:Button;
        public var nameInput:TextInput;
        public var street:TextInput;
        public var city:TextInput;
        public var state:TextInput;
        public var country:CountryComboBox;
       
        // Constructor

        public function AddressFormClass ():void
        {
            addEventListener(FlexEvent.CREATION_COMPLETE, creationCompleteHandler);
        }

       
        // Creation complete is a good time to add event listeners and
        // interact with child components.
        private function creationCompleteHandler (event:FlexEvent):void

        {
            submitButton.addEventListener(MouseEvent.CLICK, submitHandler);
        }
       
        // Gets called when the Submit button is clicked
        private function submitHandler (event:MouseEvent):void

        {
            // Gather the data for this form
            var addressVO:AddressVO = new AddressVO();
            addressVO.name = nameInput.text;
            addressVO.street = street.text;
            addressVO.city = city.text;
            addressVO.state = state.text;
            addressVO.country = country.selectedItem as String;
                       
            var submitEvent:AddressFormEvent = new AddressFormEvent(AddressFormEvent.SUBMIT);
            submitEvent.data = addressVO;
                       
            // Dispatch an event to signal that the form has been submitted

            dispatchEvent(submitEvent);
        }
    }

视图的页面层,这里使用了上面的页面模型

components/AddressForm.mxml

<?xml version="1.0" encoding="utf-8"?>
<custom:AddressFormClass
    xmlns:mx="
http://www.adobe.com/2006/mxml"
    xmlns:custom="components.*">
   <mx:FormItem label="Name">
        <mx:TextInput id="nameInput"/>
    </mx:FormItem>

    <mx:FormItem label="Street">
        <mx:TextInput id="street"/>
    </mx:FormItem>

    <mx:FormItem label="City">
        <mx:TextInput id="city"/>
    </mx:FormItem>

    <mx:FormItem label="State/County">
        <mx:TextInput id="state"/>
    </mx:FormItem>

    <mx:FormItem label="Country">
        <custom:CountryComboBox id="country"/>

    </mx:FormItem>
  
    <mx:Button
        id="submitButton"
        label="Submit"
    />
</custom:AddressFormClass>
 

 

应用层的模型:

components/ApplicationClass.as


package components

{

    import mx.core.Application;

    import mx.events.FlexEvent;

    import mx.controls.Alert;

   

    import components.AddressFormEvent;

    import components.AddressVO;

    import flash.utils.describeType;

   

    public class ApplicationClass extends Application

    {


        // Components in MXML

        public var addressForm:AddressForm;

       

        public function ApplicationClass()


        {

            addEventListener (FlexEvent.CREATION_COMPLETE, creationCompleteHandler);

        }

       

        //

        // Event handlers

        //


        private function creationCompleteHandler(event:FlexEvent):void

        {


            // The custom AddressForm component dispatches a "submit"

            // event the form is submitted. Listen for this.

            addressForm.addEventListener(AddressFormEvent.SUBMIT, submitHandler);

        }

       

        private function submitHandler(event:AddressFormEvent):void


        {

            // Get the value object (data) from the event object

            var data:AddressVO = event.data as AddressVO;

                                   

            // Compose a string to display the contents of the value object to the user.


            var msg:String = "You submitted the following information: /r";

           

            // Use the new introspection API and E4X to get a list of the properties

            // in the data object and enumerate over them to compose the string.

            var dataProperties:XMLList = describeType(data)..variable;

           

            for each (var i:XML in dataProperties)

            {


                var propertyName:String =
i.@name;

                msg += i.@name + ": " + data[i.@name] + "/r";

            }


            // Display the contents of the address form to the user.

            Alert.show(msg, "Thank you for submitting the form!");

        }

    }

应用层的视图

应用程序 MXML 文件

<?xml version="1.0" encoding="utf-8"?>

<custom:ApplicationClass

    xmlns:custom="components.*"


    viewSourceURL="src/CodeBehind/index.html"

    width="400" height="310"

    <custom:PaddedPanel title="Code Behind">


        <custom:AddressForm id="addressForm"/>

    </custom:PaddedPanel>

</custom:ApplicationClass>

 

 

消息流:

用户提交的数据—>submitButton监听到,调用AddressFormClass中的sumbitHandler函数处理,封装的数据到AddressFormEvent中,并转发事件,被注册了AddressFormEventAddressForm监听到,调用ApplicationClass中的submitHandler进行处理。

这个完成了sumbitButton的事件到AddressForm的完美封装。

其中,sumbitButton的事件只负责收集页面的原始数据。而AddressForm的事件才是真正意义上这个自定义控件的事件。

标题SpringBoot智能在线预约挂号系统研究AI更换标题第1章引言介绍智能在线预约挂号系统的研究背景、意义、国内外研究现状及论文创新点。1.1研究背景与意义阐述智能在线预约挂号系统对提升医疗服务效率的重要性。1.2国内外研究现状分析国内外智能在线预约挂号系统的研究与应用情况。1.3研究方法及创新点概述本文采用的技术路线、研究方法及主要创新点。第2章相关理论总结智能在线预约挂号系统相关理论,包括系统架构、开发技术等。2.1系统架构设计理论介绍系统架构设计的基本原则和常用方法。2.2SpringBoot开发框架理论阐述SpringBoot框架的特点、优势及其在系统开发中的应用。2.3数据库设计与管理理论介绍数据库设计原则、数据模型及数据库管理系统。2.4网络安全与数据保护理论讨论网络安全威胁、数据保护技术及其在系统中的应用。第3章SpringBoot智能在线预约挂号系统设计详细介绍系统的设计方案,包括功能模块划分、数据库设计等。3.1系统功能模块设计划分系统功能模块,如用户管理、挂号管理、医生排班等。3.2数据库设计与实现设计数据库表结构,确定字段类型、主键及外键关系。3.3用户界面设计设计用户友好的界面,提升用户体验。3.4系统安全设计阐述系统安全策略,包括用户认证、数据加密等。第4章系统实现与测试介绍系统的实现过程,包括编码、测试及优化等。4.1系统编码实现采用SpringBoot框架进行系统编码实现。4.2系统测试方法介绍系统测试的方法、步骤及测试用例设计。4.3系统性能测试与分析对系统进行性能测试,分析测试结果并提出优化建议。4.4系统优化与改进根据测试结果对系统进行优化和改进,提升系统性能。第5章研究结果呈现系统实现后的效果,包括功能实现、性能提升等。5.1系统功能实现效果展示系统各功能模块的实现效果,如挂号成功界面等。5.2系统性能提升效果对比优化前后的系统性能
在金融行业中,对信用风险的判断是核心环节之一,其结果对机构的信贷政策和风险控制策略有直接影响。本文将围绕如何借助机器学习方法,尤其是Sklearn工具包,建立用于判断信用状况的预测系统。文中将涵盖逻辑回归、支持向量机等常见方法,并通过实际操作流程进行说明。 一、机器学习基本概念 机器学习属于人工智能的子领域,其基本理念是通过数据自动学习规律,而非依赖人工设定规则。在信贷分析中,该技术可用于挖掘历史数据中的潜在规律,进而对未来的信用表现进行预测。 二、Sklearn工具包概述 Sklearn(Scikit-learn)是Python语言中广泛使用的机器学习模块,提供多种数据处理和建模功能。它简化了数据清洗、特征提取、模型构建、验证与优化等流程,是数据科学项目中的常用工具。 三、逻辑回归模型 逻辑回归是一种常用于分类任务的线性模型,特别适用于二类问题。在信用评估中,该模型可用于判断借款人是否可能违约。其通过逻辑函数将输出映射为0到1之间的概率值,从而表示违约的可能性。 四、支持向量机模型 支持向量机是一种用于监督学习的算法,适用于数据维度高、样本量小的情况。在信用分析中,该方法能够通过寻找最佳分割面,区分违约与非违约客户。通过选用不同核函数,可应对复杂的非线性关系,提升预测精度。 五、数据预处理步骤 在建模前,需对原始数据进行清理与转换,包括处理缺失值、识别异常点、标准化数值、筛选有效特征等。对于信用评分,常见的输入变量包括收入水平、负债比例、信用历史记录、职业稳定性等。预处理有助于减少噪声干扰,增强模型的适应性。 六、模型构建与验证 借助Sklearn,可以将数据集划分为训练集和测试集,并通过交叉验证调整参数以提升模型性能。常用评估指标包括准确率、召回率、F1值以及AUC-ROC曲线。在处理不平衡数据时,更应关注模型的召回率与特异性。 七、集成学习方法 为提升模型预测能力,可采用集成策略,如结合多个模型的预测结果。这有助于降低单一模型的偏差与方差,增强整体预测的稳定性与准确性。 综上,基于机器学习的信用评估系统可通过Sklearn中的多种算法,结合合理的数据处理与模型优化,实现对借款人信用状况的精准判断。在实际应用中,需持续调整模型以适应市场变化,保障预测结果的长期有效性。 资源来源于网络分享,仅用于学习交流使用,请勿用于商业,如有侵权请联系我删除!
评论
添加红包

请填写红包祝福语或标题

红包个数最小为10个

红包金额最低5元

当前余额3.43前往充值 >
需支付:10.00
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明:

1.余额是钱包充值的虚拟货币,按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载,可以购买VIP、付费专栏及课程。

余额充值