aardio - godking.http 论坛登录+上传头像一例

请下载最新版 godking.http 库，版本不低于v1.8。

说明：

godking.http() 可以用于get、post、head、delete等多种模式，但提交的数据data为遇0终止的string。

godking.http.post() 仅post提交，data可以使用string、buffer等完整数据，不受0终止限制。

godking.http.upload() 简化以boundary方式提交上传文件，使用post模式。

 

import win.ui;
/*DSG{{*/
var winform = win.form(text="aardio form";right=759;bottom=469)
winform.add(
button={cls="button";text="登录";left=184;top=8;right=240;bottom=64;z=5};
button2={cls="button";text="选择头像";left=8;top=168;right=96;bottom=208;z=7};
button3={cls="button";text="上传头像";left=8;top=216;right=96;bottom=256;z=8};
custom={cls="custom";text="自定义控件";left=112;top=72;right=752;bottom=464;z=9};
edit={cls="edit";text="Edit";left=56;top=8;right=176;bottom=32;edge=1;z=3};
edit2={cls="edit";text="Edit";left=56;top=40;right=176;bottom=64;edge=1;z=4};
plus={cls="plus";left=8;top=72;right=96;bottom=160;border={color=-65536;width=1};foreRepeat="scale";forecolor=16777215;z=6};
static={cls="static";text="账号";left=8;top=8;right=56;bottom=32;transparent=1;z=1};
static2={cls="static";text="密码";left=8;top=40;right=56;bottom=64;transparent=1;z=2}
)
/*}}*/

import console
import godking.http
import string.base64
import string.md5
import web.form
var wb = web.form(winform.custom);

winform.button.oncommand = function(id,event){
    var r  = godking.http.post({
        url = "https://xxx.online/user-login.htm"; 
        data = {
            email = winform.edit.text;
            password = string.md5(winform.edit2.text,true);
        };
    })
    if ..string.find(r,"@</i> 退出</a></li>"){
        var r = godking.http("https://xxx.online/my-avatar.htm");
        var img = ..string.match(r,`\<img id="avatar_img" class="logo-4" src="(.+?)"\>`);
        if img {
            winform.plus.foreground = godking.http("https://xxx.online/"++img);
        }
    } else {
        win.msgbox("登录失败");
    }
    wb.go( "https://xxx.online/my-avatar.htm");
}

var file;
winform.button2.oncommand = function(id,event){
    import fsys.dlg;
    file = fsys.dlg.open("*.png|*.png","选择头像");
    if file winform.plus.foreground = file;
}

winform.button3.oncommand = function(id,event){
    if !file return ;
    var r = godking.http.post({
        url = "https://xxx.online/my-avatar.htm"; 
        data = {
            width = 128;
            height = 128;
            action = "clip";
            filetype = "jpg";
            name = "2.png";
            data = "data:image/png;base64,"++..string.base64.encode(..string.load(file));
        }
    })
    wb.go( "https://xxx.online/my-avatar.htm")
}

winform.show();
win.loopMessage();