把 TObjectList 序列化为 JSON

最新推荐文章于 2025-10-18 11:39:46 发布

原创最新推荐文章于 2025-10-18 11:39:46 发布 · 591 阅读

0 ·

CC 4.0 BY-SA版权

文章标签：

#json #Delphi

本文介绍了在Delphi中如何使用TJsonSerializer类进行TMyClass对象的序列化和反序列化操作，对比了TJson.ObjectToJsonString和TJson.JsonToObject的使用情况。

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, System.Generics.Collections;

type
  TMyClass = class
  private
    FName: string;
    FValue: Integer;
  public
    property MyName: string read FName write FName;
    property MyValue: Integer read FValue write FValue;
  end;

  TForm1 = class(TForm)
    Memo1: TMemo;
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

uses System.JSON.Serializers;

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
  AList: TObjectList<TMyClass>;
  Seri: TJsonSerializer;
  MyObj: TMyClass;
begin
  //序列化 ObjectList 为 JSON
  AList := TObjectList<TMyClass>.Create;

  MyObj := TMyClass.Create;
  MyObj.FName := 'aaa';
  MyObj.FValue := 100;
  AList.Add(MyObj);

  MyObj := TMyClass.Create;
  MyObj.FName := '吃饭啦';
  MyObj.FValue := 110;
  AList.Add(MyObj);

  MyObj := TMyClass.Create;
  MyObj.FName := 'ccc';
  MyObj.FValue := 120;
  AList.Add(MyObj);

  Seri := TJsonSerializer.Create;

  Memo1.Text := Seri.Serialize<TObjectList<TMyClass>>(AList);

  AList.Free;
  Seri.Free;
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  Seri: TJsonSerializer;
  AList: TObjectList<TMyClass>;
  JSON: string;
  i: Integer;
begin
  //反序列化 JSON 为 ObjectList
  JSON := Memo1.Lines.Text;
  Seri := TJsonSerializer.Create;
  AList := Seri.Deserialize<TObjectList<TMyClass>>(JSON);

  for I := 0 to Pred(AList.Count) do
  begin
    Memo1.Lines.Add(AList[i].FName + ': ' + AList[i].FValue.ToString);
  end;

  Seri.Free;
  AList.Free;
end;


end.

以前测试过使用 TJson.ObjectToJsonString 和 TJson.JsonToObject，发现好像有 BUG，不稳定。

这次测试的是使用 TJsonSerializer, 测试没发现问题。