易语言Xml介绍，应用，举例

支持库：XML解析支持库

一

①首先使用

程序集_XML.导入 ()

命令导入XML文件

例子：

程序集_XML.导入 (取运行目录 () ＋ “\abc1.xml”)

②

输出调试文本 (程序集_XML.取根节点名文本 ())

//数据库

输出调试文本 (程序集_XML.取子节点个数 (“数据库/”, ))

//31

输出调试文本 (程序集_XML.取子节点个数 (“@1/”, ))

//31

输出调试文本 (程序集_XML.取属性值文本 (“数据库/第1条记录/”, “市”, ))

//鞍山

二

①

程序集_XML.创建 (“界面配置”)

程序集_XML.插入节点 (“界面配置/”, “尺寸”, “记录窗体大小属性”, )

程序集_XML.导出到文件 (取运行目录 () ＋ “\temp.xml”, , , )

②

程序集_XML.创建 (“界面配置”)
程序集_XML.插入节点 (“界面配置/”, “尺寸”, “记录窗体大小属性”, )
程序集_XML.插入属性 (“界面配置/尺寸”, “宽度”, 到文本 (_启动窗口.宽度))
程序集_XML.插入属性 (“界面配置/尺寸”, “高度”, 到文本 (_启动窗口.高度))
程序集_XML.插入属性 (“界面配置/尺寸”, “左边”, 到文本 (_启动窗口.左边))
程序集_XML.插入属性 (“界面配置/尺寸”, “顶边”, 到文本 (_启动窗口.顶边))
程序集_XML.导出到文件 (取运行目录 () ＋ “\temp.xml”, , , )

③区分

写配置项 (取运行目录 () ＋ “\temp.ini”, “尺寸”, “宽度”, 到文本 (_启动窗口.宽度))
写配置项 (取运行目录 () ＋ “\temp.ini”, “尺寸”, “高度”, 到文本 (_启动窗口.高度))
写配置项 (取运行目录 () ＋ “\temp.ini”, “尺寸”, “左边”, 到文本 (_启动窗口.左边))
写配置项 (取运行目录 () ＋ “\temp.ini”, “尺寸”, “顶边”, 到文本 (_启动窗口.顶边))

三、界面配置

四、界面配置+数据库

.版本 2
.支持库 EXMLParser
.支持库 iext
.支持库 HtmlView

.程序集 窗口程序集_启动窗口
.程序集变量 程序集_XML界面配置, XML树
.程序集变量 程序集_XML数据记录, XML树
.程序集变量 程序集_当前序号, 整数型

.子程序 __启动窗口_创建完毕

程序集_XML界面配置.导入 (取运行目录 () ＋ “\temp.xml”)
.判断开始 (文件是否存在 (取运行目录 () ＋ “\user.xml”) ＝ 假)
    程序集_XML数据记录.创建 (“用户信息”)
.默认
    程序集_XML数据记录.导入 (取运行目录 () ＋ “\user.xml”)
.判断结束
_按钮_刷新列表_被单击 ()
程序集_当前序号 ＝ 程序集_XML数据记录.取子节点个数 (“用户信息”, )
' 输出调试文本 (程序集_当前序号)
_启动窗口.宽度 ＝ 到数值 (程序集_XML界面配置.取属性值文本 (“界面配置/尺寸”, “宽度”, ))
_启动窗口.高度 ＝ 到数值 (程序集_XML界面配置.取属性值文本 (“界面配置/尺寸”, “高度”, ))
_启动窗口.左边 ＝ 到数值 (程序集_XML界面配置.取属性值文本 (“界面配置/尺寸”, “左边”, ))
_启动窗口.顶边 ＝ 到数值 (程序集_XML界面配置.取属性值文本 (“界面配置/尺寸”, “顶边”, ))

.子程序 __启动窗口_可否被关闭, 逻辑型

' 程序集_XML.导入 (取运行目录 () ＋ “\abc1.xml”)
' 输出调试文本 (程序集_XML.取根节点名文本 ())
' ' 程序集_XML.导入 ()
' 输出调试文本 (程序集_XML.取子节点个数 (“@1/”, ))
' 输出调试文本 (程序集_XML.取属性值文本 (“数据库/第1条记录/”, “市”, ))
程序集_XML界面配置.创建 (“界面配置”)
程序集_XML界面配置.插入节点 (“界面配置/”, “尺寸”, “记录窗体大小属性”, )
程序集_XML界面配置.插入属性 (“界面配置/尺寸”, “宽度”, 到文本 (_启动窗口.宽度))
程序集_XML界面配置.插入属性 (“界面配置/尺寸”, “高度”, 到文本 (_启动窗口.高度))
程序集_XML界面配置.插入属性 (“界面配置/尺寸”, “左边”, 到文本 (_启动窗口.左边))
程序集_XML界面配置.插入属性 (“界面配置/尺寸”, “顶边”, 到文本 (_启动窗口.顶边))
' 写配置项 (取运行目录 () ＋ “\temp.ini”, “尺寸”, “宽度”, 到文本 (_启动窗口.宽度))
' 写配置项 (取运行目录 () ＋ “\temp.ini”, “尺寸”, “高度”, 到文本 (_启动窗口.高度))
' 写配置项 (取运行目录 () ＋ “\temp.ini”, “尺寸”, “左边”, 到文本 (_启动窗口.左边))
' 写配置项 (取运行目录 () ＋ “\temp.ini”, “尺寸”, “顶边”, 到文本 (_启动窗口.顶边))
程序集_XML界面配置.导出到文件 (取运行目录 () ＋ “\temp.xml”, , , )

.子程序 _按钮_添加_被单击

程序集_XML数据记录.插入节点 (“用户信息”, “用户记录”, 编辑框_姓名.内容 ＋ “的信息”, )
程序集_当前序号 ＝ 程序集_当前序号 ＋ 1
程序集_XML数据记录.插入属性 (“用户信息/@” ＋ 到文本 (程序集_当前序号), “姓名”, 编辑框_姓名.内容)
程序集_XML数据记录.插入属性 (“用户信息/@” ＋ 到文本 (程序集_当前序号), “年龄”, 编辑框_年龄.内容)
程序集_XML数据记录.插入属性 (“用户信息/@” ＋ 到文本 (程序集_当前序号), “身高”, 编辑框_身高.内容)
程序集_XML数据记录.导出到文件 (取运行目录 () ＋ “\user.xml”, , , )
_按钮_刷新列表_被单击 ()

.子程序 _按钮_刷新列表_被单击
.局部变量 局部_字段数, 整数型
.局部变量 局部_计次, 整数型
.局部变量 局部_字段名, 文本型, , "0"
.局部变量 局部_位置, 整数型
.局部变量 局部_计次1, 整数型

超级列表框1.表项 ＝ {  }
超级列表框1.报表列 ＝ {  }
' 局部_字段数 ＝ 程序集_XML数据记录.取属性个数 (“用户信息/用户记录”, )
局部_字段名 ＝ 程序集_XML数据记录.取所有属性名 (“用户信息/用户记录”, )
.计次循环首 (取数组成员数 (局部_字段名), 局部_计次)
    超级列表框1.插入列 (, 局部_字段名 [局部_计次], 100, , , )
.计次循环尾 ()
.计次循环首 (程序集_XML数据记录.取子节点个数 (“用户信息”, ), 局部_计次)
    局部_位置 ＝ 超级列表框1.插入表项 (, , , , , )
    .计次循环首 (取数组成员数 (局部_字段名), 局部_计次1)
        超级列表框1.置标题 (局部_位置, 局部_计次1 － 1, 程序集_XML数据记录.取属性值文本 (“@1/@” ＋ 到文本 (局部_计次), 局部_字段名 [局部_计次1], ))
    .计次循环尾 ()
.计次循环尾 ()
超文本浏览框1.地址 ＝ 取运行目录 () ＋ “\user.xml”

.子程序 _按钮_修改_被单击

程序集_XML数据记录.修改属性值 (“用户信息/@” ＋ 到文本 (超级列表框1.现行选中项 ＋ 1), “姓名”, 编辑框_姓名.内容)
程序集_XML数据记录.修改属性值 (“用户信息/@” ＋ 到文本 (超级列表框1.现行选中项 ＋ 1), “年龄”, 编辑框_年龄.内容)
程序集_XML数据记录.修改属性值 (“用户信息/@” ＋ 到文本 (超级列表框1.现行选中项 ＋ 1), “身高”, 编辑框_身高.内容)
程序集_XML数据记录.导出到文件 (取运行目录 () ＋ “\user.xml”, , , )
_按钮_刷新列表_被单击 ()
信息框 (“修改成功！”, #信息图标, , )

.子程序 _超级列表框1_左键单击表项

编辑框_姓名.内容 ＝ 超级列表框1.取标题 (超级列表框1.现行选中项, 0)
编辑框_年龄.内容 ＝ 超级列表框1.取标题 (超级列表框1.现行选中项, 1)
编辑框_身高.内容 ＝ 超级列表框1.取标题 (超级列表框1.现行选中项, 2)

.子程序 _按钮_删除_被单击

程序集_XML数据记录.删除节点 (“用户信息/@” ＋ 到文本 (超级列表框1.现行选中项 ＋ 1))
程序集_XML数据记录.导出到文件 (取运行目录 () ＋ “\user.xml”, , , )
_按钮_刷新列表_被单击 ()