对start.s中的lowlevel_init 函数对应的lowlevel_init.s文件的分析:
文件相关:
lowlevel_init.s是中最重要的就是包含了lowlevel_init函数的实现部分,而lowlevel_init是start.中很重要的一个函数。
ldr sp, =0xd0036000 /* end of sram dedicated to u-boot */
sub sp, sp, #12 /* set stack */
mov fp, #0
bl lowlevel_init /* go setup pll,mux,memory */
在start.s中第一次设置栈就是用来运行这个函数。
文件的分析:
1.进行一些与我们start.s启动主线不太相关的初始化操作:
检查复位的状态:检查的原因是硬件的复位分为好几种状态,除了真正按下复位按键进行硬件的复位这种成为冷启动外,还存在热启动与睡眠状态,所以在这里确定我们的复位状态到底是哪种情况。
/* check reset status */
ldr r0, =(ELFIN_CLOCK_POWER_BASE+RST_STAT_OFFSET)
ldr r1, [r0]
bic r1, r1, #0xfff6ffff
cmp r1, #0x10000
beq wakeup_reset_pre
cmp r1, #0x80000
beq wakeup_reset_from_didle
IO状态的复位;
/* IO Retention release */
ldr r0, =(ELFIN_CLOCK_POWER_BASE + OTHERS_OFFSET)
ldr r1, [r0]
ldr r2, =IO_RET_REL
orr r1, r1, r2
str r1, [r0]
关闭看门狗;
/* Disable Watchdog */
ldr r0, =ELFIN_WATCHDOG_BASE /* 0xE2700000 */
mov r1, #0
str r1, [r0]
SRAM与SROM中一些IO口的设置;
/* SRAM(2MB) init for SMDKC110 */
/* GPJ1 SROM_ADDR_16to21 */
ldr r0, =ELFIN_GPIO_BASE
ldr r1, [r0, #GPJ1CON_OFFSET]
bic r1, r1, #0xFFFFFF
ldr r2, =0x444444
orr r1, r1, r2
str r1, [r0, #GPJ1CON_OFFSET]
ldr r1, [r0, #GPJ1PUD_OFFSET]
ldr r2, =0x3ff
bic r1, r1, r2
str r1, [r0, #GPJ1PUD_OFFSET]
2.进行开发板的供电索存:
/* PS_HOLD pin(GPH0_0) set to high */
ldr r0, =(ELFIN_CLOCK_POWER_BASE + PS_HOLD_CONTROL_OFFSET)
ldr r1, [r0]
orr r1, r1, #0x300
orr r1, r1, #0x1
str r1, [r0]
3.下面判断当前代码运行的内存地址:DRAM or SRAM?
ldr r0, =0xff000fff
bic r1, pc, r0 /* r0 <- current base addr of code */
ldr r2, _TEXT_BASE /* r1 <- original base addr in ram */
bic r2, r2, r0 /* r0 <- current base addr of code */
cmp r1, r2 /* compare r0, r1 */
beq 1f /* r0 == r1 then skip sdram init */
说到这里就不得不再说说uboot的启动过程了:
硬件在上电启动也就是冷启动后,会先执行固化在SROM中的BL0阶段的启动代码。而uboot在启动时将自己分割成两部分:BL1和BL2阶段。BL1阶段通常为uboot的前8KB代码,BL2阶段包含uboot的整段代码。BL0阶段执行完会第一阶段的代码到SRAM中进行执行,然后BL1阶段的代码执行,进行DRAM(DDR)的初始化等一些其他的初始化操作,最后引导第二阶段BL2(其实也就是整个uboot)在DRAM中运行,进行进一步的初始化。
这样一来,在DRAM中不仅放着BL1阶段的代码也放着BL2阶段的代码。在热启动或者是休眠转态被唤醒时不必再在从启动介质中拷贝BL1阶段的代码进行运行,可以直接在DRAM中运行uboot的整包程序。
经过当前运行地址与之前Makefile中设置的_TEXT_BASE进行比对,得知当前的运行环境是否在DRAM中,不是的话则说明程序运行在IRAM中,则需要进行时钟的初始化,DRAM的初始化:
/* init system clock */
bl system_clock_init
/* Memory initialize */
bl mem_ctrl_asm_init
实际分析可以知道:uboot中规定的可用的物理地址范围为:0x30000000-0x4FFFFFFF,一共512MB,其中30000000-3FFFFFFF为DRAM0,40000000-4FFFFFFF为DRAM1。
如果是是运行在DRAM中的话再进行下面串口的初始化:
/* for UART */
bl uart_asm_init
串口在初始化完之后会打印出'O',与后面再次打印的'K'组合成ok,是uboot启动时最早打印出来的东西。
4.最后返回start.s进行继续主线的启动:
pop {pc}
END....