noip2007初赛-棋盘覆盖

最新推荐文章于 2024-03-23 12:52:47 发布

编程老头

最新推荐文章于 2024-03-23 12:52:47 发布

阅读量929

点赞数

分类专栏：竞赛真题全国信息学奥林匹克竞赛

本文链接：https://blog.youkuaiyun.com/sjtu081200/article/details/47907243

版权

全国信息学奥林匹克竞赛同时被 2 个专栏收录

26 篇文章

订阅专栏

竞赛真题

19 篇文章

订阅专栏

博客介绍了2007年NOIP竞赛中的一个棋盘覆盖问题，其中棋盘由2k*2k个方格组成，只有一个特殊方格。解决方法使用L型纸片覆盖所有非特殊方格，数量为(4^k-1)/3。文章提到的程序采用分治策略，将棋盘四等分并递归处理。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

noip2007C_4_2（棋盘覆盖问题）在一个2k*2k个方格组成的棋盘中恰有一个方格与其他方格不同（图中标记为-1的方格），称之为特殊方格。现用L型（占3个小格）纸片覆盖棋盘上除特殊方格的所有部分，各纸片不得重叠，于是，用到的纸片数恰好是(4^k−1)/3。在下表给出的一个覆盖方案中，k=2，相同的3个数字构成一个纸片。下面给出的程序是用分治法设计的，将棋盘一分为四，依次处理左上角、右上角、左下角、右下角，递归进行。请将程序补充完整。

type
arr1=array[1..65] of integer;
arr2=array[1..65] of arr1;

var
board:arr2;
tile:integer;
size,dr,dc:integer;

procedure chessboard(tr,tc:integer;dr,dc:integer;var size:integer);
var
t,s:integer;
begin
	if (size=1) then exit;
	t:=tile;
	inc(tile);
	s:=size div 2;
	if (dr<tr+s) and (dc<tc+s) then chessboard(tr,tc,dr,dc,s)
	//如果残点在左上角
	else
	begin
		board[tr+s-1][tc+s-1]:=t;//取右下角为新残点
		chessboard(tr,tc,tr+s-1,tc+s-1,s);
	end;
	if (dr<tr+s) and (dc>=tc+s) then chessboard(tr,tc+s,dr,dc,s)
	//如果残点在右上角
	else
	begin
		board[tr+s-1][tc+s]:=t;//取左下角为新残点
		chessboard(tr,tc+s,tr+s-1,tc+s,s);
	end;
	if (dr>=tr+s) and (dc<tc+s) then chessboard(tr+s,tc,dr,dc,s)
	else
	begin
		board[tr+s][tc+s-1]:=t;
		chessboard(tr+s,tc,tr+s,tc+s-1,s);
	end;
	if (dr>=tr+s) and (dc>=tc+s) then chessboard(tr+s,tc+s,dr,dc,s)
	else
	begin
		board[tr+s][tc+s]:=t;
		chessboard(tr+s,tc+s,tr+s,tc+s,s);
	end;
end;

procedure prt1(n:integer);
var
i,j:integer;
begin
	for i:=1 to n do
	begin
		for j:=1 to n do write(board[i][j]:3);
		writeln;
	end;
end;

begin
	writeln('input size(4/8/16/64):');
	readln(size);
	writeln('input the position of special block(x,y):');
	readln(dr,dc);
	board[dr][dc]:=-1;
	tile:=1;
	chessboard(1,1,dr,dc,size);
	prt1(size);
end.