QT 编译时拷贝文件

记：在进行QT开发时，一些程序运行依赖的外部库、配置文件需要从工程文件夹下拷贝到Debug或Release目录下，有时候修改后，手动拷贝非常麻烦，甚至忘记，遂记录下该命令。

一、直接修改.Pro文件

#-------------------------------------------------
#
# Project created by QtCreator 2023-07-16T21:08:53
#
#-------------------------------------------------

QT       += core gui

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

TARGET = Test
TEMPLATE = app

DESTDIR = $$PWD/Debug

SOURCES += main.cpp\
        widget.cpp

HEADERS  += widget.h

FORMS    += widget.ui

unix{
src_MenuConfig_file = $$PWD/MenuConfig
dst_MenuConfig_file = $$DESTDIR/MenuConfig

src_Languages_file = $$PWD/Languages
dst_Languages_file = $$DESTDIR/Languages

copyMenuConfig.commands = cp -r $$src_MenuConfig_file $$dst_MenuConfig_file
copyLanguages.commands = cp -r $$src_Languages_file $$dst_Languages_file
QMAKE_EXTRA_TARGETS += copyMenuConfig copyLanguages
POST_TARGETDEPS += copyMenuConfig copyLanguages
}

win32 {
src_MenuConfig_file = $$PWD\MenuConfig\\

src_MenuConfig_file ~= s,/,\\,g
dst_MenuConfig_file = $$DESTDIR\MenuConfig\\

dst_MenuConfig_file ~= s,/,\\,g
src_Languages_file = $$PWD\Languages\\

src_Languages_file ~= s,/,\\,g
dst_Languages_file = $$DESTDIR\Languages\\

dst_Languages_file ~= s,/,\\,g

copyMenuConfig.commands = xcopy $$src_MenuConfig_file $$dst_MenuConfig_file /S /E /Y
copyLanguages.commands = xcopy $$src_Languages_file $$dst_Languages_file  /S /E /Y
QMAKE_EXTRA_TARGETS += copyMenuConfig copyLanguages
POST_TARGETDEPS += copyMenuConfig copyLanguages
}

其中Linux系统和Windows系统下有点区别

二、注意事项

在Windows系统下，箭头处的换行非常重要，不换行的话，最终路径会不对。

ZhengLG
ChengDu China
2023.07.16