还是直接贴加注释的代码吧,真方面 哈哈....发现最近快工作了,人是越来越懒了...唉`~~~~
!
! setup.s (C) 1991 Linus Torvalds
!
! setup.s is responsible for getting the system data from the BIOS,
! and putting them into the appropriate places in system memory.
! both setup.s and system has been loaded by the bootblock.
!
! This code asks the bios for memory/disk/other parameters, and
! puts them in a "safe" place: 0x90000-0x901FF, ie where the
! boot-block used to be. It is then up to the protected mode
! system to read them from there before the area is overwritten
! for buffer-blocks.
!
! NOTE! These had better be the same as in bootsect.s!
INITSEG = 0x9000 ! we move boot here - out of the way
SYSSEG = 0x1000 ! system loaded at 0x10000 (65536).
SETUPSEG = 0x9020 ! this is the current segment
.globl begtext, begdata, begbss, endtext, enddata, endbss
.text
begtext:
.data
begdata:
.bss
begbss:
.text
entry start
start:
! ok, the read went well so we get current cursor position and save it for
! posterity.
mov ax,#INITSEG ! this is done in bootsect already, but...
mov ds,ax
mov ah,#0x03 ! read cursor pos
xor bh,bh
int 0x10 ! save it in known place, con_init fetches
mov [0],dx ! it from 0x90000.
!将当前光标位置存放在90000H字单元里.高字节是行,低字节是列
! Get memory size (extended mem, kB)
!int 15h 88h号中断 INT 15 - EXTENDED MEMORY - GET MEMORY SIZE (AT,XT286,PS)
! AH = 88h
! Return: AX = memory size
mov ah,#0x88
int 0x15
mov [2],ax !90002h处的字单元里存放扩展内存大小(KB)
! Get video-card data:
! INT 10 - VIDEO - GET CURRENT VIDEO MODE
! AH = 0Fh
! Return: AH = number of columns on screen
! AL = current video mode (see INT 10h/AH=00h)
! BH = current active display page
mov ah,#0x0f
int 0x10
mov [4],bx ! bh = display page
mov [6],ax ! al = video mode, ah = window width
! check for EGA/VGA and some config parameters
! int 10 - VIDEO - ALTERNATE FUNCTION SELECT (PS, EGA, VGA, MCGA)
! AH = 12h
! BL = 10h: return EGA information
! Returns:
! BH = 0: color mode in effect (3Dx)
! 1: mono mode in effect (3Bx)
! BL = 0: 64k bytes memory installed
! 1: 128k bytes memory installed
! 2: 192k bytes memory installed
! 3: 256k bytes memory installed
! CH = feature bits
! CL = switch settings
! BL = 20h: select alternate print screen routine
! BL = 30h: select vertical resolution for alphanumeric modes (VGA only)
! AL = 00h 200 scan lines
! 01h 350 scan lines
! 02h 400 scan lines
! Return: AL = 12h if function supported
! BL = 31h: enable/disable default palette loading (VGA/MCGA)
! AL = 00h enable default palette loading
! 01h disable default palette loading
! Return: AL = 12h if function was supported
! BL = 32h: enable/disable video addressing (VGA/MCGA)
! AL = 00h enable video
! 01h disable video
! Return: AL = 12h if function was supported
! BL = 33h: enable/disable default gray-scale summing (VGA/MCGA)
! AL = 00h enable gray scale summing
! 01h disable gray scale summing
! Return: AL = 12h if function was supported
! BL = 34h: enable/disable alphanumeric cursor emulation (VGA only)
! AL = 00h enable cursor emulation
! 01h disable cursor emulation
! Return: AL = 12h if function was supported
! BL = 35h: PS/2 display-switch interface
! AL = 00h initial adapter video off
! 01h initial planar video on
! 02h switch active video off
! 03h switch inactive video on
! 80h *UNDOCUMENTED* set system board video active flag
! ES:DX = buffer (128 byte save area if AL = 0, 2 or 3)
! BL = 36h: video refresh control (VGA/PS)
! AL = 0 enable refresh
! 1 disable refresh
! Return: AL = 12h if function supported
mov ah,#0x12
mov bl,#0x10
int 0x10
mov [8],ax
mov [10],bx
mov [12],cx
! Get hd0 data
! 在中断向量0x41处起的16个字节存放第一个硬盘参数表
! 在中断向量0x46处起的16个字节存放第二个硬盘参数表
mov ax,#0x0000
mov ds,ax
lds si,[4*0x41] !把0x41*4 处所指的地址存入SI
mov ax,#INITSEG
mov es,ax
mov di,#0x0080
mov cx,#0x10
rep
movsb
!第一个硬盘参数表复制到0x90080
! Get hd1 data
mov ax,#0x0000
mov ds,ax
lds si,[4*0x46]
mov ax,#INITSEG
mov es,ax
mov di,#0x0090
mov cx,#0x10
rep
movsb
!第二个硬盘参数表复制到0x90090
! Check that there IS a hd1 :-)
! INT 13 - DISK - GET TYPE (AT,XT2,XT286,CONV,PS)
! AH = 15h
! DL = drive ID
! Return: AH = disk type
! 0 = disk not there
! 1 = floppy, no change detection present
! 2 = floppy with change detection
! 3 = fixed disk
! CX:DX = number of 512-byte sectors
! 中断int0x13，取盘类型功能。功能号ah＝0x15
! 输入：dl＝驱动器号（0x8x是硬盘，0x80是第一个硬盘，0x81是第2个硬盘
! 输出：ah＝类型码：00－没有这个盘，CF置位；01－软驱，没有change-line支持；
! 02－是软驱或者其他可移动设备，03－是硬盘。
mov ax,#0x01500
mov dl,#0x81 !上网一查,原来0x81是指第二块硬盘ID
int 0x13
jc no_disk1
cmp ah,#3
je is_disk1
no_disk1:
mov ax,#INITSEG
mov es,ax
mov di,#0x0090
mov cx,#0x10
mov ax,#0x00
rep
stosb !没有第二个盘则参数表清零
is_disk1:
! now we want to move to protected mode ...
!准备进入保护模式-__- 关中断先~
cli ! no interrupts allowed !
! first we move the system to it's rightful place
mov ax,#0x0000
cld ! 'direction'=0, movs moves forward
do_move:
mov es,ax ! destination segment
add ax,#0x1000
cmp ax,#0x9000
jz end_move
mov ds,ax ! source segment
sub di,di
sub si,si
mov cx,#0x8000
rep
movsw
jmp do_move
!上段代码将SYSTEM模块从0x10000移动到0处,将中断向量覆盖掉了
! then we load the segment descriptors
end_move:
mov ax,#SETUPSEG ! right, forgot this at first. didn't work :-)
mov ds,ax
lidt idt_48 ! load idt with 0,0 !加载IDTR,在下面定义
lgdt gdt_48 ! load gdt with whatever appropriate !加载GDTR,在下面定义
! that was painless, now we enable A20
!开A20,共三种方法,这是其中一种
call empty_8042
mov al,#0xD1 ! command write
out #0x64,al
call empty_8042
mov al,#0xDF ! A20 on
out #0x60,al
call empty_8042
! well, that went ok, I hope. Now we have to reprogram the interrupts :-(
! we put them right after the intel-reserved hardware interrupts, at
! int 0x20-0x2F. There they won't mess up anything. Sadly IBM really
! messed this up with the original PC, and they haven't been able to
! rectify it afterwards. Thus the bios puts interrupts at 0x08-0x0f,
! which is used for the internal hardware interrupts as well. We just
! have to reprogram the 8259's, and it isn't fun.
! 重新设置硬件中断地址...详细编程需查看一下微机原理与接口上的8259编程,书收柜子里了,没翻,不找了..-_-
mov al,#0x11 ! initialization sequence
out #0x20,al ! send it to 8259A-1
.word 0x00eb,0x00eb ! jmp $+2, jmp $+2
out #0xA0,al ! and to 8259A-2
.word 0x00eb,0x00eb
mov al,#0x20 ! start of hardware int's (0x20)
out #0x21,al
.word 0x00eb,0x00eb
mov al,#0x28 ! start of hardware int's 2 (0x28)
out #0xA1,al
.word 0x00eb,0x00eb
mov al,#0x04 ! 8259-1 is master
out #0x21,al
.word 0x00eb,0x00eb
mov al,#0x02 ! 8259-2 is slave
out #0xA1,al
.word 0x00eb,0x00eb
mov al,#0x01 ! 8086 mode for both
out #0x21,al
.word 0x00eb,0x00eb
out #0xA1,al
.word 0x00eb,0x00eb
mov al,#0xFF ! mask off all interrupts for now
out #0x21,al
.word 0x00eb,0x00eb
out #0xA1,al
! well, that certainly wasn't fun :-(. Hopefully it works, and we don't
! need no steenking BIOS anyway (except for the initial loading :-).
! The BIOS-routine wants lots of unnecessary data, and it's less
! "interesting" anyway. This is how REAL programmers do it.
!
! Well, now's the time to actually move into protected mode. To make
! things as simple as possible, we do no register set-up or anything,
! we let the gnu-compiled 32-bit programs do that. We just jump to
! absolute address 0x00000, in 32-bit protected mode.
mov ax,#0x0001 ! protected mode (PE) bit
lmsw ax ! This is it! !进入保护模式,即PE置位
jmpi 0,8 ! jmp offset 0 of segment 8 (cs) !8 已是选择子了,即GDT中的第三个表项
! This routine checks that the keyboard command queue is empty
! No timeout is used - if this hangs there is something wrong with
! the machine, and we probably couldn't proceed anyway.
empty_8042:
.word 0x00eb,0x00eb
in al,#0x64 ! 8042 status port
test al,#2 ! is input buffer full?
jnz empty_8042 ! yes - loop
ret
gdt:
.word 0,0,0,0 ! dummy !空表项
.word 0x07FF ! 8Mb - limit=2047 (2048*4096=8Mb)
.word 0x0000 ! base address=0
.word 0x9A00 ! code read/exec
.word 0x00C0 ! granularity=4096, 386
! 8Mb大小的可读可运行代码段
.word 0x07FF ! 8Mb - limit=2047 (2048*4096=8Mb)
.word 0x0000 ! base address=0
.word 0x9200 ! data read/write
.word 0x00C0 ! granularity=4096, 386
! 8Mb大小的可读写的数据段
idt_48:
.word 0 ! idt limit=0
.word 0,0 ! idt base=0L
! 定义为0:0处
gdt_48:
.word 0x800 ! gdt limit=2048, 256 GDT entries
.word 512+gdt,0x9 ! gdt base = 0X9xxxx
! 表在上面gdt处定义了,共三项
.text
endtext:
.data
enddata:
.bss
endbss:
扫一扫
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
