AS3 控制按钮的缓动缩放

最新推荐文章于 2013-11-08 17:15:04 发布

Jave.Lin

最新推荐文章于 2013-11-08 17:15:04 发布

阅读量2.3k

点赞数

CC 4.0 BY-SA版权

分类专栏： AS3 文章标签： function import class null

本文链接：https://blog.youkuaiyun.com/linjf520/article/details/7286145

AS3 专栏收录该内容

85 篇文章

订阅专栏

本文介绍了一个使用Adobe Flash CS4及ActionScript 3.0实现缓动动画效果的例子。通过四个矩形在鼠标悬停时放大缩小的动画演示了缓动效果，并详细展示了如何在Flash中创建此类动画。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

以下类,可以直接设置为启动类,运行看到效果:

package
{
	import flash.display.Graphics;
	import flash.display.MovieClip;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;

	public class TestEasing extends Sprite
	{
		private var _easing:Number=0.3;
		private var _bigScaleX:Number=4;
		private var _bigScaleY:Number=4;
		
		public function TestEasing()
		{
			if(stage)
			{
				addToStage();
			}
			else this.addEventListener(Event.ADDED_TO_STAGE,addToStage);
		}
		
		private function addToStage(e:Event = null):void
		{
			var mc:MovieClip;
			var graphics:Graphics;
			var size:Number=50;
			for(var i:int = 0; i < 4; i++)
			{
				mc = new MovieClip();
				graphics = mc.graphics;
				graphics.beginFill(0xFF0000);
				graphics.drawRect(-size/2,-size/2,size,size);
				graphics.endFill();
				mc.x = int(i%30) * (mc.width + 50)+100;
				mc.y = 100;
				mc.isOver = false;
				mc.buttonMode = true;
				this.addChild(mc);
				mc.addEventListener(MouseEvent.MOUSE_OVER,mouseOver);
				mc.addEventListener(MouseEvent.MOUSE_OUT,mouseOut);
			}
		}
		
		private function onEnterFrameHandler(e:Event):void
		{
			var tMc:MovieClip=e.target as MovieClip;
			if(!tMc)return;
			var tx:Number;
			var targetScale:Number;
			
			if(tMc.isOver)
			{
				targetScale=_bigScaleX;
			}else
			{
				targetScale=1;
			}
			tx=targetScale-tMc.scaleX;
			
			tMc.scaleX+=tx*_easing;
			tMc.scaleY+=tx*_easing;
			if(Math.abs(tx)<0.01)
			{
				tMc.scaleX=targetScale;
				tMc.scaleY=targetScale;
				tMc.removeEventListener(Event.ENTER_FRAME,onEnterFrameHandler);
			}
		}
		
		private function mouseOver(e:MouseEvent):void
		{
			var tMc:MovieClip=e.target as MovieClip;
			if(!tMc)return;
			tMc.isOver=true;
			if(!tMc.hasEventListener(Event.ENTER_FRAME))
			{
				tMc.addEventListener(Event.ENTER_FRAME,onEnterFrameHandler);
			}
		}
		
		private function mouseOut(e:MouseEvent):void
		{
			var tMc:MovieClip=e.target as MovieClip;
			if(!tMc)return;
			tMc.isOver=false;
			if(!tMc.hasEventListener(Event.ENTER_FRAME))
			{
				tMc.addEventListener(Event.ENTER_FRAME,onEnterFrameHandler);
			}
		}
	}
}