利用vbscript脚本修改文件内容，此适用于自动化的操作中

最新推荐文章于 2021-06-22 22:14:39 发布

qq_29427355

最新推荐文章于 2021-06-22 22:14:39 发布

阅读量1.7k

点赞数 1

CC 4.0 BY-SA版权

分类专栏：自动化测试

本文链接：https://blog.youkuaiyun.com/qq_29427355/article/details/84325467

自动化测试专栏收录该内容

9 篇文章

订阅专栏

本文介绍如何使用VBS脚本实现文件内容的自动化查找与替换，适用于批量修改文件需求，通过创建Replace.vbs脚本，输入查找内容、替换内容及目标文件，实现文件内容的高效更新。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

利用vbscript脚本修改文件内容，此适用于自动化的操作中

'新建一个Replace.vbs脚本，脚本内容如下，程序运行时输入三个参数：查找内容，替换内容，文件

Dim FileName, Find, ReplaceWith, FileContents, dFileContents   
Find = WScript.Arguments(0)   
ReplaceWith = WScript.Arguments(1)   
FileName = WScript.Arguments(2)   

'读取文件   
FileContents = GetFile(FileName)   

'用“替换内容”替换文件中所有“查找内容”   
dFileContents = replace(FileContents, Find, ReplaceWith, 1, -1, 1)   

'比较源文件和替换后的文件   
if dFileContents <> FileContents Then   
'保存替换后的文件   
WriteFile FileName, dFileContents   

Wscript.Echo "Replace done."   
If Len(ReplaceWith) <> Len(Find) Then   
'计算替换总数   
Wscript.Echo _   
( (Len(dFileContents) - Len(FileContents)) / (Len(ReplaceWith)-Len(Find)) ) & _   
" replacements."   
End If   
Else   
Wscript.Echo "Searched string Not In the source file"   
End If   

'读取文件   
function GetFile(FileName)   
If FileName<>"" Then   
Dim FS, FileStream   
Set FS = CreateObject("Scripting.FileSystemObject")   
on error resume Next   
Set FileStream = FS.OpenTextFile(FileName)   
GetFile = FileStream.ReadAll   
End If   
End Function   

'写文件   
function WriteFile(FileName, Contents)   
Dim OutStream, FS   

on error resume Next   
Set FS = CreateObject("Scripting.FileSystemObject")   
Set OutStream = FS.OpenTextFile(FileName, 2, True)   
OutStream.Write Contents   
End Function