为Group添加网格线, 控制隐藏与显示

最新推荐文章于 2024-05-14 15:57:15 发布

-氺_涙-

最新推荐文章于 2024-05-14 15:57:15 发布

阅读量912

点赞数

CC 4.0 BY-SA版权

分类专栏： Flex

本文链接：https://blog.youkuaiyun.com/luohuayuan69/article/details/8894141

Flex 专栏收录该内容

33 篇文章

订阅专栏

这篇博客展示了如何在Flex应用中创建一个BorderContainer，其中包含一个Group，并为Group添加了可控制显示和隐藏的网格线。通过监听ToggleButton的点击事件，实现网格线的显示和隐藏功能。网格线的间距、横线和竖线的绘制都进行了详细说明。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

<?xml version="1.0" encoding="utf-8"?>
<s:BorderContainer xmlns:fx="http://ns.adobe.com/mxml/2009" 
		 xmlns:s="library://ns.adobe.com/flex/spark" 
		 xmlns:mx="library://ns.adobe.com/flex/mx"
		 width="100%" height="100%"
		 creationComplete="init(event)">
	<s:layout>
		<s:VerticalLayout/>
	</s:layout>
	<fx:Declarations>
		<!-- 将非可视元素（例如服务、值对象）放在此处 -->
	</fx:Declarations>
	<fx:Script>
		<![CDATA[
			import mx.events.FlexEvent;
			
			import spark.core.SpriteVisualElement;
			
			//网格间距
			private var spaceNumber:int = 50;
			//网格画布
			public var sprite:SpriteVisualElement = new SpriteVisualElement();
			
			protected function init(event:FlexEvent):void
			{
				editorGroup.graphics.clear();
				
				//填充背景色
				editorGroup.graphics.beginFill(0xFFFFFF);
				editorGroup.graphics.drawRect(1, 1, editorGroup.width - 1, editorGroup.height - 1);
				editorGroup.graphics.endFill();
				
				//画网格
				sprite.width = editorGroup.width;
				sprite.height = editorGroup.height;
				
				editorGroup.addElement(sprite);
				sprite.visible = false;
				
				sprite.graphics.lineStyle(1, 0xEEEEEE);
				//横线
				var rowNumber:int = Math.round(sprite.height / spaceNumber);
				if((sprite.height / spaceNumber) is int)
				{
					rowNumber--;
				}
				for(var i:int=0; i<rowNumber; i++)
				{
					sprite.graphics.moveTo(0, spaceNumber * (i + 1));
					sprite.graphics.lineTo(sprite.width, spaceNumber * (i + 1));
				}
				//竖线
				var columnNumber:int = Math.round(sprite.width / spaceNumber);
				if((sprite.width / spaceNumber) is int)
				{
					columnNumber--;
				}
				for(var j:int=0; j<columnNumber; j++)
				{
					sprite.graphics.moveTo(spaceNumber * (j + 1), 0);
					sprite.graphics.lineTo(spaceNumber * (j + 1), sprite.height);
				}
			}

			protected function grid_clickHandler(event:MouseEvent):void
			{
				sprite.visible = grid.selected;
			}
		]]>
	</fx:Script>
	<s:ToggleButton id="grid" label="网格" click="grid_clickHandler(event)"/>
	<s:Group id="editorGroup" width="100%" height="100%"/>
</s:BorderContainer>