Flash Media Server

么是Flash Media Server ？

Flash大家庭里的一员，以前大概叫Flash Communication Server，传说中的FCS就是这个？现在该叫FMS了吧...
不见不知道哦，一见真可怕，mm还有这么cool的东东，自从见了她，让我做些小东东的兴趣全没了，一心想研究这个

这东东能做什么？

flash聊天室啊，在线视频会议啊啊， 网络游戏？

不管怎样先安个试试吧

先到这里下载免费的开发者版本吧
http://www.macromedia.com/software/flashmediaserver/
然后安装，安装时记得用户名和密码不要瞎填自己要记住，不然好象就要重装喽。。
偶装到了c盘，找到目录
C:/Program Files/Macromedia/Flash Media Server 2

 

先要打开服务器哦

开始===程序===Macromedia===Flash Media Server 2
有两个start****,都要打开，关时候两个都要关,两个stop***，如果你怕麻烦直接找tool文件夹里的批处理文件StartServerService.bat吧，他会帮你搞定地,想关就找StopServerService.bat。~

管理服务器~

打开后就要管理了哦，点开fms2_console.swf，别看他只是个swf，后台管理就靠他了，输入你安装时候的密码和用户，服务器地址写 localhost 就好
看到了吧，熟悉熟悉他吧

applications文件夹

你可以在里边建一个文件夹例如叫 FirstApp，以后所有此项目服务器端的flv文件啊，共享文件啊都要放在这里边

包括视频等  基本上的都在这操作!

 

有一种协议叫rtmp

客户端和服务器端通信是使用协议rtmp的

现在在服务器端applications文件夹（当然偶的客户端和服务器端是一台机器了）里建个test1文件夹，你的地址就为

rtmp:/test1 或者 rtmp://localhost/test1

注意两个地址中的 "/ "符号

打开flash

与服务器通信首先要建个NetConnection()

var nc = new NetConnection();

连接

nc.connect("rtmp://localhost/test1");

怎么知道连没连上呢？顺利连接服务器后会触发一个onStatus事件,自己trace一下info.code

nc.onStatus = function(info) {
  //trace(info)
  //trace(info.code)
  for (i in info) {
    trace(i+": "+info[i]);
  }
};

完整代码：

var nc = new NetConnection();
nc.onStatus = function(info) {
  trace(info.code);
  if (info.code == "NetConnection.Connect.Success") {
    trace("接通");
  }
};
nc.connect("rtmp://localhost/test1");

注意：默认情况下服务器是允许你连接的，但只是默认，如果服务器拒绝你连接的话，上述代码就不好用了。怎么回事？我们看看连接的过程吧

连接过程
每当客户端试图连接服务器，一个NetConnection.connect()，服务器将会调用application.onConnect 来鉴定是不是允许客户端连接，onConnect()方法返回null 或不返回则将进入未决状态,直到onConnect方法中返回true或执行acceptConnection(client)则允许，返回false或执行rejectConnection(client)则拒绝，如图

 

服务器文件是以.asc形式存在的，可以在test1文件夹里建一个main.asc

application.onConnect=function(client){
this.rejectConnection(client);

//this.acceptConnection(client)

}

这样就拒绝连接了

 

 

 

远程共享？

共享的概念就是让每个链接到服务器的swf都能实时的得到共享的数据。
一个人更改了这些数据，其他人都会看得到。例如聊天室里的发言。

共享对象

共享对象，说英文大概你比较熟ha~ SharedObject， 恩flash中有两种sharedObject，local sharedobject （LSO） 和 remote sharedobject (RSO)，也就是本地共享和远程共享,偶们讨论远程的，不过之前你最好先去了解了解本地的，对你有好处...

RSO在服务器端是以文件形式存储的，扩展名是.fso，为什么不是.rso?....我也想问呢- -b

代码

初始化RSO需要先与服务器建立一个连接，续上节 ，我们先与服务器建立一个连接

//初始化远程共享要利用nc通道
var myNC = new NetConnection();
myNC.onStatus = function(info) {
  if (info.code == "NetConnection.Connect.Success") {
    //成功则利用此nc初始化rso
    initRSO(this);
  }
};

 下边是initRSO了，跟连接结构差不多

function initRSO(NC) {
 //在服务器上建立myRSO.fso文件，第2个参数指定nc通道，第3个指定文件在服务器上持久保留
  my_rso = SharedObject.getRemote("myRSO", NC.uri, true);
  my_rso.onSync = function(list) {
    //list 是一个对象数组 ，类似这种[{name:"x",code:"success"},{name:"y",code:"success"}]
 //初始成功
  };
  my_rso.connect(NC); //连接
}

了解了吧，下边看一个完整的例子

画一个mc起名叫mc，在第一帧上写代码，

//初始化远程共享要利用nc通道
var myNC = new NetConnection();
myNC.onStatus = function(info) {
  if (info.code == "NetConnection.Connect.Success") {
    //成功则利用此nc初始化rso
    initRSO(this);
  }
};
myNC.connect("rtmp://localhost/test1");
function initRSO(NC) {
  my_rso = SharedObject.getRemote("myRSO", NC.uri, true);
  my_rso.onSync = function() {
    mc._x=this.data.x
    mc._y=this.data.y
  };
  my_rso.connect(NC);
}
onMouseDown = function () {
  my_rso.data.x = _root._xmouse
  my_rso.data.y = _root._ymouse
};

然后发布设置中设置只允许网络，发布看看

现在你可以开多个播放器窗口，点其中一个，看看其他的窗口变不变，