win32汇编环境,网络编程入门之九

一品人家

已于 2025-03-24 11:46:29 修改

阅读量802

点赞数 17

分类专栏： win32汇编网络编程入门教程文章标签：汇编

于 2025-03-23 23:17:10 首次发布

本文链接：https://blog.youkuaiyun.com/iltokyo/article/details/146464352

版权

win32汇编网络编程入门教程专栏收录该内容

18 篇文章

订阅专栏

;在上一教程里，我们学习了在连接成功网站后，应该发送什么数据给网站
;在前面的几个教程里，简单地运行了套接字机制连接网站的方式，这是字节级的网络连接，扩展几乎是无限的。
;想了想，这个开个头就行了，暂时放下来，再讲下去越搞越复杂，还是把一些基础运用的方式讲一讲。以后回头再来研究它。

;从这个教程开始，讲一下部分微软专用网络API的运用。
;微软网络API有2个值得一提，1个是WinInet,还1个是WinHTTP
;这2个东西差不多，WinHTTP相当于WinInet的升级版本，2个都是网络连接机制，也是一整套的API，就是封装好的函数集
;我们可以查看RadASM 的masm32文件夹下有include目录，下面有个 wininet.inc文件，里面就是WinInet的函数集，可以研究一下它

;先弄个使用 WinInet机制连接网站并得到网页内容的示例观摩一下看看,看起来代码很少，但很重要，因为这是基础流程

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.386
.model flat,stdcall
option casemap:none

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Include 文件定义
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
include windows.inc
include user32.inc
include kernel32.inc
include wininet.inc ;需要添加的wininet头文件

includelib user32.lib
includelib kernel32.lib
includelib wininet.lib ;需要添加的wininet库文件

; 自定义函数声明
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
DlgProc proto :DWORD,:DWORD,:DWORD,:DWORD ;对话框窗口函数

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Equ 等值定义
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
MAINDIALOG   equ 1
ICO_MAIN   equ 1000   ;图标
ID_BUTTON01   equ 41
ID_EDIT01   equ 11

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 数据段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.data

szMsg db "提示",0
szFrm db "%d",0
szErr db "错误",0

szAgent db "Microsoft Internet Explorer",0 ;骗网站说自已是IE浏览器
szHostName db "www.kepai2023.cn",0 ;要访问的主机域名
szUrlPath db "/",0 ;要访问主页
szVerb db "GET",0 ;GET方法访问
szAccept db "Accept: text/html",0 ;只接受text或html文件返回

.data?
hInstance HINSTANCE ?
hEdithwnd01 HWND ?

hInternet dd ?
hHttpSession dd ?
hHttpRequest dd ?
hHttp dd ?

.const

; 代码段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.code
start:
invoke GetModuleHandle, NULL
mov hInstance,eax
invoke DialogBoxParam, hInstance, MAINDIALOG,NULL, addr DlgProc, NULL
invoke ExitProcess,eax
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_WorkThread   proc   _lParam
LOCAL @dwBytesRead
LOCAL @szRecBuffer[1024]:byte

invoke InternetOpen,addr szAgent,INTERNET_OPEN_TYPE_DIRECT,NULL,NULL,0 ;初始化应用程序的 WinINet 函数的使用
mov hInternet,eax
invoke InternetConnect,hInternet,addr szHostName,80,NULL,NULL,INTERNET_SERVICE_HTTP,0,0 ;为给定站点打开文件传输协议（FTP）或 HTTP 会话,80是http的端口
mov hHttpSession,eax
.if eax == NULL
invoke MessageBox,NULL,addr szErr,addr szMsg,MB_OK
.endif

invoke HttpOpenRequest,hHttpSession,addr szVerb,addr szUrlPath,NULL,addr szAccept,0,0,0 ;创建 HTTP 请求句柄
mov hHttpRequest,eax
invoke HttpSendRequest,hHttpRequest,NULL,0,NULL,0 ;将指定的请求发送到 HTTP 服务器，可以附加数据，后面再说，先实现基本效果先
.if eax == NULL
invoke MessageBox,NULL,addr szErr,addr szMsg,MB_OK
.endif
invoke   RtlZeroMemory,addr @szRecBuffer,sizeof @szRecBuffer

invoke InternetReadFile,hHttpRequest,addr @szRecBuffer,1024,addr @dwBytesRead ;从打开的句柄读取数据，
.if eax == NULL
invoke MessageBox,NULL,addr szErr,addr szMsg,MB_OK
.endif
invoke SendMessage,hEdithwnd01,WM_SETTEXT,0,addr @szRecBuffer ;把网站返回的数据显示在编辑框里

   ret

_WorkThread endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
DlgProc proc hWnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM
LOCAL   @stWsa:WSADATA

.if uMsg == WM_INITDIALOG
   invoke   LoadIcon,hInstance,ICO_MAIN
   invoke   SendMessage,hWnd,WM_SETICON,ICON_BIG,eax

invoke GetDlgItem,hWnd,ID_EDIT01
mov hEdithwnd01,eax

.elseif   uMsg ==   WM_COMMAND
           mov   ebx,wParam
       .if   bx ==   ID_BUTTON01
       invoke   CreateThread,NULL,0,offset _WorkThread,0,NULL,0 ;启动连接线程,用线程的原因是不让网络等待卡住主进程
           .endif
.elseif uMsg == WM_CLOSE
invoke InternetCloseHandle,hHttpRequest ;反向清除各类HINTERNET 句柄，即先生成的后清除，后生成的先清除
invoke InternetCloseHandle,hHttpSession
invoke InternetCloseHandle,hInternet
       invoke EndDialog,hWnd,NULL
.else
mov eax,FALSE
ret
.endif
mov eax,TRUE
ret
DlgProc endp

end start

;下面为rc文件内容
#include "resource.h" //提示缺少该文件，可以在资源里下载
//>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
#define MAINDIALOG 1
#define ICO_MAIN 1000 //图标
#define ID_BUTTON01 41

#define ID_EDIT01 11 //编辑框标识符