Unity Shader学习四：基础光照模型

已于 2023-09-28 15:26:55 修改
阅读量337 收藏 1
点赞数
分类专栏： Unity Shader学习笔记 文章标签： unity 学习 游戏引擎
于 2023-09-28 13:55:08 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.youkuaiyun.com/miwuwu/article/details/133357723
版权

        观前提示：本文章是个人笔记，只是给自己看的，我自己看得懂就行。

一、逐顶点光照和逐像素光照

1、逐顶点光照

        逐顶点光照或高洛德着色（Gouraud shading）, 在每个顶点上计算光照，然后在渲染图元内部进行线性插值，输出成像素颜色。而顶点数目通常会远小于像素数目，所以逐顶点光照的计算量往往更小。

2、逐像素光照

        逐像素光照或Phong着色，先在渲染图元内部进行线性插值，然后在每个像素上计算光照、像素颜色。像素数目远大于顶点数目，逐像素光照的计算量更大且计算更复杂，性能消耗也更大，但效果好，光照更加细腻精准。

二、漫反射光照模型

        漫反射光照是用于被物体表面随机散射到各个方向的辐射度进行的建模，也被称为兰伯特光照模型。在漫反射中视角的位置是不重要的，因为反射是完全随机的，所以在任何反射方向都是随机的。但是入射光线的角度很重要。

        漫反射光照（兰伯特定律）        

        漫反射光照 = 光源的颜色 * 材质的漫反射颜色 * MAX（0, 标准化后物体表面法线向量· 标准化后光源方向向量）

        光源颜色：场景中光GameObject取得

        材质的漫反射颜色：材质球配置

        Max是数学函数，标准化也有函数

        表面法线向量：CPU加载模型后，传递到GPU中的

        光源方向向量：场景中光GameObject取得

        逐顶点漫反射光照代码：

Shader "test/DiffuseVertex"
{
    Properties
    {
        _DiffuseColor("DiffuseColor",Color) = (1,1,1,1)
    }
    SubShader
    {
        Pass
        {
            //设定光照模式为前向模式（只有设置了光照模式，才能正常获取光的颜色和方向）
            Tags { "LightMode" = "ForwardBase" }

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            //加载Cg语言的脚本，用来 处理光照参数
            //处理光照的Cg库文件（cginc扩展名），目录在Unity的安装目录下Editor/Data/CGIncludes/Lighting.cginc
            #include "Lighting.cginc"

            //导入材质颜色
            fixed4 _DiffuseColor;

            //如果在Cg编程中，顶点或片元着色器接受多个参数的时候，一般会用结构体实现
            //从CPU接收到的数据
            struct c2v
            {
                float4 vertex:POSITION;//从CPU接收到的模型空间下的点的位置
                float3 normal:NORMAL;//从CPU接收到的当前点的模型空间下的法线向量
            };

            struct v2f
            {
                float4 pos:SV_POSITION;//经过顶点着色器计算后的，当前点的裁剪空间下的位置
                fixed3 color:COLOR;//经过兰伯特定律计算后的当前点的颜色 
            };

            //高洛德着色（逐顶点光照），光照计算应该编写在顶点着色器上中
            v2f vert(c2v data)
            {
                //顶点着色器传递给片元着色器的数据结构体声明
                v2f r;

                //必须要做的，将点从模型空间下，转化到裁剪空间下
                r.pos =  UnityObjectToClipPos(data.vertex);

                //光照是在世界中发生的，需要将所有的数值，变换到世界坐标系下，再运算
                //_Object2World矩阵是Unity提供的用于转换模型空间下到世界空间下的转换矩阵
                //因为法线传递过来的是3x1的列矩阵，_Object2World是4x4的齐次矩阵，如果想做矩阵乘法，需要将齐次矩阵，变成3x3的矩阵
                fixed3 worldNormal = normalize(mul((float3x3)unity_ObjectToWorld,data.normal));
                //获得直射光的光方向
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);

                //兰伯特定律计算
                //漫反射光照 = 光源的颜色 * 材质的漫反射颜色 * MAX(0，标准化后物体表面法线向量 * 标准化后光源方向向量)
                fixed3 diffuse = _LightColor0.rgb * _DiffuseColor.rgb * max(0,dot(worldNormal,worldLightDir));

                //根据Phong光照模型，将环境光追加在最终计算后的颜色上
                r.color = UNITY_LIGHTMODEL_AMBIENT.xyz + diffuse;

                return r;
            }

            fixed4 frag(v2f data):SV_Target
            {
                return fixed4(data.color,1.0);
            }
            ENDCG
        }
    }

    FallBack  "DIFFUSE"
}

        逐像素漫反射光照代码：

Shader "test/DiffusePixel"
{
    Properties
    {
        _DiffuseColor("DiffuseColor",Color) = (1,1,1,1)
    }
    SubShader
    {
        Pass
        {
            //设定光照模式为前向模式（只有设置了光照模式，才能正常获取光的颜色和方向）
            Tags { "LightMode" = "ForwardBase" }

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            //加载Cg语言的脚本，用来 处理光照参数
            //处理光照的Cg库文件（cginc扩展名），目录在Unity的安装目录下Editor/Data/CGIncludes/Lighting.cginc
            #include "Lighting.cginc"

            //导入材质颜色
            fixed4 _DiffuseColor;

            //如果在Cg编程中，顶点或片元着色器接受多个参数的时候，一般会用结构体实现
            //从CPU接收到的数据
            struct c2v
            {
                float4 vertex:POSITION;//从CPU接收到的模型空间下的点的位置
                float3 normal:NORMAL;//从CPU接收到的当前点的模型空间下的法线向量
            };

            //因为在顶点着色器中，需要计算裁剪空间下点的位置和高洛德着色计算出来的兰伯特定律计算后的颜色
            struct v2f
            {
                float4 pos:SV_POSITION;//经过顶点着色器计算后的，当前点的裁剪空间下的位置
                fixed3 worldNormal:NORMAL;//经过矩阵转换后的法线向量
            };

            //顶点着色器将渲染点从模型空间下转换到裁剪空间下
            //将舒安然点对应的法线向量，从模型空间下转换到世界空间下
            v2f vert(c2v data)
            {
                //顶点着色器传递给片元着色器的数据结构体声明
                v2f r;

                //必须要做的，将点从模型空间下，转化到裁剪空间下
                r.pos =  UnityObjectToClipPos(data.vertex);

                //几何运算，在顶点着色器中完成，再将运算好的数值，传递给片元着色器
                //_Object2World矩阵是Unity提供的用于转换模型空间下到世界空间下的转换矩阵
                //因为法线传递过来的是3x1的列矩阵，_Object2World是4x4的齐次矩阵，如果想做矩阵乘法，需要将齐次矩阵，变成3x3的矩阵
                r.worldNormal = mul((float3x3)unity_ObjectToWorld,data.normal);
                
                return r;
            }

            fixed4 frag(v2f data):SV_Target
            {
                //光照是在世界中发生的，需要将所有的数值，变换到世界坐标系下，再运算

                //获得直射光的光方向
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);

                //兰伯特定律计算
                //漫反射光照 = 光源的颜色 * 材质的漫反射颜色 * MAX(0，标准化后物体表面法线向量 * 标准化后光源方向向量)
                fixed3 diffuse = _LightColor0.rgb * _DiffuseColor.rgb * max(0,dot(normalize(data.worldNormal),worldLightDir));

                //根据Phong光照模型，将环境光追加在最终计算后的颜色上
                fixed3 color = UNITY_LIGHTMODEL_AMBIENT.xyz + diffuse;
                return fixed4(color,1.0);
            }
            ENDCG
        }
    }

    FallBack  "DIFFUSE"
}

        半兰伯特定律，将整体颜色降低一半，再加一半

        漫反射光照 = 光源的颜色 * 材质的漫反射颜色 * ((标准化后物体表面法线向量· 标准化后光源方向向量) * 0.5 + 0.5)

        半兰伯特定律代码：

Shader "test/HalfLambert"
{
    Properties
    {
        _DiffuseColor("DiffuseColor",Color) = (1,1,1,1)
    }
    SubShader
    {
        Pass
        {
            //设定光照模式为前向模式（只有设置了光照模式，才能正常获取光的颜色和方向）
            Tags { "LightMode" = "ForwardBase" }

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            //加载Cg语言的脚本，用来 处理光照参数
            //处理光照的Cg库文件（cginc扩展名），目录在Unity的安装目录下Editor/Data/CGIncludes/Lighting.cginc
            #include "Lighting.cginc"

            //导入材质颜色
            fixed4 _DiffuseColor;

            //如果在Cg编程中，顶点或片元着色器接受多个参数的时候，一般会用结构体实现
            //从CPU接收到的数据
            struct c2v
            {
                float4 vertex:POSITION;//从CPU接收到的模型空间下的点的位置
                float3 normal:NORMAL;//从CPU接收到的当前点的模型空间下的法线向量
            };

            //因为在顶点着色器中，需要计算裁剪空间下点的位置和高洛德着色计算出来的兰伯特定律计算后的颜色
            struct v2f
            {
                float4 pos:SV_POSITION;//经过顶点着色器计算后的，当前点的裁剪空间下的位置
                fixed3 worldNormal:NORMAL;//经过矩阵转换后的法线向量
            };

            //顶点着色器将渲染点从模型空间下转换到裁剪空间下
            //将舒安然点对应的法线向量，从模型空间下转换到世界空间下
            v2f vert(c2v data)
            {
                //顶点着色器传递给片元着色器的数据结构体声明
                v2f r;

                //必须要做的，将点从模型空间下，转化到裁剪空间下
                r.pos =  UnityObjectToClipPos(data.vertex);

                //几何运算，在顶点着色器中完成，再将运算好的数值，传递给片元着色器
                //_Object2World矩阵是Unity提供的用于转换模型空间下到世界空间下的转换矩阵
                //因为法线传递过来的是3x1的列矩阵，_Object2World是4x4的齐次矩阵，如果想做矩阵乘法，需要将齐次矩阵，变成3x3的矩阵
                r.worldNormal = mul((float3x3)unity_ObjectToWorld,data.normal);
                
                return r;
            }

            fixed4 frag(v2f data):SV_Target
            {
                //光照是在世界中发生的，需要将所有的数值，变换到世界坐标系下，再运算

                //获得直射光的光方向
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);

                //半兰伯特定律计算
                //漫反射光照 = 光源的颜色 * 材质的漫反射颜色 * ((标准化后物体表面法线向量· 标准化后光源方向向量) * 0.5 + 0.5)
                fixed3 diffuse = _LightColor0.rgb * _DiffuseColor.rgb * (dot(normalize(data.worldNormal),worldLightDir) * 0.5 + 0.5);

                //根据Phong光照模型，将环境光追加在最终计算后的颜色上
                fixed3 color = UNITY_LIGHTMODEL_AMBIENT.xyz + diffuse;
                return fixed4(color,1.0);
            }
            ENDCG
        }
    }

    FallBack  "DIFFUSE"
}

三、高光反射光照模型

        高光反射可用于那些沿着完全镜面反射方向被反射的光线，可以让物体看起来是有光泽的。在现实世界中，粗糙的物体一般会是漫反射，而光滑的物体呈现得较多的就是镜面反射，最明显的现象就是光线照射的反射方向有一个亮斑。

        逐顶点高光反射光照代码：

Shader "test/SpecularVertex"
{
    Properties
    {
        //高光反射材质颜色
        _SpecularColor("SpecularColor",Color) = (1,1,1,1)
        //光晕系数，控制光斑的大小
        _Gloss("Gloss",Range(4,256)) = 10
    }
    SubShader
    {
        Pass
        {
            //设定光照模式为前向模式（只有设置了光照模式，才能正常获取光的颜色和方向）
            Tags { "LightMode" = "ForwardBase" }

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            //加载Cg语言的脚本，用来 处理光照参数
            //处理光照的Cg库文件（cginc扩展名），目录在Unity的安装目录下Editor/Data/CGIncludes/Lighting.cginc
            #include "Lighting.cginc"

            //导入材质颜色
            fixed4 _SpecularColor;
            //导入高光光晕大小系数
            fixed _Gloss;

            //如果在Cg编程中，顶点或片元着色器接受多个参数的时候，一般会用结构体实现
            //从CPU接收到的数据
            struct c2v
            {
                float4 vertex:POSITION;//从CPU接收到的模型空间下的点的位置
                float3 normal:NORMAL;//从CPU接收到的当前点的模型空间下的法线向量
            };

            struct v2f
            {
                float4 pos:SV_POSITION;//经过顶点着色器计算后的，当前点的裁剪空间下的位置
                fixed3 color:COLOR;//经过兰伯特定律计算后的当前点的颜色 
            };

            v2f vert(c2v data)
            {
                //顶点着色器传递给片元着色器的数据结构体声明
                v2f r;

                //必须要做的，将点从模型空间下，转化到裁剪空间下
                r.pos =  UnityObjectToClipPos(data.vertex);

                //光照是在世界中发生的，需要将所有的数值，变换到世界坐标系下，再运算
                //_Object2World矩阵是Unity提供的用于转换模型空间下到世界空间下的转换矩阵
                //因为法线传递过来的是3x1的列矩阵，_Object2World是4x4的齐次矩阵，如果想做矩阵乘法，需要将齐次矩阵，变成3x3的矩阵
                fixed3 worldNormal = normalize(mul((float3x3)unity_ObjectToWorld,data.normal));

                //观察方向（相机的位置 - 被渲染点的位置，是在世界空间下的坐标）
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld, data.vertex).xyz);

                //光线反射的方向：reflect(入射光方向，当前点的法线向量)
                fixed3 refDir = normalize(reflect(normalize(-_WorldSpaceLightPos0.xyz),worldNormal));

                //高光反射计算
                //高光光照 = 光源的颜色 * 材质的高光反射颜色 * MAX(0，标准化后的观察方向 * 标准化后的反射方向)^光晕系数
                fixed3 Specular = _LightColor0.rgb * _SpecularColor.rgb * pow(max(0,dot(viewDir,refDir)),_Gloss);

                //根据Phong光照模型，将环境光追加在最终计算后的颜色上
                r.color = UNITY_LIGHTMODEL_AMBIENT.xyz + Specular;

                return r;
            }

            fixed4 frag(v2f data):SV_Target
            {
                return fixed4(data.color,1.0);
            }
            ENDCG
        }
    }

    FallBack  "DIFFUSE"
}

        逐像素高光反射代码：

Shader "test/SpecularPixel"
{
    Properties
    {
        //高光反射材质颜色
        _SpecularColor("SpecularColor",Color) = (1,1,1,1)
        //光晕系数，控制光斑的大小
        _Gloss("Gloss",Range(4,256)) = 10
    }
    SubShader
    {
        Pass
        {
            //设定光照模式为前向模式（只有设置了光照模式，才能正常获取光的颜色和方向）
            Tags { "LightMode" = "ForwardBase" }

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            //加载Cg语言的脚本，用来 处理光照参数
            //处理光照的Cg库文件（cginc扩展名），目录在Unity的安装目录下Editor/Data/CGIncludes/Lighting.cginc
            #include "Lighting.cginc"

            //导入材质颜色
            fixed4 _SpecularColor;
            //导入高光光晕大小系数
            fixed _Gloss;

            //如果在Cg编程中，顶点或片元着色器接受多个参数的时候，一般会用结构体实现
            //从CPU接收到的数据
            struct c2v
            {
                float4 vertex:POSITION;//从CPU接收到的模型空间下的点的位置
                float3 normal:NORMAL;//从CPU接收到的当前点的模型空间下的法线向量
            };

            struct v2f
            {
                float4 pos:SV_POSITION;//经过顶点着色器计算后的，当前点的裁剪空间下的位置
                float4 worldPos:TEXCOORD0;//借用纹理的语义实现世界空间下点的位置传递
                float3 normal:NORMAL;//世界空间下，法线的方向
            };

            v2f vert(c2v data)
            {
                //顶点着色器传递给片元着色器的数据结构体声明
                v2f r;

                //必须要做的，将点从模型空间下，转化到裁剪空间下
                r.pos =  UnityObjectToClipPos(data.vertex);

                //被渲染点的位置，是在世界空间下的坐标
                r.worldPos = mul(unity_ObjectToWorld, data.vertex);

                //世界坐标下，法线的方向向量
                r.normal = mul((float3x3)unity_ObjectToWorld,data.normal);

                return r;
            }

            fixed4 frag(v2f data):SV_Target
            {
                //将顶点着色器传过来的法线向量标准化
                fixed3 worldNormal = normalize(data.normal);

                //使用相机位置减去顶点着色器计算的世界坐标系下的点的位置，并标准化
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - data.worldPos.xyz);

                //光线反射的方向：reflect(入射光方向，当前点的法线向量)
                fixed3 refDir = normalize(reflect(normalize(-_WorldSpaceLightPos0.xyz),worldNormal));

                //高光反射计算
                //高光光照 = 光源的颜色 * 材质的高光反射颜色 * MAX(0，标准化后的观察方向 * 标准化后的反射方向)^光晕系数
                fixed3 Specular = _LightColor0.rgb * _SpecularColor.rgb * pow(max(0,dot(viewDir,refDir)),_Gloss);

                //根据Phong光照模型，将环境光追加在最终计算后的颜色上
                fixed3 color = UNITY_LIGHTMODEL_AMBIENT.xyz + Specular;

                return fixed4(color,1.0);
            }
            ENDCG
        }
    }

    FallBack  "DIFFUSE"
}

四、Phong光照模型

        标准光照的构成结构：

        自发光：材质本身发出的光，模拟环境使用的光。

        漫反射光：光照到粗糙材质后，光的反射方向随机，还有一些光发生了折射，造成材质表面没有明显的光斑。

        高光反射光：光照到材质表面后，无（低）损失直接反射给观察者眼睛，材质表面能观察到光斑。

        环境光：模拟场景光照（简单理解为太阳光）。

        裴祥凤提出的光照理论：标准光照 = 自发光 + 漫反射光 + 高光反射光 + 环境光

        这个理论是模拟光照效果，并不是真实效果。以他的名字命名：Phong光照模型。

        逐顶点Phong光照代码：

Shader "test/PhongVertex"
{
    Properties
    {
        //漫反射反射材质颜色
        _DiffuseColor("DiffuseColor",Color) = (1,1,1,1)
        //高光反射材质颜色
        _SpecularColor("SpecularColor",Color) = (1,1,1,1)
        //光晕系数
        _Gloss("Gloss",Range(4,256)) = 10
    }
    SubShader
    {
        Pass
        {
            //设定光照模式为前向模式（只有设置了光照模式，才能正常获取光的颜色和方向）
            Tags { "LightMode" = "ForwardBase" }

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            //加载Cg语言的脚本，用来 处理光照参数
            //处理光照的Cg库文件（cginc扩展名），目录在Unity的安装目录下Editor/Data/CGIncludes/Lighting.cginc
            #include "Lighting.cginc"

            //导入漫反射反射材质颜色
            fixed4 _DiffuseColor;
            //导入高光反射材质颜色
            fixed4 _SpecularColor;
            //导入高光光晕大小系数
            fixed _Gloss;

            //如果在Cg编程中，顶点或片元着色器接受多个参数的时候，一般会用结构体实现
            //从CPU接收到的数据
            struct c2v
            {
                float4 vertex:POSITION;//从CPU接收到的模型空间下的点的位置
                float3 normal:NORMAL;//从CPU接收到的当前点的模型空间下的法线向量
            };

            //因为在顶点着色器中，运算Phong光照模型
            struct v2f
            {
                float4 pos:SV_POSITION;//经过顶点着色器计算后的，当前点的裁剪空间下的位置
                fixed3 color:COLOR;//经过Phong光照模型运算后的当前点的颜色 
            };

            v2f vert(c2v data)
            {
                //顶点着色器传递给片元着色器的数据结构体声明
                v2f r;

                //必须要做的，将点从模型空间下，转化到裁剪空间下
                r.pos =  UnityObjectToClipPos(data.vertex);

                //标准化后物体表面法线向量
                fixed3 worldNormal = normalize(mul((float3x3)unity_ObjectToWorld,data.normal));

                //观察方向（相机的位置 - 被渲染点的位置，是在世界空间下的坐标）
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld, data.vertex).xyz);

                //光线反射的方向：reflect(入射光方向，当前点的法线向量)
                fixed3 refDir = normalize(reflect(normalize(-_WorldSpaceLightPos0.xyz),worldNormal));

                //高光反射计算
                //高光光照 = 光源的颜色 * 材质的高光反射颜色 * MAX(0，标准化后的观察方向 * 标准化后的反射方向)^光晕系数
                fixed3 Specular = _LightColor0.rgb * _SpecularColor.rgb * pow(max(0,dot(viewDir,refDir)),_Gloss);


                //标准化后光源方向向量
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);

                //兰伯特定律计算
                //漫反射光照 = 光源的颜色 * 材质的漫反射颜色 * MAX(0，标准化后物体表面法线向量 * 标准化后光源方向向量)
                fixed3 diffuse = _LightColor0.rgb * _DiffuseColor.rgb * max(0,dot(worldNormal,worldLightDir));

                //根据Phong光照模型，将环境光追加在最终计算后的颜色上
                r.color = UNITY_LIGHTMODEL_AMBIENT.xyz +diffuse + Specular;

                return r;
            }

            fixed4 frag(v2f data):SV_Target
            {
                return fixed4(data.color,1.0);
            }
            ENDCG
        }
    }
}

        逐像素Phong光照代码：

Shader "test/PhongPixel"
{
    Properties
    {
        //漫反射反射材质颜色
        _DiffuseColor("DiffuseColor",Color) = (1,1,1,1)
        //高光反射材质颜色
        _SpecularColor("SpecularColor",Color) = (1,1,1,1)
        //光晕系数
        _Gloss("Gloss",Range(4,256)) = 10
    }
    SubShader
    {
        Pass
        {
            //设定光照模式为前向模式（只有设置了光照模式，才能正常获取光的颜色和方向）
            Tags { "LightMode" = "ForwardBase" }

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            //加载Cg语言的脚本，用来 处理光照参数
            //处理光照的Cg库文件（cginc扩展名），目录在Unity的安装目录下Editor/Data/CGIncludes/Lighting.cginc
            #include "Lighting.cginc"

            //导入漫反射反射材质颜色
            fixed4 _DiffuseColor;
            //导入高光反射材质颜色
            fixed4 _SpecularColor;
            //导入高光光晕大小系数
            fixed _Gloss;

            //如果在Cg编程中，顶点或片元着色器接受多个参数的时候，一般会用结构体实现
            //从CPU接收到的数据
            struct c2v
            {
                float4 vertex:POSITION;//从CPU接收到的模型空间下的点的位置
                float3 normal:NORMAL;//从CPU接收到的当前点的模型空间下的法线向量
            };

            //因为在顶点着色器中，运算Phong光照模型
            struct v2f
            {
                float4 pos:SV_POSITION;//经过顶点着色器计算后的，当前点的裁剪空间下的位置
                float4 worldPos:TEXCOORD0;//借用纹理的语义实现世界空间下点的位置传递
                float3 worldNormal:NORMAL;//世界空间下，法线的方向
            };

            v2f vert(c2v data)
            {
                //顶点着色器传递给片元着色器的数据结构体声明
                v2f r;

                //必须要做的，将点从模型空间下，转化到裁剪空间下
                r.pos =  UnityObjectToClipPos(data.vertex);

                //被渲染点的位置，是在世界空间下的坐标
                r.worldPos = mul(unity_ObjectToWorld, data.vertex);

                //世界坐标下，法线的方向向量
                r.worldNormal = mul((float3x3)unity_ObjectToWorld,data.normal);

                return r;
            }

            fixed4 frag(v2f data):SV_Target
            {
                //将顶点着色器传过来的法线向量标准化
                fixed3 worldNormal = normalize(data.worldNormal);

                //使用相机位置减去顶点着色器计算的世界坐标系下的点的位置，并标准化
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - data.worldPos.xyz);

                //光线反射的方向：reflect(入射光方向，当前点的法线向量)
                fixed3 refDir = normalize(reflect(normalize(-_WorldSpaceLightPos0.xyz),worldNormal));

                //高光反射计算
                //高光光照 = 光源的颜色 * 材质的高光反射颜色 * MAX(0，标准化后的观察方向 * 标准化后的反射方向)^光晕系数
                fixed3 Specular = _LightColor0.rgb * _SpecularColor.rgb * pow(max(0,dot(viewDir,refDir)),_Gloss);

                //获得直射光的光方向
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);

                //兰伯特定律计算
                //漫反射光照 = 光源的颜色 * 材质的漫反射颜色 * MAX(0，标准化后物体表面法线向量 * 标准化后光源方向向量)
                fixed3 diffuse = _LightColor0.rgb * _DiffuseColor.rgb * max(0,dot(worldNormal,worldLightDir));

                fixed3 color = UNITY_LIGHTMODEL_AMBIENT.xyz +diffuse + Specular;
                return fixed4(color,1.0);
            }
            ENDCG
        }
    }
}

真实图形学（光照模型）
smilejiasmile的博客
04-30 2万+
一 、颜色模型 真实感图形学，简单地说，就是希望用计算机生成像照相机拍的照片一样逼真的图形图像 。要实现这个目标，需要三部曲： 第一步：建立三维场景（建模）； 第二步：消隐解决物体深度的显示及确定物体之内的相互关系； 第三步：在解决了消隐问题之后，在可见面上进行明暗光泽的处理，然后进行绘制（渲染）。 一 、颜色模型概述 颜色：人的视觉系统对可见光...
【Unity Shader】（１）兰伯特模型 逐顶点光照 和 逐像素光照 分别实现 漫反射光照模型
１eonＣhan的博客
04-05 1752
使用逐顶点光照在unityShader中实现漫反射效果 漫反射公式 首先需要了解基本光照模型中，漫反射（Diffuse） 其中共有4个参数 入射光线的颜色和强度—— C light 材质的漫反射系数—— M diffuse 表面法线—— n 光源方向—— I 为了避免 n 和 I 的点积为负值，我们需要使用max来操作。但在Unity Shader中，我们可以使用 saturate(x)函数达到相同的效果。 其中，x可以是操作的标量或矢量，即float、float2、float3等类型 satura
shader入门精要：Blinn-Phone光照模型（逐像素）（笔记8）
笔记001
04-05 867
Shader "Unity Shaders Book/Chapter 6/Blinn-Phong" { Properties { _Diffuse ("Diffuse", Color) = (1, 1, 1, 1) _Specular ("Specular", Color) = (1, 1, 1, 1) _Gloss ("Gloss", Range(8.0, 256)) = 20 ...
计算机图形学——光照模型
szk972092933的博客
04-11 9064
 光线照到物体表面发生三种情况：反射、投射、吸收转换为热能。只有反射光和投射光能够刺激眼睛产生颜色，因而物体表面的反射光和投射光决定了物体呈现的颜色。一、光照明模型    目的：产生明暗过度自然的真实感图形。    概念：描述了物体表面的颜色与其空间位置、朝向、物理属性（反射率、折射率）及光源之间的关系。二、发展历程    1.早期光照明模型基于经验，只能反映光源直接照射的情况。    2.比较精...
Phong Illumination（冯氏光照模型）浅析
weixin_33695450的博客
11-12 490
原作者Paul Nettle，感谢！需要原文的朋友可以google之 (^ ^) 很多人把冯氏光照（Phong Illumination）和冯氏渲染（phong shading）混淆到一起。冯氏渲染是指计算基于每像素的与表面相交的法向量的插值过程。你可以对每个像素做你喜欢的光照效果，或者对每个顶点做冯氏光照计算，在物体表面使用高洛德着色（Gouradu shading）。 冯氏光...
Chapter6 Unity中的基础光照——Shader入门精要学习笔记
最新发布
weixin_70073176的博客
06-23 812
【代码】Chapter6 Unity中的基础光照——Shader入门精要学习。
「UnityShader学习笔记」02使用Unity Shader实现Blinn-Phong光照模型
Enterprise530的博客
03-24 3233
Part1 完整代码 Shader "Light/Blinn-Phong" { Properties { _Diffuse("Diffuse",Color) = (1,1,1,1) _Specular("Specular",Color) = (1,1,1,1) _Gloss("Gloss",Range(8.0,256)) = 20 } SubShader { pass {
UnityShader深入解析：兰伯特与半兰伯特漫反射光照模型
UnityShader中对漫反射的实现有两种主要的光照模型：兰伯特（Lambert）模型和半兰伯特（Blinn-Phong模型的一个变种）模型。这两种模型都可以通过逐顶点（vertex）光照或逐像素（fragment或pixel）光照来实现。逐顶点...
unity shader 实现phong光照模型
o83290102o5的博客
02-17 1740
phong光照模型 phong光照模型是一个经验模型，并没有理论依据，只是说“看起来能像那么回事”。 优点当然是计算量很小，因为所用的公式都很简单，而且基本只要知道一些简单的属性就可以计算，比如坐标啊，光源方向啊，法线啊、完全不用模拟单条光线的路径之类的。 缺点就是比较粗糙，而且也没有办法模拟多次反射的效果。 目前在游戏领域不是光线追踪比较火嘛，因为以前的硬件没有那么高的算力来做光线追踪，在光线追踪之前就是这个经验模型及其变体运用的最广了。 phong光照模型把光线分为四个部分处理，分别是环境光，自发光，漫
Unity Shader : 实现Phong和Blinn-Phong光照模型
weixin_47260762的博客
01-09 3252
Phong光照模型包括几个部分：环境光、漫反射、高光反射（镜面反射）。 在unity进行shader编写时，环境光可以由内置函数直接获取。 漫反射部分定义如下：（来自冯乐乐的书） 其中出现的一些向量如图所示： l是光源方向，r是光的反射方向，n是物体表面法线方向，v是视角方向，也就是相机的方向。 在漫反射计算公式中，clight是光源颜色，mdiffuse是材质的漫反射颜色，核心部分是一个点乘，n dot l，需要注意的是，在使用这些向量之前，需要对它们进行归一化，因为我们需要的只是它的方向，大小并不关
UnityShader 漫反射（兰伯特与半兰伯特光照模型-逐顶点和逐像素光照）
05-15
漫反射光照是用于对那些被物体表面随机散射到各个方向的辐射度进行建模的。在漫反射中，视角的位置是不重要的，因为反射是完全随机的，因此可以认为在任何反射方向上的分布都是一样的。但是，入射光线的角度很重要。
一组可用的逐像素光照着色器
林一鸣的专栏
04-21 1784
顶点着色器：varying vec3 N; varying vec3 v; void main(void) { v = vec3(gl_ModelViewMatrix * gl_Vertex); N = normalize(gl_NormalMatrix * gl_Normal); gl_Position = gl_ModelViewProjectionMatrix * gl
逐顶点光照 逐像素光照 差异对比
weixin_43787178的博客
06-10 1109
逐顶点光照（Gouraud着色法） 先计算，再插值，控制精度为triangle； 在vertex阶段分别计算每个顶点的颜色值，在pixel阶段再通过双线性插值计算三角形区域中其它像素的颜色。 优点： 1.当处理高精度多边形模型时，由于每个多边形所覆盖的区域很小，因此插值之后每个像素的误差也很小，所以逐顶点光照可以工作的很好； 2.如果三角形所覆盖的像素数量大于顶点数量，其效率相对于pixel较高； 缺点： 1.若顶点过多，效率慢； 2.处理某些跨度较大的多边形（比如：低精度模型，弧度较大的模型），由于跨度较
顶点片元着色器：逐像素光照和逐顶点光照
weixin_42719913的博客
03-24 3243
在片元着色器中计算光照模型，成为逐像素光照；在顶点着色器中计算，称为逐顶点光照。 在逐像素光照中，会以每一个像素为基础进行光照计算，得到法线进行插值计算，这种技术叫做Phong着色。 逐顶点光照，也称为高洛德着色，我们在每一个顶点进行光照计算，然后会在渲染图元内部进行线性插值，最后输出成像素着色。 逐顶点光照的性能开销远远小于逐像素，这是因为顶点数远远要小于像素数（这也是为什么在移动平台sh...
【Unity Shader】（３）Phong光照模型 逐顶点光照 和 逐像素光照 分别实现 高光反射光照模型
１eonＣhan的博客
04-05 868
使用逐顶点光照和逐像素光照分别在unityShader中实现高光反射光照模型 **Phong高光反射模型** Phong高光反射模型 共有4个参数 入射光线的颜色和强度—— C light 材质的漫反射系数—— M specular 视线向量—— v 反射方向—— r 为了避免 v 和 r 的点积为负值，我们需要使用max来操作。但在Unity Shader中，我们可以使用 saturate(x)函数达到相同的效果。 其中的 r 可以直接使用如下公式计算： 在计算 r 的过程中，可以直接使用CG
Unity Shader入门精要 第六章——Unity中的基础光照
buzhengli的博客
07-21 2328
逐像素光照，以每个像素为基础，得到它的法线（可以是对顶点法线插值得到的，也可以是从法线纹理中采样得到的），然后进行光照模型计算，这种在面片之间对顶点法线进行插值的技术称为Phong着色，也被称为Phong插值或法线插值技术，这不同于Phong光照模型。上面两个模型(也叫兰伯特光照模型)有个问题就是，光照没有照射到的地方是全黑的，没有明暗变化，导致背面就像是有个平面一样。与原来的兰伯特光照模型相比，半兰伯特光照模型没有使用max操作来防止n*I的点积为负值，而是进行了一个α倍的缩放和β大小的偏移。
XNA Shader 逐顶点和逐像素光照
痞子龙3D编程
11-14 2267
逐顶点光照 所谓逐顶点光照，简单地说就是在vetext shader中计算光照颜色，该过程将为每个顶点计算一次光照颜色，然后在通过顶点在多边形所覆盖的区域对像素颜色进行线形插值。现实中，光照值取决于光线角度，表面法线，和观察点（对于镜面高光来说）。具体实现时的shader代码如下： //相关全局变量 shared float4x4 matWorldViewProj; shared floa
GLSL逐顶点的光照
PeakJin的博客
06-11 1726
本文转自下述博文，并在此基础上做了微小改动： 1. 【GLSL教程】（六）逐顶点的光照 2. 【GLSL教程】（七）逐像素的光照 引言 在OpenGL中有三种类型的光：方向光（directional）、点光（point）、聚光（spotlight）。 逐顶点光照的方向光，向shader中逐渐添加环境光、散射光和高光效果。 然后对方向光使用逐像素光照以获得更好的效果。 最后...
opengl光照之镜面光逐顶点渲染与逐像素渲染
hb707934728的博客
08-07 1555
镜面光逐顶点渲染效果 顶点shader attribute vec3 pos;//顶点坐标 attribute vec2 texcoord;//纹理坐标 attribute vec3 normal;//法线 uniform mat4 M;//模型矩阵 uniform mat4 P;//投影矩阵 uniform mat4 V;//摄像机观察矩阵 uniform mat4 NM;//将法
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值