bat脚本—2

最新推荐文章于 2024-06-26 22:17:15 发布

原创最新推荐文章于 2024-06-26 22:17:15 发布 · 281 阅读

0 ·

CC 4.0 BY-SA版权

实用功能专栏收录该内容

36 篇文章

订阅专栏

本文介绍了一种使用批处理脚本自动更新Windows系统hosts文件的方法。通过检查myComputer节点是否存在及IP地址有效性，脚本决定添加或修改相应条目。涉及变量延迟、命令执行返回值读取等关键技术。

实现功能：在C:\Windows\System32\drivers\etc目录下的hosts文件中添加myComputer节点的值

实现思路：1.直接读取hosts文件，如果匹配到myComputer节点的值，就不加，否则在文件最后添加一行形如127.0.0.1 myComputer的内容，这种方式的局限在于无法验证ip地址的有效性；
2.直接在命令行ping，根据ping的结果决定后续处理。

要点：1.获取命令执行后的返回值。返回值放在errorlevel变量中，返回值为0表示正常执行完成，errorlevel的取值范围是0~255。
2.变量延迟。批处理脚本中，变量延迟默认是不开启的，所以我们在for和if中对变量值进行的修改，是无法立即生效的，需要开启变量延迟，并且变量用"!"代替之前的"%"。
3.将cmd命令执行后的结果赋值给变量。linux系统下，这个操作很简单，直接用"="赋值就好了，但是在windows系统下麻烦点，需要用for给变量赋值。

代码：
注：在有些（如win10）系统下，需要以管理员权限运行此脚本


@echo off
::开启变量延迟
setlocal EnableDelayedExpansion

set hostName=myComputer
set ipAdress=127.0.0.1
set hostsPath=C:\Windows\System32\drivers\etc
set hostsFile=%hostsPath%\hosts
set fileName=hosts
set tmpFile=%hostsPath%\hosts.tmp
set flagName=32

:start
::在命令行执行ping，获取返回值
ping %hostName% -n 1

::执行成功，说明hosts中有对应的节点信息
if %errorlevel% EQU 0 (goto end)
::执行失败的原因有可能是hosts中没有对应的节点，也有可能是对应节点的ip地址无效
if %errorlevel% EQU 1 (goto addOrModify)

goto end

:addOrModify
echo ---addOrModify---
::如果是对应的节点ip地址无效，命令行的返回结果中会有"32"的字符串，其它字符串除"Ping"外都会受到操作系统语言的影响；但是hosts文件中没有对应节点也会有"Ping"这个字符串
set flag=0
for /f %%i in ('ping %hostName% -n 1 ^| find /c "%flagName%"') do (
    set flag=%%i
)
::如果含有"32"这个字符串，说明对应的ip地址无法ping通，需要修改
if %flag% GTR 0 (goto modifyAdress) else (goto addAdress)

::校验修改后是否生效
goto start


:modifyAdress
echo ---modifyAdress---
::查找到相应的节点后，将其修改
for /f "delims=" %%i in (%hostsFile%) do (
    set hasHostNameFlag=0
    for /f %%j in ('echo %%i ^| find /c "%hostName%"') do (
        set hasHostNameFlag=%%j
    )
    
    if !hasHostNameFlag! EQU 0 (echo %%i) else (echo     %ipAdress%       %hostName%)
)>>%tmpFile%
del %hostsFile% /q
ren %tmpFile% %fileName%

::校验修改后是否生效
goto start

:addAdress
echo ---addAdress---

::如果没有对应的节点，直接在文件末尾追加
echo     %ipAdress%       %hostName%>>%hostsFile%

::校验修改后是否生效
goto start


:end
echo ----------end----------