【Linux】编写最简单操作系统(mbr)并用bochs工具调试

参考：https://blog.youkuaiyun.com/u011391093/article/details/51701602
           https://blog.youkuaiyun.com/jadeshu/article/details/89046838

BIOS ROM芯片地址空间布局 

-----------------------------------------------------------------------------------------------------------

0-3ff    1k 用于中断向量表

400-4ff 256B  bios数据区

500-7Bff  30kb  可自定义区域

7C00-7BFF 512b MBR被bios加载到的内存区域

7E00-9FBFF 608k 自定义区域

9FC00-9FFFF 1kb  扩展bios数据区

A0000-AFFFF 64k  彩色显示适配器

B0000 B7FFF 32k  黑白显示适配器

B8000 BFFFF 32k  文本显示适配器

C0000 C7FFF 32k 显示适配器bios

C8000 EFFFF 160k 映射硬件适配器的rom或者内存映射i/o

F0000 FFFEF 64kb-16b  真正的入口

FFFF0 FFFFF 16b bios入口地址(跳转使用.因为空间有限)

以下在实模式阶段.我们是可以随意使用的

7E00-9FBFF 608k 自定义区域

500-7Bff  30kb  可自定义区域

-----------------------------------------------------------------------------------------------------

当电脑加电,CS:IP寄存器被强制初始化为0xF000:0xFFF0,也就是物理地址0XFFFF0,但实模式下只有1M地址空间(20位地址总线),加电执行的第一条指令距离尾部只有16B,显然.这个地址只能作为跳板！第二条指令是jmp far f000:e05b.所以真正所执行的地址是从f000:e05b开始。

接下来BIOS将开始检测内存、显卡、外设，建立中断向量表。另外现在实模式(可以直接访问物理地址)的中断处理程序由硬件提供(BIOS提供)，软件可以完成什么功能，取决于硬件(外设)。

BIOS只需要建立中断向量表，即可调用BIOS中断服务程序。BIOS会在内存0-0x3ff建立中断向量表，最后检查启动盘的第0盘0磁道1扇区的内容（1个扇区512字节）。BIOS会检查此扇区的末尾2个字节是否是0x55、0xaa，如果存在BIOS将会认为此处有主引导记录程序MBR。BIOS将把此扇区的内容(程序)加载到物理地址0x7c00处，.最后bios将执行jmp 0:0x7c00跳转，执行MBR。

想深入了解以上的细节，参看BIOS设计相关的书籍。.

以下是自己编写的一简单mbr.S引导程序

;------------------------------------------------------------
SECTION MBR vstart=0x7c00          
   mov ax,cs      
   mov ds,ax
   mov es,ax
   mov ss,ax
   mov fs,ax
   mov sp,0x7c00 ;栈指针

; 清屏 利用0x06号功能，上卷全部行，则可清屏。
; -----------------------------------------------------------
;INT 0x10   功能号:0x06       功能描述:上卷窗口
;------------------------------------------------------
;输入：
;AH 功能号= 0x06
;AL = 上卷的行数(如果为0,表示全部)
;BH = 上卷行属性
;(CL,CH) = 窗口左上角的(X,Y)位置
;(DL,DH) = 窗口右下角的(X,Y)位置
;无返回值：
   mov     ax, 0x600
   mov     bx, 0x700
   mov     cx, 0           ; 左上角: (0, 0)
   mov     dx, 0x184f       ; 右下角: (80,25),
               ; VGA文本模式中,一行只能容纳80个字符,共25行。
               ; 下标从0开始,所以0x18=24,0x4f=79
   int     0x10            ; int 0x10

;;;;;;;;;    下面这三行代码是获取光标位置    ;;;;;;;;;
;.get_cursor获取当前光标位置,在光标位置处打印字符.
   mov ah, 3        ; 输入: 3号子功能是获取光标位置,需要存入ah寄存器
   mov bh, 0        ; bh寄存器存储的是待获取光标的页号

   int 0x10        ; 输出: ch=光标开始行,cl=光标结束行
            ; dh=光标所在行号,dl=光标所在列号

;;;;;;;;;    获取光标位置结束    ;;;;;;;;;;;;;;;;

;;;;;;;;;     打印字符串    ;;;;;;;;;;;
   ;还是用10h中断,不过这次是调用13号子功能打印字符串
   mov ax, message 
   mov bp, ax        ; es:bp 为串首地址, es此时同cs一致，
            ; 开头时已经为sreg初始化

   ; 光标位置要用到dx寄存器中内容,cx中的光标位置可忽略
   mov cx, 5        ; cx 为串长度,不包括结束符0的字符个数
   mov ax, 0x1301    ; 子功能号13是显示字符及属性,要存入ah寄存器,
            ; al设置写字符方式 ah=01: 显示字符串,光标跟随移动
   mov bx, 0x2        ; bh存储要显示的页号,此处是第0页,
            ; bl中是字符属性, 属性黑底绿字(bl = 02h)
   int 0x10        ; 执行BIOS 0x10 号中断
;;;;;;;;;      打字字符串结束     ;;;;;;;;;;;;;;;

   jmp $        ; 使程序悬停在此

   message db "hello world"
   times 510-($-$$) db 0
   db 0x55,0xaa

将以上汇编程序 nasm -o mbr.bin mbr.S
然后创建一个硬盘.写入到0扇区.具体自行google bochs使用方法。参看【附录B】
在bochs(x86模拟器).显示效果

我的具体实践，参看【附录B】 

实践资料下载： https://download.youkuaiyun.com/download/qq2399431200/12228930

 

附录A： nasm汇编器下载

https://www.nasm.us/pub/nasm/releasebuilds/2.14.02/win64/

 

附录B：bochs模拟器创建映像文件 、写入文件并启动
 

安装 bochs，dd for windows，nasm，并将三个工具的安装目录加入到环境变量$Path中。

我用的bochs版本是2.6.8

1.用 bochs 中 bximage.exe 创建新的 img 文件

选择hd还是fd随意，一路回车采用默认设置即可。

2.编写汇编代码并编译成二进制文件

mbr.asm汇编文本文件

; 如果直接从网页复制如下代码保存，编译时可能会提示错误，需要删除那些看不见的非法字符，直到编译通过为止
org 0x7C00    ;主引导记录的内存地址
jmp entry

entry:
  mov ax, 0
  mov ss, ax
  mov ds, ax
  mov es, ax
  mov si, msg  ;将msg地址赋给si

putLoop:
  mov al, [si]  ;等同 mov al, byte [si]  将si地址开始的一个字节的值放入al中
  add si, 1     ;si = si+1
  cmp al, 0     ;al与0比较
  je fin        ;如上面比较相等 则跳转到fin 不相等则不跳转,执行后面命令
  mov ah, 0x0e
  int 0x10
  jmp putLoop

fin:
  HLT  ;暂停
  jmp fin

msg:
  DB 0x0a, 0x0a
  DB "hello world!"
  ;DB 0
  times 510-($-$$) db 0  ;填充510字节的0，$$表示编译后的起始地址
  dw 0xaa55  ;表示结束，加上前面的510字节正好512字节满足条件

用cmd 命令输入nasm mbr.asm -o mbr.bin 编译成二进制文件

3.将mbr.bin文件写入如上面第1点讲解创建的映像文件a.img第0扇区内

  在 cmd 中使用指令

dd if=test.bin of=a.img bs=512 count=1 conv=notrunc

  将mbr.bin写入 a.img映射文件内

  

4.新建一个文件bosh.bxrc，文件名你自己可以随便命名，如下是软盘启动的配置文件[硬盘配置以#注释]:

推荐bochs-2.4.exe版本

megs:32
romimage: file=$BXSHARE/BIOS-bochs-latest
vgaromimage:file=$BXSHARE/VGABIOS-lgpl-latest
floppya:1_44=a.img,status=inserted
#floppyb:1_44=b.img,status=inserted
#软盘映射 
boot:a
#boot:b
#硬盘
#boot:disk
#分配HD为60M，根据分配硬盘大小，cylinders, heads, spt会变化
#ata0: enabled=1, ioaddr1=0x1f0, ioaddr2=0x3f0, irq=14
#ata0-master: type=disk, mode=flat, path="boot.img", cylinders=121, heads=16, spt=63
log:bochsout.txt
mouse:enabled=0

5.启动

  

如果bochs窗口显示空白，则尝试改用下面的方法，还是弹出空白窗口能，就关掉cmd，重新打开一个再试一次。(亲身经历过，用相同的.bxrc、相同的镜像，做任何修改，这两种启动方式，时而正常时而弹出空白窗口，遇到这种情况，两种启动命令都轮换尝试吧)

或者，在命令指示符中键入 .\bochs.exe -f bosh.src

点击start按钮即可运行!

 

6.调试

 在命令指示符中键入 .\bochsdbg.exe -f bosh.src

 

点击start按钮即可运行!

即到第一条指令 jmp 0XF000:E05B  地址为：f000:fff0 即FFFF0 (1M的最后16字节)，因为实模式下只能读取1M内存