動態語句的使用方法(exec/sp_executesql)

1. --动态语句语法
2. /******************************************************************************************************************************************************
3. 动态语句语法:exec/sp_executesql语法
5. 整理人：中国风(Roy)
7. 日期:2008.06.06
8. ******************************************************************************************************************************************************/
9. 动态语句语法:
11. --方法1查询表改为动态
12. select * from sysobjects
13. exec('select ID,Name from sysobjects')
14. exec sp_executesql N'select ID,Name from sysobjects'--多了一个N为unicode
16. --方法2:字段名，表名，数据库名之类作为变量时,用动态SQL 
17. declare @FName varchar(20)
18. set @FName='ID'
19. exec('select '+@FName+' from sysobjects where '+@FName+'=5' )
22. declare @s varchar(1000)
23. set @s=N'select '+@FName+' from sysobjects where '+@FName+'=5'
24. exec sp_executesql @s--会报错
27. declare @s nvarchar(1000)--改为nvarchar
28. set @s=N'select '+@FName+' from sysobjects where '+@FName+'=5'
29. exec sp_executesql @s--成功
32. --方法3:输入参数
34. declare @i int,@s nvarchar(1000)
35. set @i=5
36. exec('select ID,Name from sysobjects where ID='+@i)
38. set @s='select ID,Name from sysobjects where ID=@i'
39. exec sp_executesql @s,N'@i int',@i--此处输入参数要加上N
41. --方法4:输出参数
43. declare @i int,@s nvarchar(1000)
44. set @s='select @i=count(1) from sysobjects'
46. --用exec
47. exec('declare @i int '+@s+' select @i')--把整个语句用字符串加起来执行
49. --用sp_executesql
50. exec sp_executesql @s,N'@i int output',@i output--此处输出参数要加上N
51. select @i
54. --方法5:输入输出
56. --用sp_executesql
57. declare @i int,@con int,@s nvarchar(1000)
58. set @i=5
59. select @s='select @con=count(1) from sysobjects where ID>@i'
60. exec sp_executesql @s,N'@con int output,@i int',@con output ,@i 
61. select @con
63. --用exec
64. declare @i int,@s nvarchar(1000)
65. set @i=5
66. select @s='declare @con int select @con=count(1) from sysobjects where ID>'+rtrim(@i)+' select @con'
67. exec(@s)