Hive-DML数据操作

数据导入

向表中装载数据（Load）

1．语法

load data [local] inpath '/opt/module/datas/student.txt' [overwrite] into table student [partition (partcol1=val1,…)];

（1）load data:表示加载数据

（2）local:表示从本地加载数据到hive表；否则从HDFS加载数据到hive表

（3）inpath:表示加载数据的路径

（4）overwrite:表示覆盖表中已有数据，否则表示追加

（5）into table:表示加载到哪张表

（6）student:表示具体的表

（7）partition:表示上传到指定分区

2．案例

加载本地文件到hive中

创建一张表

create table student(
id string, name string
)
row format delimited fields terminated by '\t';

加载本地文件到hive

load data local inpath '/opt/module/datas/student.txt' into table default.student;

加载HDFS文件到hive中

上传文件到HDFS

dfs -put /opt/module/datas/student.txt /user/liun/hive;

加载HDFS上数据

load data inpath '/user/liun/hive/student.txt' into table default.student;

加载数据覆盖表中已有的数据，overwrite

load data inpath '/user/liun/hive/student.txt' overwrite into table default.student;

通过查询语句向表中插入数据（Insert）

1．创建一张分区表

create table student(
id int, name string
) partitioned by (month string) row format delimited fields terminated by '\t';

2．基本插入数据

insert into table  student partition(month='201909') values(1,'liu');

3．基本模式插入（根据单张表查询结果）

insert overwrite table student partition(month='201908')
select id, name from student where month='201909';

4．多插入模式（根据多张表查询结果）

from student
              insert overwrite table student partition(month='201907')
              select id, name where month='201909'
              insert overwrite table student partition(month='201906')
              select id, name where month='201909';

注：insert into追加，insert overwrite覆盖

查询语句中创建表并加载数据（As Select）

create table if not exists student2 as select id, name from student;

注意创建表后面不能指定列字段名

创建表时通过Location指定加载数据路径

1．创建表，并指定在hdfs上的位置

create table if not exists student5(
              id int, name string
              )
              row format delimited fields terminated by '\t'
              location '/user/hive/warehouse/student4';

2．上传数据到hdfs上

dfs -put /opt/module/datas/student.txt /user/hive/warehouse/student4;

3．查询数据

select * from student4;

Import数据到指定Hive表中

注意：先用export导出后，再将数据导入。因为export导出数据带有元数据信息。表中不能有数据。

import table student2 partition(month='201909') from '/user/hive/warehouse/export/student';

数据导出

 Insert导出

1．将查询的结果导出到本地

insert overwrite local directory '/opt/module/datas/export/student'
select * from student;

2．将查询的结果格式化导出到本地

insert overwrite local directory '/opt/module/datas/export/student1'
ROW FORMAT DELIMITED FIELDS TERMINATED BY '\t'
select * from student;

3．将查询的结果导出到HDFS上(没有local)

insert overwrite directory '/user/liun/student2'
ROW FORMAT DELIMITED FIELDS TERMINATED BY '\t' 
select * from student;

Hadoop命令导出到本地

dfs -get /user/hive/warehouse/student/ /opt/module/datas/export/student.txt;

Hive Shell 命令导出

基本语法：（hive -f/-e 执行语句或者脚本 > file）

bin/hive -e 'select * from default.student;' > /opt/module/datas/export/student2.txt;

 Export导出到HDFS上

export table default.student to '/user/hive/warehouse/export/student';

清除表中数据（Truncate）

注意：Truncate只能删除管理表，不能删除外部表中数据

truncate table student;