unity中shader的Cutout问题

最新推荐文章于 2024-12-25 21:51:22 发布

lynon

最新推荐文章于 2024-12-25 21:51:22 发布

阅读量8.6k

点赞数

CC 4.0 BY-SA版权

本文链接：https://blog.youkuaiyun.com/lynon/article/details/38759205

本文探讨了Unity中Shader的Cutout特性，通过分析内置的透明切割Shader源代码，展示了如何在不同的场景下使用Cutout效果。在尝试将此效果应用于Android平台时遇到了性能问题，通过对比和实验，找到了既能保持效果又能避免手机死机的解决方案，即使用'Transparent/Cutout/VertexLit' Shader。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

unity中自带的shader里有Cutout类型的shader，今天发现这种类型很诡异，先

贴几种自带的：

// Unlit alpha-cutout shader.
// - no lighting
// - no lightmap support
// - no per-material color

Shader "Unlit/Transparent Cutout" {
Properties {
   _MainTex ("Base (RGB) Trans (A)", 2D) = "white" {}
   _Cutoff ("Alpha cutoff", Range(0,1)) = 0.5
}
SubShader {
   Tags {"Queue"="AlphaTest" "IgnoreProjector"="True" "RenderType"="TransparentCutout"}
   LOD 100

   Lighting Off

   Pass {
       CGPROGRAM
           #pragma vertex vert
           #pragma fragment frag

           #include "UnityCG.cginc"

           struct appdata_t {
               float4 vertex : POSITION;
               float2 texcoord : TEXCOORD0;
           };

           struct v2f {
               float4 vertex : SV_POSITION;
               half2 texcoord : TEXCOORD0;
           };

           sampler2D _MainTex;
           float4 _MainTex_ST;
           fixed _Cutoff;

           v2f vert (appdata_t v)
           {
               v2f o;
               o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
               o.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);
               return o;
           }

           fixed4 frag (v2f i) : COLOR
           {
               fixed4 col = tex2D(_MainTex, i.texcoord);
               clip(col.a - _Cutoff);
               return col;
           }
       ENDCG
   }
}

}

Shader "Transparent/Cutout/Diffuse" {
Properties {
   _Color ("Main Color", Color) = (1,1,1,1)
   _MainTex ("Base (RGB) Trans (A)", 2D) = "white" {}
   _Cutoff ("Alpha cutoff", Range(0,1)) = 0.5
}

SubShader {
   Tags {"Queue"="AlphaTest" "IgnoreProjector"="True" "RenderType"="TransparentCutout"}
   LOD 200

CGPROGRAM
#pragma surface surf Lambert alphatest:_Cutoff

sampler2D _MainTex;
fixed4 _Color;

struct Input {
   float2 uv_MainTex;
};

void surf (Input IN, inout SurfaceOutput o) {
   fixed4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;
   o.Albedo = c.rgb;
   o.Alpha = c.a;
}
ENDCG
}

Fallback "Transparent/Cutout/VertexLit"
}

Shader "Transparent/Diffuse" {
Properties {
   _Color ("Main Color", Color) = (1,1,1,1)
   _MainTex ("Base (RGB) Trans (A)", 2D) = "white" {}
}

SubShader {
   Tags {"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
   LOD 200

CGPROGRAM
#pragma surface surf Lambert alpha

sampler2D _MainTex;
fixed4 _Color;

struct Input {
   float2 uv_MainTex;
};

void surf (Input IN, inout SurfaceOutput o) {
   fixed4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;
   o.Albedo = c.rgb;
   o.Alpha = c.a;
}
ENDCG
}

Fallback "Transparent/VertexLit"
}

我现在做的某个项目，模型需要用transparent/diffuse的效果，但是有的建筑窗户是贴图，贴图中的边缘导入时alpha是0，

我综合上述代码写了个shader，能再电脑上的unity的Android平台上运行，但是在手机上会死机。。Android手机只能同时支持

lightmap，Alphatest，ZTest 中的两种。

Shader "Custom/TranDifExt" {
   Properties {
   _Color ("Main Color", Color) = (1,1,1,1)
   _MainTex ("Base (RGB) Trans (A)", 2D) = "white" {}
   _Cutoff ("Alpha cutoff", Range(0,1)) = 0.5
}

SubShader {
   Tags {"Queue"="AlphaTest" "IgnoreProjector"="True" "RenderType"="TransparentCutout"}
   LOD 200

CGPROGRAM
//#pragma surface surf Lambert alpha
#pragma surface surf Lambert
#include "UnityCG.cginc"
sampler2D _MainTex;
fixed4 _Color;
fixed _Cutoff;

struct Input {
   float2 uv_MainTex;
};

void surf (Input IN, inout SurfaceOutput o) {
   fixed4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;
   o.Albedo = c.rgb;
   o.Alpha = c.a;
   clip(o.Alpha-_Cutoff);
}
ENDCG
}

Fallback "VertexLit"
}

然后又被同伙找了个shader："Transparent/Cutout/VertexLit"，可以在手机Android上执行，同时有lightmap，Alphatest，ZTest 三种（不死机）

Shader "Transparent/Cutout/VertexLit" {
Properties {
   _Color ("Main Color", Color) = (1,1,1,1)
   _SpecColor ("Spec Color", Color) = (1,1,1,0)
   _Emission ("Emissive Color", Color) = (0,0,0,0)
   _Shininess ("Shininess", Range (0.1, 1)) = 0.7
   _MainTex ("Base (RGB) Trans (A)", 2D) = "white" {}
   _Cutoff ("Alpha cutoff", Range(0,1)) = 0.5
}

SubShader {
   Tags {"Queue"="AlphaTest" "IgnoreProjector"="True" "RenderType"="TransparentCutout"}
   LOD 100

   // Non-lightmapped
   Pass {
       Tags { "LightMode" = "Vertex" }
       Alphatest Greater [_Cutoff]
       AlphaToMask True
       ColorMask RGB
       Material {
           Diffuse [_Color]
           Ambient [_Color]
           Shininess [_Shininess]
           Specular [_SpecColor]
           Emission [_Emission]
       }
       Lighting On
       SeparateSpecular On
       SetTexture [_MainTex] {
           Combine texture * primary DOUBLE, texture * primary
       }
   }

   // Lightmapped, encoded as dLDR
   Pass {
       Tags { "LightMode" = "VertexLM" }
       Alphatest Greater [_Cutoff]
       AlphaToMask True
       ColorMask RGB

       BindChannels {
           Bind "Vertex", vertex
           Bind "normal", normal
           Bind "texcoord1", texcoord0 // lightmap uses 2nd uv
           Bind "texcoord", texcoord1 // main uses 1st uv
       }
       SetTexture [unity_Lightmap] {
           matrix [unity_LightmapMatrix]
           constantColor [_Color]
           combine texture * constant
       }
       SetTexture [_MainTex] {
           combine texture * previous DOUBLE, texture * primary
       }
   }

   // Lightmapped, encoded as RGBM
   Pass {
       Tags { "LightMode" = "VertexLMRGBM" }
       Alphatest Greater [_Cutoff]
       AlphaToMask True
       ColorMask RGB

       BindChannels {
           Bind "Vertex", vertex
           Bind "normal", normal
           Bind "texcoord1", texcoord0 // lightmap uses 2nd uv
           Bind "texcoord1", texcoord1 // unused
           Bind "texcoord", texcoord2 // main uses 1st uv
       }

       SetTexture [unity_Lightmap] {
           matrix [unity_LightmapMatrix]
           combine texture * texture alpha DOUBLE
       }
       SetTexture [unity_Lightmap] {
           constantColor [_Color]
           combine previous * constant
       }
       SetTexture [_MainTex] {
           combine texture * previous QUAD, texture * primary
       }
   }

   // Pass to render object as a shadow caster
   Pass {
       Name "Caster"
       Tags { "LightMode" = "ShadowCaster" }
       Offset 1, 1

       Fog {Mode Off}
       ZWrite On ZTest LEqual Cull Off

CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#pragma multi_compile_shadowcaster
#include "UnityCG.cginc"

struct v2f {
   V2F_SHADOW_CASTER;
   float2 uv : TEXCOORD1;
};

uniform float4 _MainTex_ST;

v2f vert( appdata_base v )
{
   v2f o;
   TRANSFER_SHADOW_CASTER(o)
   o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
   return o;
}

uniform sampler2D _MainTex;
uniform fixed _Cutoff;
uniform fixed4 _Color;

float4 frag( v2f i ) : COLOR
{
   fixed4 texcol = tex2D( _MainTex, i.uv );
   clip( texcol.a*_Color.a - _Cutoff );

   SHADOW_CASTER_FRAGMENT(i)
}
ENDCG

   }

   // Pass to render object as a shadow collector
   Pass {
       Name "ShadowCollector"
       Tags { "LightMode" = "ShadowCollector" }

       Fog {Mode Off}
       ZWrite On ZTest LEqual

CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#pragma multi_compile_shadowcollector

#define SHADOW_COLLECTOR_PASS
#include "UnityCG.cginc"

struct v2f {
   V2F_SHADOW_COLLECTOR;
   float2 uv : TEXCOORD5;
};

uniform float4 _MainTex_ST;

v2f vert (appdata_base v)
{
   v2f o;
   TRANSFER_SHADOW_COLLECTOR(o)
   o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
   return o;
}

uniform sampler2D _MainTex;
uniform fixed _Cutoff;
uniform fixed4 _Color;

fixed4 frag (v2f i) : COLOR
{
   fixed4 texcol = tex2D( _MainTex, i.uv );
   clip( texcol.a*_Color.a - _Cutoff );

   SHADOW_COLLECTOR_FRAGMENT(i)
}
ENDCG

   }
}

}