u-boot.lds文件详解

最新推荐文章于 2024-06-13 23:11:56 发布

Limeng_L

最新推荐文章于 2024-06-13 23:11:56 发布

阅读量498

点赞数 1

分类专栏： makefile

makefile 专栏收录该内容

5 篇文章

订阅专栏

文件详解：

OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")

/*指定输出可执行文件是elf格式,32位ARM指令,小端*/

OUTPUT_ARCH(arm)

/*指定输出可执行文件的平台为ARM*/

ENTRY(_start)

/*指定输出可执行文件的起始代码段为_start*/

SECTIONS
{

/*指定可执行image文件的全局入口点，通常这个地址都放在ROM(flash)0x0位置。必须使编译器知道这个地址，通常都是修改此处来完成*/
. = 0x00000000; /*;从0x0位置开始*/

. = ALIGN(4);                     /*代码以4字节对齐*/
.text :
{
cpu/arm920t/start.o (.text)    /*代码的第一个代码部分*/
*(.text)       /*其它代码部分*/
}

. = ALIGN(4); /*代码以4字节对齐*/
.rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) } /*指定只读数据段*/

. = ALIGN(4); /*代码以4字节对齐*/
.data : { *(.data) } /*指定读/写数据段*/

. = ALIGN(4); /*代码以4字节对齐*/
.got : { *(.got) } /*指定got段, got段是uboot自定义的一个段, 非标准段*/

. = .;
__u_boot_cmd_start = .; /*把__u_boot_cmd_start赋值为当前位置, 即起始位置*/
.u_boot_cmd : { *(.u_boot_cmd) } /*指定u_boot_cmd段, uboot把所有的uboot命令放在该段.*/
__u_boot_cmd_end = .; /*把__u_boot_cmd_end赋值为当前位置,即结束位置*/

. = ALIGN(4);
__bss_start = .; /*把__bss_start赋值为当前位置,即bss段的开始位置*/
.bss (NOLOAD) : { *(.bss) . = ALIGN(4); } /*指定bss段,告诉加载器不要加载这个段*/
__bss_end = .; /*把_end赋值为当前位置,即bss段的结束位置*/
}

看完上面的解析思路本来应该是很清晰的，于是乎编译u-boot，查看一下System.map,

33f80000 T _start
33f80020 t _undefined_instruction
33f80024 t _software_interrupt
33f80028 t _prefetch_abort
33f8002c t _data_abort
33f80030 t _not_used
33f80034 t _irq
33f80038 t _fiq

发现 _start 的链接地址不是u-boot.lds中.text 的当前地址0x00000000，而是33f80000 ，这就产生很多疑问了：

为什么u-boot.lds指定的 .text 的首地址不起作用？
33f80000 是什么地址，由谁指定.text的首地址是33f80000 的呢？
假如有其他动作改变了 .text 的首地址，那么该动作跟u-boot.lds的优先级又是怎么决定的呢？

其实这三个问题都在Makefile的LDFLAGS 变量和u-boot.lds 中找到答案。

$(obj)u-boot:		depend version $(SUBDIRS) $(OBJS) $(LIBS) $(LDSCRIPT)
		UNDEF_SYM=`$(OBJDUMP) -x $(LIBS) |sed  -n -e 's/.*\(__u_boot_cmd_.*\)/-u\1/p'|sort|uniq`;\
		cd $(LNDIR) && $(LD) $(LDFLAGS) $$UNDEF_SYM $(__OBJS) \
			--start-group $(__LIBS) --end-group $(PLATFORM_LIBS) \
			-Map u-boot.map -o u-boot

LDFLAGS 在u-boot根目录文件下的config.mk

LDFLAGS += -Bstatic -T $(LDSCRIPT) -Ttext $(TEXT_BASE) $(PLATFORM_LDFLAGS)

其中TEXT_BASE 是在u-boot根目录的board文件夹的对应的开发板名字的子目录下的config.mk文件中定义的

TEXT_BASE = 0x33f80000

看到这里我们应该明白为什么_start，也就是.text的首地址总是等于0x33f80000 了，在连接的时候ld命令会把参数-Ttext指定的地址赋给.text,所以.text在u-boot.lds中的默认地址(当前地址)不起作用了。

原文：https://blog.youkuaiyun.com/xinyuwuxian/article/details/8931650