Part8:S3C2440时钟体系结构

1 硬件时钟体系

S3C2440的时钟体系很好理解，记住两点：
1. 三大部分：CPU 、高速设备、低速设备分别对应内部BUS、AHB BUS(H：高速)、APB BUS (P:外设)
	这三条总线的时钟源分别为 FCLK、HCLK、PCLK，最大值依次为：400Mhz、136Mhz、68Mhz
 但是，S3C2440使用的是12Mhz的晶振，如何放大的呢？
 -----> 锁相环PPL，具体原理就不深究了，也没必要(毕竟不是搞硬件的：)
 2. 那FCLK、HCLK、PCLK是如何产生的呢？
 看下图(截取自S3C2440手册)

对吧，S3C2440的时钟体系不难理解，下面看看如何改变这些时钟源，即如何编程？

2 时钟体系编程

从上面图解可知道，影响时钟源输出的有三个寄存器：MPLL、HDIVIN、PDIVIN
而选择器默认是选择12Mhz晶振(可查看手册得知)
接着，看看上电后，时钟体系的时序图

因此，我们只需在锁定时间设置MPLL、HDIVIN、PDIVIN即可。
这些设置可查阅手册得知，需设置CLKDIVIN及MPLLCON 即可，此外，仔细阅读手册的话，发现有个Notes,如下

OK,明确了目标之后，我们开始编程。(程序员光说不练，假把式，哈哈)
启动文件：start.S

.text
.global _start
_start:
/* 关闭看门狗 */
 ldr r0, =0x53000000
 ldr r1, =0
 str r1, [r0]
 /* 设置MPLL, FCLK : HCLK : PCLK = 400m : 100m : 50m */
 /* LOCKTIME(0x4C000000) = 0xFFFFFFFF */
 ldr r0, =0x4C000000
 ldr r1, =0xFFFFFFFF
 str r1, [r0]
 /* CLKDIVN(0x4C000014) = 0X5, tFCLK:tHCLK:tPCLK = 1:4:8  */
 ldr r0, =0x4C000014
 ldr r1, =0x5
 str r1, [r0]
 /* 设置CPU工作于异步模式 */
 mrc p15,0,r0,c1,c0,0
 orr r0,r0,#0xc0000000   //R1_nF:OR:R1_iA
 mcr p15,0,r0,c1,c0,0
 /* 设置MPLLCON(0x4C000004) = (92<<12)|(1<<4)|(1<<0) 
  *  m = MDIV+8 = 92+8=100
  *  p = PDIV+2 = 1+2 = 3
  *  s = SDIV = 1
  *  FCLK = 2*m*Fin/(p*2^s) = 2*100*12/(3*2^1)=400M
  */
 ldr r0, =0x4C000004
 ldr r1, =(92<<12)|(1<<4)|(1<<0)
 str r1, [r0]
/* 一旦设置PLL, 就会锁定lock time直到PLL输出稳定
  * 然后CPU工作于新的频率FCLK
  */
/* 设置内存: sp 栈 */
 /* 分辨是nor/nand启动
  * 写0到0地址, 再读出来
  * 如果得到0, 表示0地址上的内容被修改了, 它对应ram, 这就是nand启动
  * 否则就是nor启动
  */
 mov r1, #0
 ldr r0, [r1] /* 读出原来的值备份 */
 str r1, [r1] /* 0->[0] */ 
 ldr r2, [r1] /* r2=[0] */
 cmp r1, r2   /* r1==r2? 如果相等表示是NAND启动 */
 ldr sp, =0x40000000+4096 /* 先假设是nor启动 */
 moveq sp, #4096  /* nand启动 */
 streq r0, [r1]   /* 恢复原来的值 */
 
 bl main
 halt:
 	b halt

set_clk.c文件

#include "s3c2440_soc.h"
void delay(volatile int count)
{
    while(count--);
}
int main(void)
{
	GPFCON &= ~((3<<8)|(3<<10)|(3<<12));
 	GPFCON |= ((1<<8) | (1<<10) | (1<<12));
	/* 流水灯 */
 	volatile int tmp = 7;
 	volatile int val = 0x10;
    	while(1)
 	{
 		GPFDAT = (tmp << 4);
  		GPFDAT &= (~val);
 		val <<= 1;
  		delay(100000);
  		if(val == 0x80)
   		val = 0x10;
 	}
 	return 0;
}

Makefile文件

all:
 arm-linux-gcc -c -o set_clk.o  set_clk.c
 arm-linux-gcc -c -o start.o start.S
 arm-linux-ld -Ttext 0  start.o set_clk.o  -o set_clk.elf#注意start.o必须在set_clk.o之前
 arm-linux-objcopy -O binary -S set_clk.elf set_clk.bin
 arm-linux-objdump -D set_clk.elf > set_clk.dis
clean:
 rm *.o *.bin *.elf *.dis

s3c2440_soc.h文件

#ifndef  __S3C2440_SOC_H
#define  __S3C2440_SOC_H

#define     __REG(x)     (*(volatile unsigned int *)(x)) 

#define     GPFCON                   __REG(0x56000050)  //Port F control                                   
#define     GPFDAT                   __REG(0x56000054)  //Port F data 

#endif

根据上面文件，执行make即可生成set_clk.bin文件，并烧写进s3c2440开发板，观察LED流水灯的快慢

实验效果：
由于目前仅支持腾讯视频、优酷视频、哔哩哔哩视频。避免麻烦，我这边观察到的效果是，设置了
FCLK、HCLK、PCLK分别为400Mhz 100Mhz 50Mhz后，LED流水的快很多(我烧写在Nor Flash，
不设置的话，Nor Flash启动程序， LED流水很慢)


总结一下：
s3c2440芯片时钟体系的设置只需配置CLKDIVIN、MPLLCON两个寄存器，此外，还需注意将CPU设置
为异步模式。对这个时钟体系的理解，在于时钟的时序图的理解。因此，s3c2440的时钟体系不难理解。

下一篇预告：
>>>  SDRAM的原理与硬件编程...