CMD内的各个段名解释，dsp内使用malloc

最新推荐文章于 2025-02-18 16:26:56 发布

ngany

最新推荐文章于 2025-02-18 16:26:56 发布

阅读量2.3k

点赞数 2

分类专栏： DSP 文章标签： DSP CMD 动态内存

DSP 专栏收录该内容

4 篇文章

订阅专栏

CMD文件里有两个基本的段：初始化段和非初始化段。初始化段包含代码和常数等必须在DSP上电之后有效的数。故初始化块必须保存在如片内FLASH等非易失性存储器中，非初始化段中含有在程序运行过程中才像变量内写数据进去，所以非初始化段必须链接到易失性存储器中如RAM。

已初始化的段：.text,.cinit,.const,.econst,.pinit和.switch..
.text：所有可以执行的代码和常量
.cinit:全局变量和静态变量的C初始化记录，包含未用const声明的外部（extern）或静态（static）数据表
.const：包含字符串常量和初始化的全局变量和静态变量（由const）的初始化和说明
.econst：包含字符串常量和初始化的全局变量和静态变量（由far const）的初始化和说明，与.const不同的是.const分配范围被限制在低64K 16位数据区，而.econst的分配范围是4M 22位数据区
.pinit：全局构造器（C++）程序列表
.switch：包含switch声明的列表

非初始化的段：.bss,.ebss,.stack,.sysmem,和esysmem.（更好的理解就是，这些段就是存储空间而已）
.bss: 为全局变量和局部变量保留的空间，在程序上电时.cinit空间中的数据复制出来并存储在.bss空间中。
.ebss：为使用大寄存器模式时的全局变量和静态变量预留的空间，在程序上电时，cinit空间中的数据复制出来并存储在.ebss中，与.bss不同的是.bss分配范围被限制在低64K 16位数据区，而.ebss的分配范围是4M 22位数据区
.stack:为系统堆栈保留的空间，用于和函数传递变量或为局部变量分配空间。
.sysmem:为动态存储分配保留的空间。如果有宏函数，此空间被宏函数占用，如果没有的话，此空间保留为0
.esysmem:为动态存储分配保留的空间。如果有far函数，此空间被相应的占用，如果没有的化，此空间保留为0.

编译器生成的包含代码和数据的多个部分，称为段。这下段被分为两个不同的组：初始化了的和没被初始化的，初始化的部分是由所有的代码，常量和初始化表组成的。下表列出了由编译器产生的初始化段。

初始化段
段名	内容	限制
.cinit	显式初始化的全局变量和静态变量表	代码
.const	显式初始化的全局和静态的const变量和字符串常量	不超过64K长度
.econst	长调用的常量	数据中的任何地方
.pinit	全局对象的构造函数表	代码
.switch	switch语句产生的表	代码或者数据
.text	可执行代码和常数	代码

没初始化的段是由未初始化的变量，堆栈和malloc产生的内存。下表列出了由编译器产生的没初始化段。

没初始化段
段名	内容	限制
.bss	全局和静态变量	不超过64K长度
.ebss	长调用的全局或静态变量	数据中的任何地方
.stack	堆栈空间	不超过64K长度
.sysmem	malloc函数产生的内存	不超过64K长度
.esysmem	far_malloc函数产生的内存	数据中的任何地方

一旦编译器生成的这些段，连接器会从各个源文件中取出这些段，并结合它们来创建一个输出文件。连接器命令文件（.cmd）就是用来告诉连接器去哪里找这些段的。初始化段必须分配到非易失性存储器，如flash/ ROM，当电源被撤除时，程序不会消失。未初始化的段可以被分配到RAM中，因为它们是在代码执行期间被初始化的。

当需要把程序从flash复制到RAM里时，各个段分配参考如下：

.cinit	Flash
.cio	RAM
.const	Flash
.econst	Flash
.pinit	Flash
.switch	Flash
.text	Flash
.bss	RAM
.ebss	RAM
.stack	Lower 64Kw RAM
.sysmem	RAM
.esysmem	RAM
.reset	RAM1

---------------------------------------------------------------------------------------------------------------------------------------------------------------------

2806的CMD文件：

MEMORY
{
PAGE 0:    /* Program Memory */
           /* Memory (RAM/FLASH/OTP) blocks can be moved to PAGE1 for data allocation */

   RAML0       : origin = 0x008000, length = 0x001000     /* on-chip RAM block L0 */
   OTP         : origin = 0x3D7800, length = 0x000400     /* on-chip OTP */
//   FLASHD      : origin = 0x3F0000, length = 0x002000     /* on-chip FLASH */
//   FLASHC      : origin = 0x3F2000, length = 0x002000     /* on-chip FLASH */
//   FLASHA      : origin = 0x3F6000, length = 0x001F80     /* on-chip FLASH */
   FLASH       : origin = 0x3F0000, length = 0x005F80     /* on-chip FLASH */
   CSM_RSVD    : origin = 0x3F7F80, length = 0x000076     /* Part of FLASHA.  Program with all 0x0000 when CSM is in use. */
   BEGIN       : origin = 0x3F7FF6, length = 0x000002     /* Part of FLASHA.  Used for "boot to Flash" bootloader mode. */
   CSM_PWL     : origin = 0x3F7FF8, length = 0x000008     /* Part of FLASHA.  CSM password locations in FLASHA */
   
   ROM         : origin = 0x3FF000, length = 0x000FC0     /* Boot ROM */
   RESET       : origin = 0x3FFFC0, length = 0x000002     /* part of boot ROM  */
   VECTORS     : origin = 0x3FFFC2, length = 0x00003E     /* part of boot ROM  */

PAGE 1 :   /* Data Memory */
           /* Memory (RAM/FLASH/OTP) blocks can be moved to PAGE0 for program allocation */
           /* Registers remain on PAGE1                                                  */

   RAMM0       : origin = 0x000000, length = 0x000400     /* on-chip RAM block M0 */
   BOOT_RSVD   : origin = 0x000400, length = 0x000080     /* Part of M1, BOOT rom will use this for stack */
   RAMM1       : origin = 0x000480, length = 0x000380     /* on-chip RAM block M1 */
   RAML1       : origin = 0x009000, length = 0x001000     /* on-chip RAM block L1 */
   FLASHB      : origin = 0x3F4000, length = 0x002000     /* on-chip FLASH */
}

/* Allocate sections to memory blocks.
   Note:
         codestart user defined section in DSP28_CodeStartBranch.asm used to redirect code 
                   execution when booting to flash
         ramfuncs  user defined section to store functions that will be copied from Flash into RAM
*/ 
 
SECTIONS
{
 
   /* Allocate program areas: */
   .cinit              : > FLASH      PAGE = 0
   .pinit              : > FLASH,     PAGE = 0
   .text               : > FLASH      PAGE = 0
   codestart           : > BEGIN       PAGE = 0
   ramfuncs            : LOAD = FLASH,
                         RUN = RAML0,
                         LOAD_START(_RamfuncsLoadStart),
                         LOAD_END(_RamfuncsLoadEnd),
                         RUN_START(_RamfuncsRunStart),
                         PAGE = 0

   csmpasswds          : > CSM_PWL     PAGE = 0
   csm_rsvd            : > CSM_RSVD    PAGE = 0
   
   /* Allocate uninitalized data sections: */
   .stack              : > RAMM0       PAGE = 1
   .ebss               : > RAML1       PAGE = 1
   .esysmem            : > RAML1       PAGE = 1

   /* Initalized sections go in Flash */
   /* For SDFlash to program these, they must be allocated to page 0 */
   .econst             : > FLASH      PAGE = 0
   .switch             : > FLASH      PAGE = 0

   /* Allocate IQ math areas: */
   IQmath              : > FLASH      PAGE = 0                  /* Math Code */
   IQmathTables        : > ROM         PAGE = 0, TYPE = NOLOAD   /* Math Tables In ROM */

   /* .reset is a standard section used by the compiler.  It contains the */ 
   /* the address of the start of _c_int00 for C Code.   /*
   /* When using the boot ROM this section and the CPU vector */
   /* table is not needed.  Thus the default type is set here to  */
   /* DSECT  */ 
   .reset              : > RESET,      PAGE = 0, TYPE = DSECT
   vectors             : > VECTORS     PAGE = 0, TYPE = DSECT

}

错误情况：一旦使用到malloc函数时，系统进入非法中断ILLEGAL_ISR()，申请后地址是0。

实际原因为.esysmem : > FLASHB PAGE = 1这条语句不对，改为.esysmem : > RAML1 PAGE = 1

内存堆是放在RAM内的，并且配置中的Heap大小要适合。不能大于RAML1分配的大小。