java环境变量 (2个步骤)-优快云博客

本文详细介绍了在Windows操作系统下配置Java环境的全过程，包括如何保存配置脚本、运行设置脚本以及验证配置是否成功。通过遵循步骤，读者能够轻松完成Java环境的配置，并了解如何检查设置是否正确。

java环境配置，二部曲

windows 操作系统

1 保存文件为 “设置Java环境变量.bat”，注意后缀名必须是 bat格式的，格式的内容是一下内容

@echo off
title Java环境变量设置 by Xu.J.Y
 mode con cols=60 lines=15
echo.
echo 正在检查并删除旧的Java环境变量设置...
echo.
rem 在环境变量path中，剔除掉变量java_home相关的字符
call set a=%%path:;%%java_home%%\jre\bin=%%
call set b=%%a:;%java_home%\jre\bin=%%
call set c=%%b:;%%java_home%%\bin=%%
call set d=%%c:;%java_home%\bin=%%
wmic ENVIRONMENT where "name='Path' and username='<system>'" set VariableValue=%d% >nul 2>nul


rem 如果有的话，先删除ClassPath 
wmic ENVIRONMENT where "name='ClassPath'" delete >nul 2>nul


rem 如果有的话，先删除JAVA_HOME
wmic ENVIRONMENT where "name='JAVA_HOME'" delete >nul 2>nul
cls
echo.
echo ===========================================================
echo          此批处理只需要安装JAVA后运行一次既可
echo ===========================================================
echo.
echo  你的Java安装在哪个盘？C D E F G H ...
echo.
set /p disk=请输入盘符：
echo.
echo 正在查看是否安装在默认路径
echo.
ping -n 2 127.0.0.1 >nul 2>nul
cls
set lu=""
setlocal enabledelayedexpansion
for /d %%i in ("%disk%:\Program Files\Java\jdk*") do set lu=%%i
if !lu!=="" (
echo.
echo 好吧，你太个性了~~修改了默认安装路径~~
echo.
echo 例如默认路径C:\Program Files\Java\jdk1.6.0_25
echo.
echo.
echo 现在就辛苦你手动输入jdk路径了^^.^^
echo.&set /p lu=路径：)
echo.
echo 安装路径：%lu%
ping -n 2 127.0.0.1 >nul 2>nul




wmic ENVIRONMENT create name="JAVA_HOME",username="<system>",VariableValue="%lu%"  >nul 2>nul


wmic ENVIRONMENT create name="CLASSPATH",username="<system>",VariableValue=".;%%JAVA_HOME%%\lib\tools.jar;%%JAVA_HOME%%\lib\dt.jar;" >nul 2>nul






wmic ENVIRONMENT where "name='PATH' and username='<system>'" set VariableValue="%d%;%%JAVA_HOME%%\bin;%%JAVA_HOME%%\jre\bin" >nul 2>nul
echo.
echo 设置完成，请运行 检测环境变量设置是否成功.bat...
echo.
pause


rem

2 运行文件 “设置Java环境变量.bat”，按步骤操作即可。

3 以上可以完成 java环境配置，当然也可以测试。

"开始——cmd——java -version"

如果可以看到到版本号，则配置成功。

也可以用文件 “ 检测环境变量设置是否成功.bat"，一下是文件内容，运行即可。

@echo off
mode con cols=50 lines=10
javac >nul 2>nul
echo.&echo.
if errorlevel 9009 (echo 设置失败，请检查后重新设置...
)else (echo 设置成功！)


echo.
pause

以下是附件下载地址

http://download.youkuaiyun.com/download/pioayang/6005441