洛谷 P1162 填涂颜色

题目描述

由数字0 组成的方阵中，有一任意形状闭合圈，闭合圈由数字1构成，围圈时只走上下左右4个方向。现要求把闭合圈内的所有空间都填写成2.例如：6X6的方阵（n=6），涂色前和涂色后的方阵如下：

0 0 0 0 0 0 0 0 0 0 0 0

0 0 1 1 1 1 0 0 1 1 1 1

0 1 1 0 0 1 0 1 1 2 2 1

1 1 0 0 0 1 1 1 2 2 2 1

1 0 0 0 0 1 1 2 2 2 2 1

1 1 1 1 1 1 1 1 1 1 1 1

输入输出格式

输入格式：
每组测试数据第一行一个整数：n。其中n(1<=n<=30)

接下来n行，由0和1组成的nXn的方阵。

方阵内只有一个闭合圈，圈内至少有一个0。

//感谢黄小U饮品指出本题数据和数据格式不一样. 已修改(输入格式)

输出格式：
已经填好数字2的完整方阵。

输入输出样例

输入样例#1：
6
0 0 0 0 0 0
0 0 1 1 1 1
0 1 1 0 0 1
1 1 0 0 0 1
1 0 0 0 0 1
1 1 1 1 1 1
输出样例#1：
0 0 0 0 0 0
0 0 1 1 1 1
0 1 1 2 2 1
1 1 2 2 2 1
1 2 2 2 2 1
1 1 1 1 1 1
说明

1<=n<=30

分析：
就是一个广搜的模版题。这种题的时间很玄学（一开始还TLE了一个点）。

代码：

type
  node=record
    x,y:longint;
  end;
const
  dir:array[1..4,1..2] of longint=((0,1),(0,-1),(1,0),(-1,0));
var
  n,i,j,h,t,x,y,newx,newy:longint;
  map:array[1..35,1..35] of longint;
  q:array[1..2000] of node;
procedure find(x,y:longint);
begin
  if map[x,y]=2 then
    begin
      map[x,y]:=0;
      inc(t);
      q[t].x:=x; q[t].y:=y;
    end;
end;
begin
  readln(n);
  for i:=1 to n do
    begin
      for j:=1 to n do
        begin
          read(map[i,j]);
          if map[i,j]=0 then
            map[i,j]:=2;
        end;
      readln;
    end;
  h:=0; t:=0;
  for i:=1 to n-1 do
    begin
      find(i,1);
      find(i+1,n);
      find(1,i+1);
      find(n,i);
    end;
  while h<t do
    begin
      inc(h);
      x:=q[h].x; y:=q[h].y;
      for i:=1 to 4 do
        begin
          newx:=x+dir[i,1];
          newy:=y+dir[i,2];
          if (newx>=1) and (newx<=n) and
            (newy>=1) and (newy<=n) and (map[newx,newy]=2) then
              begin
                map[newx,newy]:=0;
                inc(t);
                q[t].x:=newx; q[t].y:=newy;
              end;
        end;
    end;
  for i:=1 to n do
    begin
      for j:=1 to n do
        write(map[i,j],' ');
      writeln;
    end;
end.