MySQL一键安装脚本

@setlocal enabledelayedexpansion
@echo off
chcp 65001
rem Author: 梓岸ZiAns
rem Date: 2023-09-14

rem 初始化安装路径 如要更改MySQL安装路径，请用自己的全绝对路径替换下一行中的“D:\environment\MySQL\”字符串
set MYSQL_DIR=D:\environment\MySQL\
dir %MYSQL_DIR% /ad | find /i "<DIR>"   
if %errorlevel%==0 (
echo ==========目录已存在，删除后重新创建
echo.
rd %MYSQL_DIR%
md %MYSQL_DIR%
if %ERRORLEVEL% EQU 0 (echo ==========初始化安装路径成功！) else (echo ==========初始化安装路径失败！)
echo.
) else (
md %MYSQL_DIR%
if %ERRORLEVEL% EQU 0 (echo ==========初始化安装路径成功！) else (echo ==========初始化安装路径失败！)
echo.
)

rem 将压缩包解压到配置安装目录
%~d0
set package= %~dp0package
cd %package%
for /f %%i in ('dir /s/B') do set full_package_path=%%i
echo  %full_package_path%
tar -xzvf %full_package_path% -C %MYSQL_DIR%
for /f %%i in ('dir  /B') do set full_package_name=%%i
set package_name=%full_package_name:~0,-4%

rem 创建数据库文件夹
echo %MYSQL_DIR%%package_name%
md %MYSQL_DIR%%package_name%\data

rem mysql基础变量配置
set base=%MYSQL_DIR%%package_name%
set basedir=%base%
set bindir=%base%\bin
set datadir=%base%\data
set logerror=%base%\Logs.log
set slowlog=!datadir!\slow.log

rem 写入my.ini配置
echo [mysql] > %base%\my.ini
echo default-character-set=utf8 >> %base%\my.ini
echo [mysqld] >> %base%\my.ini
echo port = 3306 >> %base%\my.ini
echo basedir=!basedir! >> %base%\my.ini
echo datadir=!datadir! >> %base%\my.ini
echo log-error=!logerror! >> %base%\my.ini
echo user=mysql >> %base%\my.ini
echo default_authentication_plugin=mysql_native_password >> %base%\my.ini
echo max_connections=1500 >> %base%\my.ini
echo character-set-server=utf8mb4>> %base%\my.ini
echo innodb_buffer_pool_size=3072M>> %base%\my.ini
echo wait_timeout=100 >> %base%\my.ini
echo interactive_timeout=300 >> %base%\my.ini
echo thread_cache_size=100 >> %base%\my.ini
echo default-time_zone='+8:00' >> %base%\my.ini
echo long_query_time=4 >> %base%\my.ini
echo slow_query_log='ON' >> %base%\my.ini
echo slow_query_log_file=!slowlog! >> %base%\my.ini
echo binlog_format="STATEMENT" >> %base%\my.ini
echo binlog_expire_logs_seconds=2592000 >> %base%\my.ini
echo general_log=1 >> %base%\my.ini
echo [client] >> %base%\my.ini 

rem 添加环境变量
wmic ENVIRONMENT where "name='MYSQL_HOME'" delete
wmic ENVIRONMENT create name="MYSQL_HOME",username="<system>",VariableValue="%basedir%"
set string=%PATH%
echo %string% | findstr /C:"%bindir%" && (
    echo contains 
) || (
    setx path "%path%;%%MYSQL_HOME%%\bin" /M
)

rem 安装mysql服务

cd %bindir%

echo ==========安装中............

rem 初始化数据库
mysqld --initialize-insecure

rem installation
mysqld --install MySQL

rem startmysql
net start mysql 

echo ==========初始化中..........
rem login
mysqladmin -u root password 123456

echo ==========安装完成

pause