请管理员创建pre-revprop-change钩子

最新推荐文章于 2025-02-13 10:16:58 发布

原创最新推荐文章于 2025-02-13 10:16:58 发布 · 1.4k 阅读

2 ·

CC 4.0 BY-SA版权

文章标签：

#SVN #Google #F#

Java综合专栏收录该内容

1 篇文章

订阅专栏

本文介绍如何通过创建pre-revprop-change.bat文件来允许用户修改SVN版本库中的提交注释，同时确保只允许修改日志消息而不改变作者等其他属性。

今天想更改SVN中已经提交的版本的注释，提示说“请管理员创建pre-revprop-change钩子”，google了之后找到了解决办法，在hooks目录下创建pre-revprop-change.bat，里面的代码如下：

@ECHO OFF 
:: Set all parameters. Even though most are not used, in case you want to add 
:: changes that allow, for example, editing of the author or addition of log messages. 
set repository=%1 
set revision=%2 
set userName=%3 
set propertyName=%4 
set action=%5 
 
:: Only allow the log message to be changed, but not author, etc. 
if /I not "%propertyName%" == "svn:log" goto ERROR_PROPNAME 
 
:: Only allow modification of a log message, not addition or deletion. 
if /I not "%action%" == "M" goto ERROR_ACTION 
 
:: Make sure that the new svn:log message is not empty. 
set bIsEmpty=true 
for /f "tokens=*" %%g in ('find /V ""') do ( 
set bIsEmpty=false 
) 
if "%bIsEmpty%" == "true" goto ERROR_EMPTY 
 
goto :eof 
 
:ERROR_EMPTY 
echo Empty svn:log messages are not allowed. >&2 
goto ERROR_EXIT 
 
:ERROR_PROPNAME 
echo Only changes to svn:log messages are allowed. >&2 
goto ERROR_EXIT 
 
:ERROR_ACTION 
echo Only modifications to svn:log revision properties are allowed. >&2 
goto ERROR_EXIT 
 
:ERROR_EXIT 
exit /b 1