Windows7/10/11系统bat脚本安装打印机

不再苦恼整半天了还在点来点去为啥打印机还是脱机，快下班了突然有人找你装打印机想下班却只能加班当牛马！

ㅤㅤㅤㅤㅤㅤㅤㅤㅤㅤㅤㅤㅤㅤㅤㅤ
教你一秒安装打印机，下班找你也能轻松应对。

既这篇文章后又优化后的脚本“https://blog.youkuaiyun.com/lzh99rsq/article/details/143019443?spm=1001.2014.3001.5501”上一篇写的代码太长了，像shi山一样。自己都看不下去了，优化下
往下看
ㅤㅤㅤㅤㅤㅤ
直接上干货，末班照着搞就行

@echo off
echo "更改命令行窗口宽高"
MODE con: COLS=75 LINES=45
rem 自动提权以管理员方式运行
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' EQU '5' (
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
pushd "%CD%"
CD /D "%~dp0"

echo =------------欢迎使用XXXXXX打印机安装小工具------------=
echo          -------------------------------------
echo                当前时间：%DATE%
echo          -------------------------------------
color 0a

@echo off

setlocal enabledelayedexpansion

echo 检测同名打印机并删除

:: 定义打印机名称数组
set "打印机名[0]=HP ColorLaserJet MFP M178-M181 PCL-6 (V4)"
set "打印机名[1]=HP ColorLaserJet MFP M178-M181 PCL-6 (V4) (副本 1)"
set "打印机名[2]=HP ColorLaserJet MFP M178-M181 PCL-6 (V4) (副本 2)"
set "打印机名[3]=HP ColorLaserJet MFP M178-M181 PCL-6 (V4) (副本 3)"
set "打印机名[4]=HP ColorLaserJet MFP M178-M181 PCL-6 (V4) (副本 4)"
set "打印机名[5]=HP ColorLaserJet MFP M178-M181 PCL-6 (V4) (副本 5)"
set "打印机名[6]=XX打印机"
set "打印机名[7]=XX打印机 (副本 1)"
set "打印机名[8]=XX打印机 (副本 2)"
set "打印机名[9]=XX打印机 (副本 3)"
set "打印机名[10]=XX打印机 (副本 4)"
set "打印机名[11]=XX打印机 (副本 5)"
set "打印机名[12]=XX部打印机"
set "打印机名[13]=XX部打印机 (副本 1)"
set "打印机名[14]=XX部打印机 (副本 2)"
set "打印机名[15]=XX部打印机 (副本 3)"
set "打印机名[16]=XX部打印机 (副本 4)"
set "打印机名[17]=XX部打印机 (副本 5)"

:: 遍历数组并检查打印机
for /L %%i in (0,1,17) do (
    set "当前打印机名=!打印机名[%%i]!"
    wmic printer get Name /value | find /i "!当前打印机名!" >nul && (
        echo 正在删除打印机: !当前打印机名!
        rundll32 printui.dll,PrintUIEntry /n"!当前打印机名!" /dl
        echo !当前打印机名! 已删除
    ) || (
        echo !当前打印机名! 未找到
    )
)

echo "尝试创建打印机TCP/IP端口：xx.xx.xx.xx " 
cscript //nologo C:\Windows\System32\Printing_Admin_Scripts\zh-CN\prnport.vbs -a -r xx.xx.xx.xx -h xx.xx.xx.xx -o raw  

echo "停止打印服务"
net stop spooler 

echo "重新启动打印服务"
net start spooler

echo "安装打印机驱动---不自动共享此打印机"
rundll32 printui.dll,PrintUIEntry  /if /b "XX部打印机" /n "XX部打印机" /f "C:\科技部门打印机\HP ColorLaserJet MFP M178-M181\hppyaf2a4_x64.inf" /r "xx.xx.xx.xx" /m "HP ColorLaserJet MFP M178-M181 PCL-6 (V4)" /z  

echo "将打印机设置为默认打印机"
rundll32 printui.dll,PrintUIEntry /y /n "XX部打印机" 

echo =====================================================================
echo 恭喜，打印机安装完成！【举例（用不到删除即可）：如遇到问题请联系基础运维部相关IT老师解决】
echo =====================================================================

pause

以上是自动安装打印机的代码，如何找打印机驱动，请参照上次的文章“https://blog.youkuaiyun.com/lzh99rsq/article/details/143019443?spm=1001.2014.3001.5501”
新建好.bat文件后，把驱动和批处理放在一起就好了，运行安装的时候急的把文件夹放在C盘根目录。

C:\科技部门打印机\HP ColorLaserJet MFP M178-M181\hppyaf2a4_x64.inf

注：这个路径一定要和打印机驱动在一个目录下，不然会报错！！！