Stored-Carry 加法器

Stored-Carry 加法器

Stored-Carry 是一种冗余数制系统，可以用于实现 Carry-Save 加法器。

Stored-Carry 使用 2 作为进制基底，使用 [0,2] 作为数字，与传统二进制数制相比，多用了一个数字 2。

通过 2-bit 编码获得三种数字的表示：

• 0: (0,0)
• 1: (1,0) 或 (0,1)
• 2: (1,1)

当 Stored-Carry 数与普通二进制数相加时，即 Stored-Carry 加法器。

在加法过程中，总是将每一位的加法计算为 中间和 与 传递位 ，中间和再与传递位相加得到本位和。

例如下图：

一个位的最大结果为 3，可以将 3 拆成 1 传递位， 1 中间位，这样传递位最大为 1，中间位最大为 1，本位和最大为 2，这样的结果依然是 Stored-Carry 数，而且将进位限制在了 1 位以内。

每计算一位需要一个全加器：

这样计算一次 Stored-Carry 加法的时间仅为一个全加器的延迟，与数据长度无关，是常数时间加法 $O(1)$ ，空间上需要 $O(n)$ 个全加器加法器。

// 单个比特位加法单元
module CarrySaveAdder (
    input [1:0] A,
    input B,
    input T,
    output [1:0] S,
    output Q
);
wire fullAdderS, fullAdderQ;

// FullAdder 是一个全加器单元
FullAdder fullAdder(
    .A(A[0]),
    .B(A[1]),
    .C(B),
    .S(fullAdderS),
    .Q(fullAdderQ)
);

assign S = {fullAdderS, T};
assign Q = fullAdderQ;
endmodule

// Stored-Carry 加法器链
// A 输入的 Stored-Carry 数
// B 输入的一般二进制数
// C 结果 Stored-Carry 数
module CarrySaveAdderChain #(
    parameter LEN = 8
) (
    input [1:0] A [LEN - 1:0],
    input [LEN - 1:0] B,
    output [1:0] S [LEN - 1:0]
);

wire [LEN:0] T;
assign T[0] = 0;

genvar i;
generate
    for(i = 0;i < LEN; i++) begin
        CarrySaveAdder carrySaveAdder(
            .A(A[i]),
            .B(B[i]),
            .T(T[i]),
            .S(S[i]),
            .Q(T[i+1])
        );
    end
endgenerate
endmodule

// 将 Stored-Carry 数转换为普通二进制数
module CarrySaveToBin #(
    parameter LEN = 8
) (
    input [1:0] A [LEN - 1:0],
    output [LEN - 1:0] S
);

wire [LEN:0] T;
assign T[0] = 0;

genvar i;
generate
    for(i = 0;i < LEN; i++) begin
        FullAdder fullAdder(
            .A(A[i][0]),
            .B(A[i][1]),
            .C(T[i]),
            .S(S[i]),
            .Q(T[i+1])
        );
    end
endgenerate
endmodule

该结构可用于多次累加算数的情况，当串行累加 $k$ 次，仅需要 $O(k)$ 的时间，最后只需要一次进位链计算将 Stored-Carry 转为普通二进制数。