多个bat汇总的小工具

最新推荐文章于 2022-03-08 19:55:14 发布

原创最新推荐文章于 2022-03-08 19:55:14 发布 · 399 阅读

1 ·

CC 4.0 BY-SA版权

文章标签：

#C #C++ #C# #F#

Windows 专栏收录该内容

4 篇文章

订阅专栏

本文介绍了一个数据交换命令整合脚本，该脚本由enica编写，用于自动化数据交换任务。通过配置文件config.ini指定不同的程序ID可以启动相应数据交换程序或查看其日志。脚本支持按需执行数据交换程序或输出日志。


@echo off
@echo ************************************
@echo *                                  *
@echo *说明：数据交换命令整合            *
@echo *作者：enica                       *
@echo *日期：2011-02-14                  *
@echo *版本：version 1.0                 *
@echo *                                  *
@echo ************************************

rem ************************************
rem *                                  *
rem 取日期和时间做备份日志后缀
rem *                                  *
rem ************************************
set dateStr=%date:~0,4%%date:~5,2%%date:~8,2%
rem 0-9点小时会有空格，做数字转换
set /a hourStr = %time:~0,2%
set dateStr=%dateStr%%hourStr%%time:~3,2%%time:~6,2%


rem ************************************
rem *                                  *
rem 程序入口
rem *                                  *
rem ************************************
if "%1"=="" goto info

goto next


rem ************************************
rem *                                  *
rem 信息提示段
rem *                                  *
rem ************************************
:info
@echo 启动类命令参数
for /f "skip=3 tokens=1,2 delims='='" %%a in (config.ini) do (
	@echo	%%a	%%b
)
goto exit

rem ************************************
rem *                                  *
rem 程序入口段
rem *                                  *
rem ************************************
:next
for /f "skip=3 tokens=1,2,3,4,5 delims='='" %%a in (config.ini) do (
	if "%1"=="%%a" (	
		rem 根据数据ID来判断启动程序还是查看日志
		if %1 LSS 20 (
			rem ************************************
			rem *                                  *
			rem 程序段
			rem 程序编号：		%%a
			rem 程序名称：		%%b
			rem 程序简称：		%%c
			rem 程序绝对路径：	%%d
			rem 日志绝对路径：	%%e
			rem *                                  *
			rem ************************************
			@echo %%b数据交换
			if exist %%e ren  %%e %%c%dateStr%.log
			if ERRORLEVEL 1 pause & @echo 日志重命名异常
			if exist %%d %%d > %%e
			if not exist %%d echo %%b：程序不存在，请确认路径
			goto exit
		)

		if %1 GTR 20 (
			rem ************************************
			rem *                                  *
			rem 日志段
			rem 程序编号：		%%a
			rem 程序名称：		%%b
			rem 程序简称：		%%c
			rem 程序绝对路径：	%%d
			rem 日志绝对路径：	%%e
			rem *                                  *
			rem ************************************
			@echo %%b日志输出
			if exist %%e tail -100f %%e
			if not exist %%e echo %%e：日志不存在，请确认路径
			goto exit
		)

	)
)
rem 没有匹配的参数就跳转到信息提示
goto info

rem ************************************
rem *                                  *
rem 程序结束段
rem *                                  *
rem ************************************
:exit
pause>nul