PL/SQL游标详解-优快云博客

--在PL/SQL块中执行SELECT、INSERT、DELETE和UPDATE语句时，

ORACLE会在内存中为其分配上下文区（Context Area），即缓冲区。

游标是指向该区的一个指针，或是命名一个工作区（Work Area），或是一种结构化数据类型

显式游标

--显式游标主要是用于对查询语句的处理，尤其是在查询结果为多条记录的情况下

declare 
cursor c1 is --定义游标
    select sname,cno from student,sc where student.sno=sc.sno order by 1;
    v_s c1%rowtype;    --也就是v_s里面包含了sname,sno，输出的时候就是v_s.sname;v_s.sno
begin
    open c1;    --打开游标
    fetch c1 into v_s;    --读取游标
    close c1;    --关闭
end;

查询结果大多为多条记录，所以大多需要进行遍历

--loop...end loop
LOOP
    FETCH c1 INTO v_s;
    EXIT WHEN c1%NOTFOUND;
    dbms_output.put_line();
END LOOP;

--while...end loop
FETCH c1 INTO v_s;
WHILE (c1%FOUND) LOOP
    dbms_output.put_line();
    FETCH c1 INTO v_s;
END LOOP;

--for...end loop
FOR idx IN c1 LOOP
    dbms_output.put_line(idx.sname || idx.cno);
END LOOP;

针对带参数游标时

--定义游标
    cursor c1(v_sno varchar) is
      select sname,cno from student,sc where student.sno=sc.sno and trim(sc.sno)=v_sno order by 1;
    v_s c1%rowtype;
--loop和while
    open c1('001')其他照旧
--for loop
    for idx in c1('001') loop
          dbms_output.put_line(idx.sname);
    end loop;

可以用select for update游标来更新由游标检索到的那些记录行。这在仅仅需要修改检索到的那些记录行，而不需要取出这些行值的情况下是非常有用的
语法:select...for update [of column_list][wait n等待n秒][nowait不等待][skip locked返回查询结果]
of字句用于指定即将更新的列，wait字句指定等待其他用户释放锁的秒数，防止无限期的等待

DECLARE
  CURSOR csr_1 IS
    SELECT * FROM s1 FOR UPDATE OF sname;
  v_sname VARCHAR2(20);
BEGIN
  FOR idx IN csr_1 LOOP
    v_sname :=UPPER(idx.sname);
    UPDATE s1
    SET sname =v_sname
    WHERE CURRENT OF csr_1;    --Where Current Of语句允许你更新或者是删除最后由cursor取的记录
--删除为delete from s1 where current of csr_1
  END LOOP;
  COMMIT;
END;

隐式游标

--对于DML语言，由ORACLE 系统自动地为这些操作设置游标并创建其工作区，隐式游标的名字为SQL，这是由ORACLE 系统定义的。用户只能通过隐式游标的相关属性，来完成相应的操作

在隐式游标的工作区中，所存放的数据是与用户自定义的显示游标无关的、最新处理的一条SQL 语句所包含的数据。

SQL%FOUND是否影响到行 SQL%ISOPEN是否打开，这个值永远为空，因为DML执行完后会自动关闭SQL游标

SQL%NOTFOUND修改行时是否失败 SQL%ROWCOUNT指明语句执行完后影响的行数

DECLARE
  v_num_rows NUMBER;
BEGIN
  INSERT INTO sc(sno,cno)
    SELECT '110425',cno FROM course WHERE cgrade>2;
  v_num_rows :=SQL%ROWCOUNT;
  IF (SQL%FOUND)THEN
    UPDATE sc_number SET selCnt =v_num_rows WHERE sno='110425';
    IF (SQL%NOTFOUND)THEN    --如果上面已经更新语句失败，说明没有学号为110425的，所以插入
      INSERT INTO sc_number VALUES ('110425',v_num_rows);
    END IF;
  END IF;
  COMMIT;
END;

动态游标（游标变量）

--也是一个指向多行查询结果集合中当前数据行的指针，游标只能与指定的查询相连，即固定指向一个查询的内存处理区域
游标变量则可与不同的查询语句相连，它可以指向不同查询语句的内存处理区域，但不能同时指向多个内存处理区域，在某一时刻只能与一个查询语句相连

DECLARE
  --定义一个游标变量
  TYPE rc is REF CURSOR;
  --声明一个游标变量
  v_rc rc;
BEGIN
  OPEN v_rc FOR SELECT *from sc;    --打开游标
  --对游标的操作和显式游标一样
END;

没有指明游标返回类型的游标变量称为弱ref cursor类型。它能指向任何一个具有任意多列的select查询

v_rc SYS_REFCURSOR; --定义，操作和动态游标一样