How to send email via vbs using cdo_vbs cdo send mail-优快云博客

本文介绍了如何使用CDO (Collaboration Data Objects) 在VBScript中发送电子邮件。包括配置远程SMTP服务器、设置身份验证及SSL连接等步骤。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

http://www.paulsadowski.com/wsh/cdo.htm

My first working vbs, which send an email to specify mailbox.

********************************

set objMessage = CreateObject("CDO.Message")
objMessage.Subject = "EXample CDO Message"
objMessage.To = "administrator@vxyqmi-dom.extest.microsoft.com"
objMessage.From = "administrator@vxyqmi-dom.extest.microsoft.com"
objMessage.HTMLBody = "<h1>This is testing h1 htmlbody</h1>"
objMessage.CreateMHTMLBody("file:///D:/repro/test1.html")

set objConfig = CreateObject("cdo.configuration")
set Flds = objConfig.Fields
Flds.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
Flds.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "exch-c-170"
Flds.Update

objMessage.Configuration = objConfig
objMessage.Send

********************************

VBScript To Send Email Using CDO

This sample sends a simple text email via GMail servers.

It's like any other mail but requires that you set the SMTP Port to 465 and tell CDO to use SSL

Const cdoSendUsingPickup = 1 'Send message using the local SMTP service pickup directory.
Const cdoSendUsingPort = 2 'Send the message using the network (SMTP over the network).

Const cdoAnonymous = 0 'Do not authenticate
Const cdoBasic = 1 'basic (clear-text) authentication
Const cdoNTLM = 2 'NTLM

Set objMessage = CreateObject("CDO.Message")
objMessage.Subject = "Example CDO Message"
objMessage.From = """Me"" <test@gmail.com>"
objMessage.To = "me@my.com"
objMessage.TextBody = "This is some sample message text.." & vbCRLF & "It was sent using SMTP authentication and SSL."

'==This section provides the configuration information for the remote SMTP server.

objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

'Name or IP of Remote SMTP Server
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.gmail.com"

'Type of authentication, NONE, Basic (Base64 encoded), NTLM
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasic

'Your UserID on the SMTP server
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusername") = "You@gmail.com"

'Your password on the SMTP server
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "YourPassword"

'Server port (typically 25)
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 465

'Use SSL for the connection (False or True)
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True

'Connection Timeout in seconds (the maximum time CDO will try to establish a connection to the SMTP server)
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60

objMessage.Configuration.Fields.Update

'==End remote SMTP server configuration section==

objMessage.Send