apktool.bat 无法下载的解决方案

最新推荐文章于 2021-06-23 11:56:31 发布

SmallMartin

最新推荐文章于 2021-06-23 11:56:31 发布

阅读量4.5k

点赞数 11

分类专栏： Android 基础文章标签： android 反编译

本文链接：https://blog.youkuaiyun.com/qq_34115898/article/details/108513756

版权

Android 基础专栏收录该内容

56 篇文章

订阅专栏

本文介绍如何创建一个用于处理APK文件的批处理文件apktool.bat。通过设置环境变量和查找最高版本的apktool jar包，此脚本能够智能地选择正确的工具进行APK的拆解和重建。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

创建一个apktool.bat的空文件

把下面的代码复制进去

@echo off
setlocal
set BASENAME=apktool_
chcp 65001 2>nul >nul


set java_exe=java.exe


if defined JAVA_HOME (
set java_exe="%JAVA_HOME%\bin\java.exe"
)


rem Find the highest version .jar available in the same directory as the script
setlocal EnableDelayedExpansion
pushd "%~dp0"
if exist apktool.jar (
set BASENAME=apktool
goto skipversioned
)
set max=0
for /f "tokens=1* delims=-_.0" %%A in ('dir /b /a-d %BASENAME%*.jar') do if %%~B gtr !max! set max=%%~nB
:skipversioned
popd
setlocal DisableDelayedExpansion


rem Find out if the commandline is a parameterless .jar or directory, for fast unpack/repack
if "%~1"=="" goto load
if not "%~2"=="" goto load
set ATTR=%~a1
if "%ATTR:~0,1%"=="d" (
rem Directory, rebuild
set fastCommand=b
)
if "%ATTR:~0,1%"=="-" if "%~x1"==".apk" (
rem APK file, unpack
set fastCommand=d
)


:load
%java_exe% -jar -Duser.language=en -Dfile.encoding=UTF8 "%~dp0%BASENAME%%max%.jar" %fastCommand% %*


rem Pause when ran non interactively
for /f "tokens=2" %%# in ("%cmdcmdline%") do if /i "%%#" equ "/c" pause

保存，执行即可