VS2003折叠代码的Micro

最新推荐文章于 2025-11-22 20:06:34 发布

原创最新推荐文章于 2025-11-22 20:06:34 发布 · 2.9k 阅读

0 ·

CC 4.0 BY-SA版权

文章标签：

#integer #string #function #vb.net #module #eclipse

.NET 专栏收录该内容

0 篇文章

订阅专栏

在VB.NET项目开发中，VS2003的编辑器相比Eclipse或VS2008缺少代码块折叠功能，如If、With、Try、For等。为解决这一问题，作者创建了一个宏，通过格式化代码使这些代码块能够折叠。虽然效率较低，处理大量代码可能需要几分钟时间，但这个宏提供了一种实用的解决方案。

VS2003折叠代码的Micro

最近一直用VB.NET来做项目，不幸公司使用的是VS2003进行开发,VisualStudio 2003的编辑器和现在的Eclipse或VS2008真是不能比。

特别少了If，With，Try，For等代码块的折叠，代码一长根本就很难读。

于是，想出了一个宏(Micro)，对文档进行格式代，使If，With，Try，For等代码块也能折叠，觉得有趣味，拿来分享。希望能对一些人有帮助。

由于效率上没优化过，而且用的是堆栈，所以长代码的情况下，１万行代码大概得两三分钟吧。比较慢，可以喝杯咖啡或上个厕所先，呵呵。

执行方法，按Alt+F8调出Micro浏览器，打开要格式化的VB文档(C#改动一下应该也能很快做到吧)，然后双击要调用的方法。

Imports EnvDTE
Imports System.Diagnostics
Imports System.Collections
Imports System.Math
Imports System.Text.RegularExpressions
Public Module FormatDocument
    '*
    '* 只折叠本代码块
    '*
    Public Sub CollapseThis()
        Dim objSel As TextSelection
        Dim intPos_Cur As Integer
        Dim intPos_Start As Integer = 0
        Dim intPos_End As Integer = 0
        Dim intPos As Integer
        Dim intStackFG_Head As Integer = 0
        Dim intStackFG_End As Integer = 0
        objSel = DTE.ActiveDocument.Selection
        ' :( 判定Collapse存在　(为解决折叠后行号发生变化的Bug)
        objSel.EndOfDocument()
        Dim temp1 As Integer = objSel.CurrentLine()
        DTE.ExecuteCommand("Edit.ToggleAllOutlining")
        objSel.EndOfDocument()
        Dim temp2 As Integer = objSel.CurrentLine()
        If temp1 > temp2 Then
            DTE.ExecuteCommand("Edit.ToggleAllOutlining")
        End If
        'Get Current Position
        DTE.ExecuteCommand("View.NavigateBackward")
        intPos_Cur = objSel.CurrentLine()
        'Get Start Position
        intPos = intPos_Cur
        objSel.GotoLine(intPos, True)
        While intPos > 0
            '模拟堆栈
            If isEndKey(objSel.Text) Then
                intStackFG_Head -= 1
            End If
            If isKey(objSel.Text) And intStackFG_Head = 0 Then
                Exit While
            ElseIf isKey(objSel.Text) And intStackFG_Head < 0 Then
                intStackFG_Head += 1
            End If

intPos -= 1
            objSel.GotoLine(intPos, True)
        End While
        intPos_Start = intPos
        'Get End Position
        intPos = intPos_Start + 1
        objSel.GotoLine(intPos, True)
        While intPos < Max(temp1, temp2)
            '模拟堆栈
            If isKey(objSel.Text) Then
                intStackFG_End += 1
            End If
            If isEndKey(objSel.Text) And intStackFG_End = 0 Then
                Exit While
            ElseIf isEndKey(objSel.Text) And intStackFG_End > 0 Then
                intStackFG_End -= 1
            End If
            intPos += 1
            objSel.GotoLine(intPos, True)
        End While
        intPos_End = intPos
        'Collapse This
        If intPos_End - intPos_Start > 0 Then
            objSel.GotoLine(intPos_Start)
            objSel.LineDown(True, intPos_End - intPos_Start + 1)
            objSel.OutlineSection()
        End If
    End Sub
    '*
    '* 全局折叠格式化
    '*
    Public Sub CollapseDocument()
        Dim objSel As TextSelection
        Dim strDoc As String
        Dim strLines() As String
        Dim strLine As String
        Dim i As Integer
        Dim stack As Stack = New Stack '存Key行数
        Dim intCollapseStart As Integer
        Dim intCollapseNum As Integer

' Get Doc and Return to Top
        objSel = DTE.ActiveDocument.Selection
        objSel.SelectAll()
        strDoc = objSel.Text
        strDoc = strDoc.ToLower
        objSel.StartOfDocument()
        'Split To Array
        strLines = strDoc.Split(vbCrLf)
        'Get collapse points
        For i = 0 To strLines.Length - 1
            '1.分析开头是否为Key
            If isKey(strLines(i)) Then
                stack.Push(i + 1) '保存行号
            End If
            '1.分析开头是否为End Key
            If isEndKey(strLines(i)) Then
                intCollapseStart = stack.Pop() '返回行号
                intCollapseNum = (i + 1) - intCollapseStart + 1
                objSel.GotoLine(intCollapseStart)
                objSel.LineDown(True, intCollapseNum)
                objSel.OutlineSection()
                DTE.ExecuteCommand("Edit.ToggleOutliningExpansion")
            End If
        Next
        objSel.StartOfDocument()
    End Sub
    Private Function isKey(ByVal s As String) As Boolean
        Dim strTemp As String = s.TrimStart
        Dim strKeys() As String = {"if ", "for ", "while ", "with ", "try", "select "}
        Dim strKey As String
        If strTemp.Length = 0 Then
            Return False
        Else
            For Each strKey In strKeys
                If strTemp.StartsWith(strKey) Then
                    Return True
                End If
            Next
        End If
        'Default
        Return False
    End Function
    Private Function isEndKey(ByVal s As String) As Boolean
        Dim strTemp As String = s.TrimStart
        Dim strKeys() As String = {"end if", "next", "end while", "end with", "end try", "end select"}
        Dim strKey As String
        If strTemp.Length = 0 Then
            Return False
        Else
            For Each strKey In strKeys
                If strTemp.StartsWith(strKey) Then
                    Return True
                End If
            Next
        End If
        'Default
        Return False
    End Function
End Module