wikioi1069 关押罪犯

题目描述 Description

S 城现有两座监狱，一共关押着N 名罪犯，编号分别为1~N。他们之间的关系自然也极

不和谐。很多罪犯之间甚至积怨已久，如果客观条件具备则随时可能爆发冲突。我们用“怨

气值”（一个正整数值）来表示某两名罪犯之间的仇恨程度，怨气值越大，则这两名罪犯之

间的积怨越多。如果两名怨气值为c 的罪犯被关押在同一监狱，他们俩之间会发生摩擦，并

造成影响力为c 的冲突事件。

每年年末，警察局会将本年内监狱中的所有冲突事件按影响力从大到小排成一个列表，

然后上报到S 城Z 市长那里。公务繁忙的Z 市长只会去看列表中的第一个事件的影响力，

如果影响很坏，他就会考虑撤换警察局长。

在详细考察了N 名罪犯间的矛盾关系后，警察局长觉得压力巨大。他准备将罪犯们在

两座监狱内重新分配，以求产生的冲突事件影响力都较小，从而保住自己的乌纱帽。假设只

要处于同一监狱内的某两个罪犯间有仇恨，那么他们一定会在每年的某个时候发生摩擦。那

么，应如何分配罪犯，才能使Z 市长看到的那个冲突事件的影响力最小？这个最小值是少？

输入描述 Input Description

第一行为两个正整数N 和M，分别表示罪犯的数目以及存在仇恨的罪犯对数。

接下来的M 行每行为三个正整数aj，bj，cj，表示aj 号和bj 号罪犯之间存在仇恨，其怨气值为cj。数据保证，且每对罪犯组合只出现一次。

输出描述 Output Description

共1 行，为Z 市长看到的那个冲突事件的影响力。如果本年内监狱

中未发生任何冲突事件，请输出0。

样例输入 Sample Input

4 6

1 4 2534

2 3 3512

1 2 28351

1 3 6618

2 4 1805

3 4 12884

样例输出 Sample Output

3512

题解：将边从大到小排序，第一条左右两点在同一集合的即为答案

const
  maxn=150000;
var
  edge:array[0..maxn,1..3]of longint;
  fa,r,h:array[0..maxn]of longint;
  n,i,j,m:longint;
  ans:int64;

function find(x:longint):longint;
begin
  if fa[x]=x then exit(x);
  fa[x]:=find(fa[x]);
  find:=fa[x];
end;

procedure union(x,y:longint);
var
  u,v:longint;
begin
  u:=find(x);v:=find(y);
  if u<>v then
  begin
    if r[u]<=r[v] then
    begin
      fa[u]:=v;
      if r[u]=r[v] then inc(r[v]);
    end
    else fa[v]:=u;
  end;
end;

procedure qsort(l,r:longint);
var
  i,j,key:longint;
begin
  if l>r then exit;
  i:=l;j:=r;
  key:=edge[(l+r)shr 1,3];
  repeat
    while edge[i,3]<key do inc(i);
    while edge[j,3]>key do dec(j);
    if i<=j then
    begin
      edge[0]:=edge[i];edge[i]:=edge[j];edge[j]:=edge[0];
      inc(i);dec(j);
    end;
  until i>j;
  qsort(l,j);
  qsort(i,r);
end;

procedure init;
var
  i,j:longint;
begin
  readln(n,m);
  for i:=1 to n do
    fa[i]:=i;
  for i:=1 to m do
    readln(edge[i,1],edge[i,2],edge[i,3]);
end;

begin
  init;
  qsort(1,m);
  for i:=m downto 1 do
  begin
    if find(edge[i,1])=find(edge[i,2]) then
    begin
      writeln(edge[i,3]);
      halt;
    end;
    if h[edge[i,1]]=0 then h[edge[i,1]]:=edge[i,2] else union(h[edge[i,1]],edge[i,2]);
    if h[edge[i,2]]=0 then h[edge[i,2]]:=edge[i,1] else union(edge[i,1],h[edge[i,2]]);

  end;
  writeln(0);
end.